build.gradle

plugins {
    id 'java'
    id 'net.kyori.blossom' version '1.3.1'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
}

group 'com.danifoldi'
version '3.0.0'
sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

repositories {
    mavenCentral()
    google()
    maven { url 'https://repo.danifoldi.com/repository/maven-releases/' }
    maven { url 'https://papermc.io/repo/repository/maven-public/' }
    maven { url 'https://nexus.velocitypowered.com/repository/maven-public/' }
    maven { url 'https://jitpack.io/' }
    maven { url 'https://mvn.exceptionflug.de/repository/exceptionflug-public/' }
    maven { url 'https://repo.simplix.dev/repository/simplixsoft-public/' }
}

dependencies {
    compileOnly 'io.github.waterfallmc:waterfall-api:1.19-R0.1-SNAPSHOT'
    compileOnly 'com.velocitypowered:velocity-api:3.1.1'
    annotationProcessor 'com.velocitypowered:velocity-api:3.1.1'

    implementation ('grapefruit:grapefruit:1.5.0') {
        exclude module: 'annotation'
        exclude module: 'guava'
    }
    compileOnly 'dev.simplix:protocolize-api:2.3.0'

    compileOnly 'net.luckperms:api:5.4'
    compileOnly 'com.github.LeonMangler:PremiumVanishAPI:2.8.8'
    compileOnly 'dev.simplix.plugins:punishcontrol-api:2.0.1'

    implementation ('com.electronwill.night-config:yaml:3.6.6') {
        exclude module: 'snakeyaml'
    }

    compileOnly 'org.jetbrains:annotations:24.0.1'
    implementation 'javax.inject:javax.inject:1'
    implementation 'com.google.dagger:dagger:2.46.1'
    annotationProcessor 'com.google.dagger:dagger-compiler:2.46.1'
}

processResources {
    duplicatesStrategy(DuplicatesStrategy.INCLUDE)
    from(sourceSets.main.resources) {
        expand version: project.version
    }
}

blossom {
    replaceTokenIn('src/main/java/com/danifoldi/protogui/platform/velocity/ProtoGui.java')
    replaceToken '@version@', project.version
}

shadowJar {
    minimize {
        //noinspection GroovyAssignabilityCheck
        exclude(dependency('com.electronwill.night-config:.*:.*'))
    }

    relocate 'org.jetbrains.annotations', 'com.danifoldi.protogui.lib.annotations'
    relocate 'javax.inject', 'com.danifoldi.protogui.lib.inject'
    relocate 'dagger', 'com.danifoldi.protogui.lib.dagger'
    relocate 'com.electronwill.nightconfig', 'com.danifoldi.protogui.lib.nightconfig'
    relocate 'grapefruit.command', 'com.danifoldi.protogui.lib.grapefruit'

    archiveFileName.set("${project.name}-${project.version}.jar")
}