From 10f1cd9ad51768c623ae1710ec0546c64e563434 Mon Sep 17 00:00:00 2001
From: Leah Amelia Chen <hi@pluie.me>
Date: Wed, 6 Nov 2024 13:45:34 +0100
Subject: [PATCH] theseus-ship: init at 6.2.0

---
 pkgs/by-name/th/theseus-ship/package.nix | 80 ++++++++++++++++++++++++
 1 file changed, 80 insertions(+)
 create mode 100644 pkgs/by-name/th/theseus-ship/package.nix

diff --git a/pkgs/by-name/th/theseus-ship/package.nix b/pkgs/by-name/th/theseus-ship/package.nix
new file mode 100644
index 0000000000000..143b25e304e9a
--- /dev/null
+++ b/pkgs/by-name/th/theseus-ship/package.nix
@@ -0,0 +1,80 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  ninja,
+  pkg-config,
+  kdePackages,
+
+  libepoxy,
+  libinput,
+  libcap,
+  como,
+  wrapland,
+  microsoft-gsl,
+  pixman,
+  wayland,
+  wlroots,
+  libdrm,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "theseus-ship";
+  version = "6.2.0";
+
+  src = fetchFromGitHub {
+    owner = "winft";
+    repo = "theseus-ship";
+    rev = "refs/tags/v${finalAttrs.version}";
+    hash = "sha256-8KTTkOkYcltcYZ+arvhRQSrHiZDX6F3JwoXVXa8NFKU=";
+  };
+
+
+  nativeBuildInputs = [
+    cmake
+    ninja
+    pkg-config
+    kdePackages.extra-cmake-modules
+    kdePackages.wrapQtAppsHook
+    libcap
+  ];
+
+  buildInputs = with kdePackages; [
+    kcrash
+    kdbusaddons
+    kwidgetsaddons
+    kirigami
+    kscreenlocker
+    breeze
+    wayland
+    qtbase
+    qttools
+
+    libepoxy
+    libinput
+    como
+    wrapland
+    microsoft-gsl
+    pixman
+    wayland
+    wlroots
+    libdrm
+  ];
+
+  # It wants <drm_fourcc.h> and not <libdrm/drm_fourcc.h>
+  env.NIX_CFLAGS_COMPILE = "-isystem ${lib.getDev libdrm}/include/libdrm";
+
+  cmakeFlags = [
+    # Otherwise the kcoreaddon plugin macro would try to write them to
+    # /plasma (yes, top level). How fun!
+    (lib.cmakeFeature "CMAKE_LIBRARY_OUTPUT_DIRECTORY" "${placeholder "out"}/lib")
+  ];
+
+  meta = {
+    description = "Wayland and X11 Compositor for the KDE Plasma desktop";
+    homepage = "https://github.com/winft/theseus-ship";
+    license = with lib.licenses; [ gpl2Only ];
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ pluiedev ];
+  };
+})