How do I execute command only if a previous command failed?

[dimitarvp]

I want to have something like just up that checks if Docker is started and if not, start it, and then proceed to run docker-compose.

Here is what I have:

[macos]
@docker:
  #!/usr/bin/env bash
  colima status
  if [ $? -ne 0 ]; then
    echo "Colima not running"
    colima start --memory 12 --cpu 16 --disk 200
  else
    echo "Colima is running"
  fi

I am on macOS. Running just docker yields this:

❯ just docker
#!/usr/bin/env bash
colima status
if [ $? -ne 0 ]; then
  echo "Colima not running"
  colima start --memory 12 --cpu 16 --disk 200
else
  echo "Colima is running"
fi
FATA[0000] colima is not running
Colima not running

Then it proceeds to start it and it starts. It works fine the second time around, too: it doesn't attempt to start it again, while printing the status message.

My questions:

• Is there a way to do this without sh/bash scripting? I looked into the docs but was unable to find anything about executing a command, suppressing its output and then asking for its exit code.
• If this conditional flow cannot be achieved by just and I stick with the bash script fragment then is there a way to suppress the output of everything except the one of colima start?

EDIT: Oops, I just realized I could just do colima status 2>/dev/null. Still, I'd like to see if I can achieve the rest of what I asked.

[dimitarvp]

I am not even sure what did I do so differently but here's a full Justfile that does what I want. I am not happy that I have to resort to bash snippets but oh well. Feel free to copy for your use:

default:
  @just --list

[macos]
start_docker:
  #!/usr/bin/env bash
  if ! colima status 2>/dev/null; then
    echo "Colima is not running, starting it now"
    colima start --memory 12 --cpu 16 --disk 200
  else
    echo "Colima is already running"
  fi

[linux]
start_docker:
  #!/usr/bin/env bash
  if ! systemctl is-active -q docker.service; then
    sudo systemctl start docker
  else
    echo "Docker is already running"
  fi

[windows]
start_docker:
  error("Windows is not supported.")

[macos]
stop_docker:
  #!/usr/bin/env bash
  if colima status 2>/dev/null; then
    echo "Colima is running, stopping it now"
    colima stop
  else
    echo "Colima is not running"
  fi

[linux]
stop_docker:
  #!/usr/bin/env bash
  if systemctl is-active -q docker.service; then
    sudo systemctl stop docker
  else
    echo "Docker is not running"
  fi

[windows]
stop_docker:
  error("Windows is not supported.")

up:
  docker-compose -f {{justfile_directory()}}/dev/docker/docker-compose.yaml up -d

down:
  docker-compose -f {{justfile_directory()}}/dev/docker/docker-compose.yaml down

logs:
  docker-compose -f {{justfile_directory()}}/dev/docker/docker-compose.yaml logs --follow

all_up: start_docker up

all_down: down stop_docker