-
Notifications
You must be signed in to change notification settings - Fork 3
/
wfnmod.f90
2312 lines (2099 loc) · 78.8 KB
/
wfnmod.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
! Copyright (c) 2013-2016 Alberto Otero de la Roza
! <[email protected]>, Felix Kannemann
! <[email protected]>, Erin R. Johnson <[email protected]>,
! Ross M. Dickson <[email protected]>, Hartmut Schmider
! <[email protected]>, and Axel D. Becke <[email protected]>
!
! postg is free software: you can redistribute it and/or modify
! it under the terms of the GNU General Public License as published by
! the Free Software Foundation, either version 3 of the License, or
! (at your option) any later version.
!
! This program is distributed in the hope that it will be useful,
! but WITHOUT ANY WARRANTY; without even the implied warranty of
! MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
! GNU General Public License for more details.
!
! You should have received a copy of the GNU General Public License
! along with this program. If not, see <http://www.gnu.org/licenses/>.
module wfnmod
use param
implicit none
private
public :: atomin, readwfn, readwfx, readfchk, readtck, readmolden, evalwfn, edisp
! double factorials minus one
integer, parameter :: dfacm1(0:8) = (/1,1,1,2,3,8,15,48,105/)
! double factorials
integer, parameter :: dfac(0:8) = (/1,1,2,3,8,15,48,105,384/)
! number of angular components for shell type
! gs fs ds ps s p d f g
integer, parameter :: nshlt(-4:4) = (/9, 7, 5, 3, 1, 3, 6, 10, 15/)
! initial and final types for cartesian shells
integer, parameter :: jshl0(0:4) = (/1, 2, 5, 11, 21/) ! s, p, d, f, g
integer, parameter :: jshl1(0:4) = (/1, 4, 10, 20, 35/) ! s, p, d, f, g
! named constants for the sph to car matrices below
real*8, parameter :: s3 = sqrt(3d0)
real*8, parameter :: s3_4 = sqrt(3d0/4d0)
real*8, parameter :: s3_8 = sqrt(3d0/8d0)
real*8, parameter :: s5_4 = sqrt(5d0/4d0)
real*8, parameter :: s5_8 = sqrt(5d0/8d0)
real*8, parameter :: s5_16 = sqrt(5d0/16d0)
real*8, parameter :: s5_28 = sqrt(5d0/28d0)
real*8, parameter :: s3_40 = sqrt(3d0/40d0)
real*8, parameter :: s6_5 = sqrt(6d0/5d0)
real*8, parameter :: s6 = sqrt(6d0)
real*8, parameter :: s9_7 = sqrt(9d0/7d0)
real*8, parameter :: s9_8 = sqrt(9d0/8d0)
real*8, parameter :: s9_20 = sqrt(9d0/20d0)
real*8, parameter :: s9_56 = sqrt(9d0/56d0)
real*8, parameter :: s10 = sqrt(10d0)
real*8, parameter :: s10_7 = sqrt(10d0/7d0)
real*8, parameter :: s10_8 = sqrt(10d0/8d0)
real*8, parameter :: s15 = sqrt(15d0)
real*8, parameter :: s15_4 = sqrt(15d0/4d0)
real*8, parameter :: s27_16 = sqrt(27d0/16d0)
real*8, parameter :: s27_28 = sqrt(27d0/28d0)
real*8, parameter :: s27_35 = sqrt(27d0/35d0)
real*8, parameter :: s27_560 = sqrt(27d0/560d0)
real*8, parameter :: s35_4 = sqrt(35d0/4d0)
real*8, parameter :: s35_8 = sqrt(35d0/8d0)
real*8, parameter :: s35_64 = sqrt(35d0/64d0)
real*8, parameter :: s45 = sqrt(45d0)
real*8, parameter :: s45_4 = sqrt(45d0/4d0)
real*8, parameter :: s45_8 = sqrt(45d0/8d0)
real*8, parameter :: s45_56 = sqrt(45d0/56d0)
real*8, parameter :: s315_8 = sqrt(315d0/8d0)
real*8, parameter :: s315_16 = sqrt(315d0/16d0)
real*8, parameter :: d32 = 3d0/2d0
real*8, parameter :: d34 = 3d0/4d0
real*8, parameter :: d38 = 3d0/8d0
! -- Real solid harmonics r^l * Slm as a function of Cartesian products. --
! see: Schlegel and Frisch, Int. J. Quantum Chem. 54 (1995) 83,
! "Transformation Between Cartesian and Pure Spherical Harmonic Gaussians"
! https://doi.org/10.1002/qua.560540202
! Use table 1 and note that:
! Rlm = sqrt(2) * Im[Y_l^|m|] if m < 0
! Y_l^0 if m =0
! sqrt(2) * Re[Y_l^|m|] if m > 0
! Can also be found in Helgaker, eqs. 9.1.9 to 9.1.12
! dsphcar: l = 2
! spherical molden order: m = 0, 1, -1, 2, -2
! Cartesian molden order: xx, yy, zz, xy, xz, yz
real*8 :: dsphcar(5,6) = reshape((/&
! 0 1 -1 2 -2
-0.5d0, 0.0d0, 0.0d0, s3_4, 0.0d0,& ! xx
-0.5d0, 0.0d0, 0.0d0, -s3_4, 0.0d0,& ! yy
1.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! zz
0.0d0, 0.0d0, 0.0d0, 0.0d0, 1.0d0,& ! xy
0.0d0, 1.0d0, 0.0d0, 0.0d0, 0.0d0,& ! xz
0.0d0, 0.0d0, 1.0d0, 0.0d0, 0.0d0 & ! yz
/),shape(dsphcar))
! fsphcar: l = 3
! spherical molden order: m = 0, 1, -1, 2, -2, 3, -3
! Cartesian molden order: xxx, yyy, zzz, xyy, xxy, xxz, xzz, yzz, yyz, xyz
real*8 :: fsphcar(7,10) = reshape((/&
! 0 1 -1 2 -2 3 -3
0.0d0, -s3_8, 0.0d0, 0.0d0, 0.0d0, s5_8, 0.0d0,& ! xxx
0.0d0, 0.0d0, -s3_8, 0.0d0, 0.0d0, 0.0d0, -s5_8,& ! yyy
1.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! zzz
0.0d0, -s3_40, 0.0d0, 0.0d0, 0.0d0, -s9_8, 0.0d0,& ! xyy
0.0d0, 0.0d0, -s3_40, 0.0d0, 0.0d0, 0.0d0, s9_8,& ! xxy
-s9_20, 0.0d0, 0.0d0, s3_4, 0.0d0, 0.0d0, 0.0d0,& ! xxz
0.0d0, s6_5, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! xzz
0.0d0, 0.0d0, s6_5, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! yzz
-s9_20, 0.0d0, 0.0d0, -s3_4, 0.0d0, 0.0d0, 0.0d0,& ! yyz
0.0d0, 0.0d0, 0.0d0, 0.0d0, 1d0, 0.0d0, 0.0d0 & ! xyz
/),shape(fsphcar))
! gsphcar: l = 4
! spherical molden order: m = 0, 1, -1, 2, -2, 3, -3, 4, -4
! Cartesian molden order: xxxx yyyy zzzz xxxy xxxz xyyy yyyz xzzz yzzz xxyy xxzz yyzz xxyz xyyz xyzz
real*8 :: gsphcar(9,15) = reshape((/&
! 0 1 -1 2 -2 3 -3 4 -4
d38, 0.0d0, 0.0d0, -s5_16, 0.0d0, 0.0d0, 0.0d0, s35_64, 0.0d0,& ! xxxx
d38, 0.0d0, 0.0d0, s5_16, 0.0d0, 0.0d0, 0.0d0, s35_64, 0.0d0,& ! yyyy
1d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! zzzz
0.0d0, 0.0d0, 0.0d0, 0.0d0, -s5_28, 0.0d0, 0.0d0, 0.0d0, s5_4,& ! xxxy
0.0d0,-s45_56, 0.0d0, 0.0d0, 0.0d0, s5_8, 0.0d0, 0.0d0, 0.0d0,& ! xxxz
0.0d0, 0.0d0, 0.0d0, 0.0d0, -s5_28, 0.0d0, 0.0d0, 0.0d0, -s5_4,& ! xyyy
0.0d0, 0.0d0,-s45_56, 0.0d0, 0.0d0, 0.0d0, -s5_8, 0.0d0, 0.0d0,& ! yyyz
0.0d0, s10_7, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! xzzz
0.0d0, 0.0d0, s10_7, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! yzzz
s27_560, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, -s27_16, 0.0d0,& ! xxyy
-s27_35, 0.0d0, 0.0d0, s27_28, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! xxzz
-s27_35, 0.0d0, 0.0d0,-s27_28, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! yyzz
0.0d0, 0.0d0, -s9_56, 0.0d0, 0.0d0, 0.0d0, s9_8, 0.0d0, 0.0d0,& ! xxyz
0.0d0, -s9_56, 0.0d0, 0.0d0, 0.0d0, -s9_8, 0.0d0, 0.0d0, 0.0d0,& ! xyyz
0.0d0, 0.0d0, 0.0d0, 0.0d0, s9_7, 0.0d0, 0.0d0, 0.0d0, 0.0d0 & ! xyzz
/),shape(gsphcar))
! gsphcar: l = 4
! spherical fchk order: m = 0, 1, -1, 2, -2, 3, -3, 4, -4
! Cartesian fchk order: zzzz yzzz yyzz yyyz yyyy xzzz xyzz xyyz xyyy xxzz xxyz xxyy xxxz xxxy xxxx
! This is just a permutation of gsphcar where the rows are arranged in fchk's primitive order
real*8 :: gsphcar_fchk(9,15) = reshape((/&
! 0 1 -1 2 -2 3 -3 4 -4
1d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! zzzz
0.0d0, 0.0d0, s10_7, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! yzzz
-s27_35, 0.0d0, 0.0d0,-s27_28, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! yyzz
0.0d0, 0.0d0,-s45_56, 0.0d0, 0.0d0, 0.0d0, -s5_8, 0.0d0, 0.0d0,& ! yyyz
d38, 0.0d0, 0.0d0, s5_16, 0.0d0, 0.0d0, 0.0d0, s35_64, 0.0d0,& ! yyyy
0.0d0, s10_7, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! xzzz
0.0d0, 0.0d0, 0.0d0, 0.0d0, s9_7, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! xyzz
0.0d0, -s9_56, 0.0d0, 0.0d0, 0.0d0, -s9_8, 0.0d0, 0.0d0, 0.0d0,& ! xyyz
0.0d0, 0.0d0, 0.0d0, 0.0d0, -s5_28, 0.0d0, 0.0d0, 0.0d0, -s5_4,& ! xyyy
-s27_35, 0.0d0, 0.0d0, s27_28, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0,& ! xxzz
0.0d0, 0.0d0, -s9_56, 0.0d0, 0.0d0, 0.0d0, s9_8, 0.0d0, 0.0d0,& ! xxyz
s27_560, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, 0.0d0, -s27_16, 0.0d0,& ! xxyy
0.0d0,-s45_56, 0.0d0, 0.0d0, 0.0d0, s5_8, 0.0d0, 0.0d0, 0.0d0,& ! xxxz
0.0d0, 0.0d0, 0.0d0, 0.0d0, -s5_28, 0.0d0, 0.0d0, 0.0d0, s5_4,& ! xxxy
d38, 0.0d0, 0.0d0, -s5_16, 0.0d0, 0.0d0, 0.0d0, s35_64, 0.0d0 & ! xxxx
/),shape(gsphcar))
contains
subroutine atomin(m,mesh,qpro)
use atomicdata
use tools_math, only: spline
implicit none
type(molecule), intent(in) :: m
type(tmesh), intent(inout) :: mesh
real*8, intent(out) :: qpro
character*(mline) :: afile
real*8 :: rmid, rdum(8), h, q, x(3), r, dq, arho1, arho2, arho, rdata
integer :: intq
real*8, allocatable, dimension(:) :: a1, b1, c1, f1
real*8, allocatable, dimension(:) :: promol, hirsh
integer :: i, j, l, ndata, idum1, idum2, is, istat, kk, nn
character*2 :: compar
logical :: ok
integer :: isenv
allocate(hirsh(mesh%n),promol(mesh%n),stat=istat)
if (istat /= 0) call error('atomin','could not allocate hirsh/promol',2)
hirsh = 0d0
promol = 0d0
open(unit=imosa,status='scratch',form='unformatted')
do i = 1, m%n
if (m%z(i) < 1) cycle
rmid = 1d0 / m%z(i)**third
if (m%z(i) <= 2) then
ndata = 200
elseif (m%z(i) <= 10) then
ndata = 400
elseif (m%z(i) <= 18) then
ndata = 600
elseif (m%z(i) <= 36) then
ndata = 800
elseif (m%z(i) <= 54) then
ndata = 1000
elseif (m%z(i) <= 86) then
ndata = 1200
elseif (m%z(i) <= 94) then
ndata = 1400
else
call error('atomin','atomic number out of range',2)
endif
allocate(f1(0:ndata),a1(0:ndata),b1(0:ndata),c1(0:ndata))
if (istat /= 0) call error('atomin','could not allocate memory for f1, a1, b1, c1',2)
h = 1d0 / (ndata+1)
f1(0) = 0d0
do j = 1, ndata
q = h * j
rdata = rmid * q / (1.d0-q)
f1(j) = ftot(j,m%z(i))
enddo
call spline(h,f1,a1,b1,c1,ndata,0.d0)
do kk = 1, mesh%n
x = mesh%x(:,kk) - m%x(:,i)
r = sqrt(x(1)**2+x(2)**2+x(3)**2)
q = r / (r + rmid)
intq = int((ndata+1) * q)
dq = q - intq * h
arho = abs((f1(intq)+dq*(a1(intq)+dq*(b1(intq)+dq*c1(intq)))))/r**2
hirsh(kk) = arho
promol(kk) = promol(kk) + arho
enddo
write(imosa) (hirsh(j),j=1,mesh%n)
deallocate(f1,a1,b1,c1)
enddo
qpro = sum(mesh%w * promol)
open(unit=ihrsh,status='scratch',form='unformatted')
rewind(imosa)
do i = 1, m%n
if (m%z(i) < 1) cycle
read(imosa) (hirsh(j),j=1,mesh%n)
write(ihrsh) (hirsh(j)/max(promol(j),1d-40),j=1,mesh%n)
enddo
deallocate(hirsh,promol)
close(imosa)
end subroutine atomin
!> Read wfn file
function readwfn(file,egauss) result(m)
character*(mline), intent(in) :: file
real*8, intent(out) :: egauss
type(molecule) :: m
character*4 :: orbtyp
character*2 :: dums, elem
integer :: i, j, istat, imax, icount, ioc, num1, num2
real*8 :: zreal, ene, ene0
logical :: isfrac
integer :: nalpha
character*8 :: dum1, dum3, dum4
character*18 :: dum2
character*1024 :: line
integer :: idum, idum2
! set title
m%name = file
m%useecp = .false.
! read number of atoms, primitives, orbitals
open(luwfn,file=file,status='old')
read (luwfn,*)
read (luwfn,101) orbtyp, m%nmo, m%npri, m%n
! atomic positions and numbers
allocate(m%x(3,m%n),stat=istat)
if (istat /= 0) call error('readwfn','could not allocate memory for atomic positions',2)
allocate(m%z(m%n),stat=istat)
if (istat /= 0) call error('readwfn','could not allocate memory for atomic numbers',2)
m%x = 0d0
m%z = 0
m%charge = 0d0
do i = 1, m%n
read(luwfn,106) elem, m%x(:,i), zreal
m%charge = m%charge + zreal
m%z(i) = elem2z(elem)
if (m%z(i) /= nint(zreal)) m%useecp = .true.
end do
! center assignments, types of primitives
allocate(m%icenter(m%npri),stat=istat)
if (istat /= 0) call error('readwfn','could not allocate memory for icenter',2)
allocate(m%itype(m%npri),stat=istat)
if (istat /= 0) call error('readwfn','could not allocate memory for itype',2)
read(luwfn,102) (m%icenter(i),i=1,m%npri)
read(luwfn,102) (m%itype(i),i=1,m%npri)
if (any(m%itype(1:m%npri) > 56)) then
call error("readwfn","primitive type not supported",2)
endif
! primitive exponents
allocate(m%e(m%npri),stat=istat)
if (istat /= 0) call error('readwfn','could not allocate memory for exponents',2)
read(luwfn,103) (m%e(i),i=1,m%npri)
! deal with ecps
dums=""
do while (dums.ne."MO")
read (luwfn,'(A2)') dums
enddo
backspace(luwfn)
! occupations and orbital coefficients
allocate(m%occ(m%nmo),stat=istat)
if (istat /= 0) call error('readwfn','could not allocate memory for occupations',2)
allocate(m%c(m%nmo,m%npri),stat=istat)
if (istat /= 0) call error('readwfn','could not allocate memory for orbital coefficients',2)
m%mult = 1
isfrac = .false.
num1 = 0
num2 = 0
ene0 = -1d30
nalpha = -1
m%nelec = 0d0
do i = 1, m%nmo
read(luwfn,104) m%occ(i), ene
read(luwfn,105) (m%c(i,j),j=1,m%npri)
m%nelec = m%nelec + m%occ(i)
ioc = nint(m%occ(i))
if (abs(ioc-m%occ(i)) > 1d-10) then
isfrac = .true.
else if (ioc == 1) then
num1 = num1 + 1
else if (ioc == 2) then
num2 = num2 + 1
endif
if (ene < ene0-1d-3) nalpha = i-1
ene0 = ene
end do
read(luwfn,*) dum1
read(luwfn,'(A80)') line
line = trim(adjustl(line))
line = line(index(line,'=')+1:)
read (line,*) egauss
! figure out charge and multiplicity
! 0 - closed, 1 - open, 2 - restricted open, 3 - fractional
m%charge = m%charge - m%nelec
if (isfrac) then
m%wfntyp = 3
call error("readwfn","natural orbital wfn files not supported",2)
else if (num1 == 0) then
m%wfntyp = 0
else if (num2 == 0) then
m%wfntyp = 1
if (nalpha == -1) then
m%mult = nint(m%nelec) + 1
else
m%mult = nalpha - (nint(m%nelec) - nalpha) + 1
endif
if (m%mult < 0) call error("readwfn","nbeta > nalpha",2)
else
m%wfntyp = 2
m%mult = count(nint(m%occ(1:m%nmo)) == 1) + 1
endif
close(luwfn)
101 format (4X,A4,10X,3(I5,15X))
102 format(20X,20I3)
103 format(10X,5E14.7)
104 format(35X,F12.7,15X,F12.6)
105 format(5(E16.8))
106 format(2X,A2,20X,3F12.8,10X,F5.1)
end function readwfn
!> Read wfn file
function readwfx(file,egauss) result(m)
character*(mline), intent(in) :: file
real*8, intent(out) :: egauss
type(molecule) :: m
integer :: i, j, istat, ncore, kk, lp, idum
real*8 :: zreal
character*(mline) :: line, tag
logical :: keyw(7)
! set title
m%name = file
m%useecp = .false.
! first pass
open (luwfn,file=file,status='old')
m%n = 0
m%nmo = 0
m%charge = 0
m%mult = 0
ncore = 0
m%npri = 0
egauss = 0d0
do while (.true.)
read(luwfn,'(A)',end=10) line
line = adjustl(line)
if (line(1:1) == "<" .and. line(2:2) /= "/") then
if (trim(line) == "<Number of Nuclei>") then
read (luwfn,*) m%n
elseif (trim(line) == "<Number of Occupied Molecular Orbitals>") then
read (luwfn,*) m%nmo
elseif (trim(line) == "<Net Charge>") then
read (luwfn,*) m%charge
elseif (trim(line) == "<Electronic Spin Multiplicity>") then
read (luwfn,*) m%mult
elseif (trim(line) == "<Number of Core Electrons>") then
read (luwfn,*) ncore
elseif (trim(line) == "<Number of Primitives>") then
read(luwfn,*) m%npri
elseif (trim(line) == "<Energy = T + Vne + Vee + Vnn>") then
read(luwfn,*) egauss
endif
endif
enddo
10 continue
if (m%n == 0) call error("readwfx","Number of Nuclei tag not found",2)
if (m%nmo == 0) call error("readwfx","Number of Occupied Molecular Orbitals tag not found",2)
if (m%mult == 0) call error("readwfx","Electronic Spin Multiplicity tag not found",2)
if (m%npri == 0) call error("readwfx","Number of Primitives tag not found",2)
if (ncore > 0) m%useecp = .true.
! allocate memory
allocate(m%x(3,m%n),stat=istat)
if (istat /= 0) call error('readwfx','could not allocate memory for atomic positions',2)
allocate(m%z(m%n),stat=istat)
if (istat /= 0) call error('readwfx','could not allocate memory for atomic numbers',2)
allocate(m%icenter(m%npri),stat=istat)
if (istat /= 0) call error('readwfx','could not allocate memory for icenter',2)
allocate(m%itype(m%npri),stat=istat)
if (istat /= 0) call error('readwfx','could not allocate memory for itype',2)
allocate(m%e(m%npri),stat=istat)
if (istat /= 0) call error('readwfx','could not allocate memory for exponents',2)
allocate(m%occ(m%nmo),stat=istat)
if (istat /= 0) call error('readwfx','could not allocate memory for occupations',2)
allocate(m%c(m%nmo,m%npri),stat=istat)
if (istat /= 0) call error('readwfx','could not allocate memory for orbital coefficients',2)
! second pass
rewind(luwfn)
keyw = .false.
do while (.true.)
read(luwfn,'(A)',end=20) line
line = adjustl(line)
if (line(1:1) == "<" .and. line(2:2) /= "/") then
if (trim(line) == "<Atomic Numbers>") then
m%z = read_integers(luwfn,m%n)
keyw(1) = .true.
elseif (trim(line) == "<Nuclear Cartesian Coordinates>") then
m%x = reshape(read_reals1(luwfn,3*m%n),shape(m%x))
keyw(2) = .true.
elseif (trim(line) == "<Primitive Centers>") then
m%icenter = read_integers(luwfn,m%npri)
keyw(3) = .true.
elseif (trim(line) == "<Primitive Types>") then
m%itype = read_integers(luwfn,m%npri)
if (any(m%itype(1:m%npri) > 56)) &
call error("readwfx","primitive type not supported",2)
keyw(4) = .true.
elseif (trim(line) == "<Primitive Exponents>") then
m%e = read_reals1(luwfn,m%npri)
keyw(5) = .true.
elseif (trim(line) == "<Molecular Orbital Occupation Numbers>") then
m%occ = read_reals1(luwfn,m%nmo)
m%nelec = sum(m%occ)
keyw(6) = .true.
elseif (trim(line) == "<Molecular Orbital Primitive Coefficients>") then
read(luwfn,*)
do i = 1, m%nmo
read(luwfn,*)
read(luwfn,*)
m%c(i,:) = read_reals1(luwfn,m%npri)
enddo
keyw(7) = .true.
endif
endif
enddo
20 continue
if (any(.not.keyw)) call error("readwfx","missing array in wfx file",2)
! wavefuntion type
! 0 - closed, 1 - open, 2 - restricted open, 3 - fractional
if (m%mult == 1) then
m%wfntyp = 0
else
if (any(m%occ > 1)) then
m%wfntyp = 2
else
m%wfntyp = 1
endif
end if
close(luwfn)
end function readwfx
!> Read fchk file
function readfchk(file,egauss) result(m)
character*(mline), intent(in) :: file
real*8, intent(out) :: egauss
type(molecule) :: m
character*(mline) :: line
integer :: ityp
integer :: lp, idum, nalpha, nbeta, nshel, ncshel, lmax, nbassph, nbascar
integer :: istat, i, j, k, k1, k2, l, ifac
integer :: acent, nn, nm, nl, nc, ns, ncar, nsph
logical :: ok, isecp
logical, allocatable :: icdup(:)
integer, allocatable :: ishlt(:), ishlpri(:), ishlat(:), itemp(:,:)
real*8, allocatable :: xat(:), exppri(:), ccontr(:), pccontr(:), motemp(:), mocoef(:,:)
real*8, allocatable :: cnorm(:), cpri(:), rtemp(:,:)
real*8 :: acoef, norm
! translation between primitive ordering fchk -> postg
! 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20
! fchk: s x y z xx yy zz xy xz yz xxx yyy zzz xyy xxy xxz xzz yzz yyz xyz
! postg: s x y z xx yy zz xy xz yz xxx yyy zzz xxy xxz yyz xyy xzz yzz xyz
!
! 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35
! fchk: zzzz yzzz yyzz yyyz yyyy xzzz xyzz xyyz xyyy xxzz xxyz xxyy xxxz xxxy xxxx
! postg: xxxx yyyy zzzz xxxy xxxz xyyy yyyz xzzz yzzz xxyy xxzz yyzz xxyz xyyz xyzz
! reorder the primitives within the same shell
! typtrans(fchk) = postg
integer, parameter :: typtrans(35) = (/&
!1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20
1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 17, 14, 15, 18, 19, 16, 20,&
!21 22 23 24 25 26 27 28 29 30 31 32 33 34 35
23, 29, 32, 27, 22, 28, 35, 34, 26, 31, 33, 30, 25, 24, 21&
/)
! set title and defaults
m%name = file
m%useecp = .false.
m%wfntyp = 0
! first pass: dimensions
isecp = .false.
open(luwfn,file=file,status='old')
do while (.true.)
read(luwfn,'(A)',end=20) line
line = adjustl(line)
lp = 45
if (line(1:6) == "Charge") then
ok = isinteger(idum,line,lp)
m%charge = idum
elseif (line(1:12) == "Multiplicity") then
ok = isinteger(m%mult,line,lp)
elseif (line(1:19) == "Number of electrons") then
ok = isinteger(idum,line,lp)
m%nelec = idum
elseif (line(1:15) == "Number of atoms") then
ok = isinteger(m%n,line,lp)
elseif (line(1:25) == "Number of alpha electrons") then
ok = isinteger(nalpha,line,lp)
elseif (line(1:25) == "Number of basis functions") then
ok = isinteger(nbassph,line,lp)
elseif (line(1:24) == "Number of beta electrons") then
ok = isinteger(nbeta,line,lp)
elseif (line(1:27) == "Number of contracted shells") then
ok = isinteger(ncshel,line,lp)
elseif (line(1:26) == "Number of primitive shells") then
ok = isinteger(nshel,line,lp)
elseif (line(1:24) == "Highest angular momentum") then
ok = isinteger(lmax,line,lp)
elseif (line(1:12) == "Total Energy") then
ok = isreal(egauss,line,lp)
elseif (line(1:21) == "Beta Orbital Energies") then
m%wfntyp = 1
elseif (line(1:8) == "ECP-LMax") then
isecp = .true.
endif
enddo
20 continue
! ECPs not implemented yet
if (isecp) call error("readfchk","ECPs not supported.",1)
! Count the number of MOs
if (m%wfntyp == 0) then
m%nmo = nint(m%nelec) / 2
else if (m%wfntyp == 1) then
m%nmo = nint(m%nelec)
endif
! allocate sutff
allocate(m%occ(m%nmo),stat=istat)
if (istat /= 0) call error('readfchk','could not allocate memory for occ',2)
allocate(ishlt(ncshel),ishlpri(ncshel),ishlat(ncshel),stat=istat)
if (istat /= 0) call error('readfchk','could not allocate memory for shell data',2)
allocate(exppri(nshel),ccontr(nshel),pccontr(nshel),stat=istat)
if (istat /= 0) call error('readfchk','could not allocate memory for primitive data',2)
! type of wavefunction -> occupations
if (m%wfntyp == 1) then
m%occ = 1
else
m%occ = 2
end if
! rewind
rewind(luwfn)
! second pass
allocate(m%x(3,m%n),m%z(m%n),xat(3*m%n),stat=istat)
if (istat /= 0) call error('readfchk','could not allocate memory for geometry',2)
allocate(motemp(nbassph*m%nmo),stat=istat)
if (istat /= 0) call error('readfchk','could not allocate memory for MO coefs',2)
do while (.true.)
read(luwfn,'(A)',end=30) line
line = adjustl(line)
lp = 45
if (line(1:11) == "Shell types") then
do i = 0, (ncshel-1)/6
read(luwfn,'(6I12)',end=30) (ishlt(6*i+j),j=1,min(6,ncshel-6*i))
enddo
elseif (line(1:30) == "Number of primitives per shell") then
do i = 0, (ncshel-1)/6
read(luwfn,'(6I12)',end=30) (ishlpri(6*i+j),j=1,min(6,ncshel-6*i))
enddo
elseif (line(1:30) == "Shell to atom map") then
do i = 0, (ncshel-1)/6
read(luwfn,'(6I12)',end=30) (ishlat(6*i+j),j=1,min(6,ncshel-6*i))
enddo
elseif (line(1:29) == "Current cartesian coordinates") then
do i = 0, (3*m%n-1)/5
read(luwfn,'(5E16.8)',end=30) (xat(5*i+j),j=1,min(5,3*m%n-5*i))
enddo
elseif (line(1:14) == "Atomic numbers") then
do i = 0, (m%n-1)/6
read(luwfn,'(6I12)',end=30) (m%z(6*i+j),j=1,min(6,m%n-6*i))
enddo
elseif (line(1:19) == "Primitive exponents") then
do i = 0, (nshel-1)/5
read(luwfn,'(5E16.8)',end=30) (exppri(5*i+j),j=1,min(5,nshel-5*i))
enddo
elseif (line(1:24) == "Contraction coefficients") then
do i = 0, (nshel-1)/5
read(luwfn,'(5E16.8)',end=30) (ccontr(5*i+j),j=1,min(5,nshel-5*i))
enddo
elseif (line(1:31) == "P(S=P) Contraction coefficients") then
do i = 0, (nshel-1)/5
read(luwfn,'(5E16.8)',end=30) (pccontr(5*i+j),j=1,min(5,nshel-5*i))
enddo
elseif (line(1:21) == "Alpha MO coefficients") then
do i = 0, (nalpha*nbassph-1)/5
read(luwfn,'(5E16.8)',end=30) (motemp(5*i+j),j=1,min(5,nalpha*nbassph-5*i))
enddo
elseif (line(1:21) == "Beta MO coefficients") then
do i = 0, (nbeta*nbassph-1)/5
read(luwfn,'(5E16.8)',end=30) (motemp(nalpha*nbassph+5*i+j),j=1,min(5,nbeta*nbassph-5*i))
enddo
endif
enddo
30 continue
! we are done with the file
close(luwfn)
! unfold sp shells next
allocate(icdup(ncshel))
nshel = 0
ncshel = 0
do i = 1, size(icdup)
if (ishlt(i) == -1) then
icdup(i) = .true.
ncshel = ncshel + 2
nshel = nshel + 2 * ishlpri(i)
else
icdup(i) = .false.
ncshel = ncshel + 1
nshel = nshel + ishlpri(i)
endif
end do
! transfer the information to the temporary sp-unfolded arrays
allocate(itemp(ncshel,3),rtemp(nshel,2))
nn = 0
nm = 0
nl = 0
do i = 1, size(icdup)
if (icdup(i)) then
nn = nn + 1
itemp(nn,1) = 0
itemp(nn,2) = ishlpri(i)
itemp(nn,3) = ishlat(i)
rtemp(nl+1:nl+ishlpri(i),1) = exppri(nm+1:nm+ishlpri(i))
rtemp(nl+1:nl+ishlpri(i),2) = ccontr(nm+1:nm+ishlpri(i))
nl = nl + ishlpri(i)
nn = nn + 1
itemp(nn,1) = 1
itemp(nn,2) = ishlpri(i)
itemp(nn,3) = ishlat(i)
rtemp(nl+1:nl+ishlpri(i),1) = exppri(nm+1:nm+ishlpri(i))
rtemp(nl+1:nl+ishlpri(i),2) = pccontr(nm+1:nm+ishlpri(i))
nl = nl + ishlpri(i)
else
nn = nn + 1
itemp(nn,1) = ishlt(i)
itemp(nn,2) = ishlpri(i)
itemp(nn,3) = ishlat(i)
rtemp(nl+1:nl+ishlpri(i),1) = exppri(nm+1:nm+ishlpri(i))
rtemp(nl+1:nl+ishlpri(i),2) = ccontr(nm+1:nm+ishlpri(i))
nl = nl + ishlpri(i)
endif
nm = nm + ishlpri(i)
end do
! move the sp-unfolded information back and reallocate
deallocate(ishlt,ishlpri,ishlat,exppri,ccontr,pccontr,icdup)
allocate(ishlt(ncshel),ishlpri(ncshel),ishlat(ncshel),exppri(nshel),ccontr(nshel))
ishlt = itemp(:,1)
ishlpri = itemp(:,2)
ishlat = itemp(:,3)
exppri = rtemp(:,1)
ccontr = rtemp(:,2)
deallocate(itemp,rtemp)
! atomic coordinates
m%x = reshape(xat,shape(m%x))
deallocate(xat)
! count the number of primitives and basis functions
m%npri = 0
nbascar = 0
nbassph = 0
do i = 1, ncshel
ityp = ishlt(i)
nbascar = nbascar + nshlt(abs(ityp))
nbassph = nbassph + nshlt(ityp)
m%npri = m%npri + nshlt(abs(ishlt(i))) * ishlpri(i)
enddo
! convert spherical basis functions to Cartesian and build the mocoef
! deallocate the temporary motemp
allocate(mocoef(m%nmo,nbascar))
nc = 0
ns = 0
do j = 1, ncshel
nsph = nshlt(ishlt(j))
ncar = nshlt(abs(ishlt(j)))
if (nsph == ncar) then
do i = 1, m%nmo
mocoef(i,nc+1:nc+ncar) = motemp((i-1)*nbassph+ns+1:(i-1)*nbassph+ns+nsph)
end do
elseif (ishlt(j) == -2) then
do i = 1, m%nmo
mocoef(i,nc+1:nc+ncar) = matmul(motemp((i-1)*nbassph+ns+1:(i-1)*nbassph+ns+nsph),dsphcar)
end do
elseif (ishlt(j) == -3) then
do i = 1, m%nmo
mocoef(i,nc+1:nc+ncar) = matmul(motemp((i-1)*nbassph+ns+1:(i-1)*nbassph+ns+nsph),fsphcar)
end do
elseif (ishlt(j) == -4) then
do i = 1, m%nmo
mocoef(i,nc+1:nc+ncar) = matmul(motemp((i-1)*nbassph+ns+1:(i-1)*nbassph+ns+nsph),gsphcar_fchk)
end do
else
call error('readfchk','h and higher primitives not supported yet',2)
endif
ns = ns + nsph
nc = nc + ncar
end do
deallocate(motemp)
! Assign primitive center and type, exponents, etc.
allocate(m%icenter(m%npri),stat=istat)
if (istat /= 0) call error('readfchk','could not allocate memory for icenter',2)
allocate(m%itype(m%npri),stat=istat)
if (istat /= 0) call error('readfchk','could not allocate memory for itype',2)
allocate(m%e(m%npri),stat=istat)
if (istat /= 0) call error('readfchk','could not allocate memory for exponents',2)
allocate(m%c(m%nmo,m%npri),cpri(m%npri),stat=istat)
if (istat /= 0) call error('readfchk','could not allocate memory for coeffs',2)
! normalize the primitive coefficients without the angular part
allocate(cnorm(maxval(ishlpri)))
nm = 0
nn = 0
do i = 1, ncshel
do j = jshl0(abs(ishlt(i))), jshl1(abs(ishlt(i)))
ityp = typtrans(j)
! normalize primitive coefficients
do k = 1, ishlpri(i)
cnorm(k) = ccontr(nm+k) * gnorm(ityp,exppri(nm+k))
end do
! normalize basis function
norm = aonorm(ityp,ishlpri(i),exppri(nm+1:nm+ishlpri(i)),cnorm(1:ishlpri(i)))
! calculate and assign the normalized primitive coefficients
do k = 1, ishlpri(i)
nn = nn + 1
cpri(nn) = cnorm(k) * norm
end do
end do
nm = nm + ishlpri(i)
end do
deallocate(cnorm)
! build the wavefunction coefficients for the primitives
nn = 0
nm = 0
nl = 0
do i = 1, ncshel
do j = jshl0(abs(ishlt(i))), jshl1(abs(ishlt(i)))
ityp = typtrans(j)
nl = nl + 1
do k = 1, ishlpri(i)
nn = nn + 1
m%icenter(nn) = ishlat(i)
m%itype(nn) = ityp
m%e(nn) = exppri(nm+k)
m%c(:,nn) = cpri(nn) * mocoef(:,nl)
end do
end do
nm = nm + ishlpri(i)
end do
deallocate(ishlt,ishlpri,ishlat)
deallocate(exppri,ccontr)
deallocate(mocoef)
end function readfchk
!> Read a molden file. Different programs write molden files in
!> different ways. Right now, this routine has only been tested
!> with psi4 (only versions starting June 2016; previous versions of
!> psi4 wrote molden files differently) and orca (4.0.2). Also,
!> psi4 writes restricted open wavefunctions the same as
!> unrestricted wavefunctions, so that is not tested either, and
!> probably won't work.
function readmolden(file,egauss) result(m)
character*(mline), intent(in) :: file
real*8, intent(out) :: egauss
type(molecule) :: m
character*(mline) :: line, word, word1, word2, keyword
integer :: ncshel, nshel, nbascar, nbassph
integer :: i, j, k, l, idum, idum1, ni, nj, k1, k2
real*8 :: rdum, norm, cons
integer, allocatable :: ishlt(:), ishlpri(:), ishlat(:)
real*8, allocatable :: exppri(:), ccontr(:), motemp(:), cpri(:), mocoef(:,:), cnorm(:)
integer :: istat, nm, ityp, lnmoa, lnmob, lnmo
logical :: isang, is5d, is7f, is9g
integer :: nn, nl, nalpha, nsph, ncar, nc, ns, imoldentype
logical :: ok, isalpha
integer, parameter :: mt_psi4 = 1
integer, parameter :: mt_orca = 2
! guide to the variables in this routine:
! ncshel = number of contraction shells (# of blocks in [GTO])
! -> ishlt(icshel) = angular momentum for this shell (s=0,p=1,d=2,dsph=-2,etc.)
! -> ishlpri(icshel) = number of primitives in this shell
! -> ishlat(icshel) = atom index where this shell is based
!
! nshel = number of primitives (not counting the angular parts)
! -> exppri(ishel) = primitive exponent
! -> ccontr(ishel) = contraction coefficient for this primitive
!
! m%npri = number of primitives (including angular parts)
!
! nbassph = number of basis functions (spherical)
!
! nbascar = number of basis functions (Cartesian)
!
! lnmo = number of molecular orbitals, regardless of occupation
! m%nmo = number of occupied molecular orbitals
! -> m%occ(imo) = occupation of the molecular orbitals
!
! m%nelec = number of electrons
! nalpha = number of alpha electrons
! m%wfntyp = type of wavefunction (0 = closed, 1 = open)
! m%charge = charge
! m%mult = multiplicity
!
! translation between primitive ordering molden -> postg
! 1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20
! molden: s x y z xx yy zz xy xz yz xxx yyy zzz xyy xxy xxz xzz yzz yyz xyz
! postg: s x y z xx yy zz xy xz yz xxx yyy zzz xxy xxz yyz xyy xzz yzz xyz
!
! 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35
! molden: xxxx yyyy zzzz xxxy xxxz xyyy yyyz xzzz yzzz xxyy xxzz yyzz xxyz xyyz xyzz
! postg: xxxx yyyy zzzz xxxy xxxz xyyy yyyz xzzz yzzz xxyy xxzz yyzz xxyz xyyz xyzz
!
! h primitives and higher not supported in molden format.
!
! typtrans(molden) = postg
integer, parameter :: typtrans(35) = (/&
!1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20
1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 17, 14, 15, 18, 19, 16, 20,&
!21 22 23 24 25 26 27 28 29 30 31 32 33 34 35
21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35&
/)
line = ""
m%name = file
m%useecp = .false.
is5d = .false.
is7f = .false.
is9g = .false.
imoldentype = mt_psi4
! parse the molden file, first pass -> read dimensions prior to allocation
open(luwfn,file=file,status='old')
do while(next_keyword())
if (trim(keyword) == "title") then
read(luwfn,'(A)',end=40) line
if (index(line,"created by orca_2mkl") > 0) then
imoldentype = mt_orca
end if
else if (trim(keyword) == "atoms") then
! read the number of atoms
m%n = 0
read(luwfn,'(A)',end=40) line
do while(index(lower(line),"[") == 0 .and. len(trim(line)) > 0)
m%n = m%n + 1
read(luwfn,'(A)',end=40) line
end do
elseif (trim(keyword) == "gto") then
! read the number of shells and primitives
ncshel = 0
nshel = 0
do i = 1, m%n
read(luwfn,'(A)',end=40) line
read(luwfn,'(A)',end=40) line
do while (index(line,".") /= 0)
read (line,*) word, idum, rdum
ncshel = ncshel + 1
nshel = nshel + idum
do j = 1, idum
read(luwfn,'(A)',end=40) line
end do
read(luwfn,'(A)',end=40) line
end do
end do
elseif (trim(keyword) == "mo") then
! read the number of MOs, number of electrons, and number of alpha electrons
m%nelec = 0
nalpha = 0
m%wfntyp = -1
do while(.true.)
read(luwfn,'(A)',end=30) line
if (index(lower(line),"[") /= 0) exit
if (index(lower(line),"ene=") /= 0) then
! spin
read(luwfn,'(A)',end=30) line
if (index(lower(line),"spin=") /= 0) then
isalpha = (index(lower(line),"alpha") > 0)
end if
! occupation
read(luwfn,'(A)',end=30) line
read (line,*) word, rdum
idum = nint(rdum)
if (abs(rdum-idum) > 1d-6) &
call error('readmolden','can not do fractional occupations with molden',2)
if (idum == 1 .or. idum == 2) then
m%nelec = m%nelec + idum
if (isalpha) then
nalpha = nalpha + idum
endif
if (m%wfntyp < 0 .and. idum == 2) m%wfntyp = 0
if (idum == 1) m%wfntyp = 1
elseif (idum == 0) then
! do not read MOs with zero occupation
continue
else
call error('readmolden','wrong integer occupation',2)
endif
end if
end do
30 continue
elseif (trim(keyword) == "5d" .or. trim(keyword) == "5d7f") then
is5d = .true.
is7f = .true.
read(luwfn,'(A)',end=40) line
elseif (trim(keyword) == "5d10f") then
is5d = .true.