build.gradle

buildscript {
    repositories {
        google()
    }
    // these dependencies are used by gradle plugins, not by the project
    dependencies {
        // Android gradle plugin
        classpath 'com.android.tools.build:gradle:7.4.2'
    }
}

plugins {
    // check for updates of gradle plugin dependencies
    id 'com.github.ben-manes.versions' version '0.46.0'
}

allprojects {
    repositories {
        maven { url "https://jitpack.io" }
        mavenCentral()
        google()
    }
}

apply plugin: 'com.android.application'

android {
    namespace 'menion.android.whereyougo'

    compileSdk 31

    defaultConfig {
        applicationId "menion.android.whereyougo"

        minSdk 21
        //noinspection OldTargetApi
        targetSdk 31

        versionName versionNameFromDate()
        versionCode versionCodeFromDate(0)

        // include only those language resources from libraries that we actively maintain ourselves in the translation project
        // when changed here - also change in array.xml/strings_pref_languages.xml is necessary
        // not yet enough strings translated (>40%): "sl","sv"
        resConfigs 'en', 'ar', 'ca', 'cs', 'da', 'de', 'el', 'es', 'fi', 'fr', 'hu', 'it', 'ja', 'ko', 'nb', 'nl', 'pl', 'pt-rBR', 'pt-rPT', 'ru', 'sk', 'tr'
    }

    // define ndk version to use local the same version as on CI
    ndkVersion '21.0.6113669'

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
        }
        debug {
            debuggable true

            // debug build name contains git commit for better reproduction of bugs
            versionNameSuffix "-" + GitCommit.currentShort() + " developer build"
        }
        nightly {
            def nightlyName = System.getenv('NB') // NB, NB1, ...
            versionNameSuffix "-$nightlyName-" + GitCommit.currentShort()
           // use release version of source code library dependencies
            matchingFallbacks = ['release']
        }
    }

    lint {
        abortOnError false
        checkReleaseBuilds false
    }

    packagingOptions {
        // exclude ARMEABI native so file, ARMEABI has been removed in NDK r17
        jniLibs {
            excludes += ['lib/armeabi/**']
        }
        resources {
            excludes += ['lib/armeabi/**']
        }
    }

    // special version code for nightly and rc builds
    applicationVariants.all { variant ->
        if (variant.buildType.name == 'nightly') {
            variant.outputs.all {
                setVersionCodeOverride(versionCodeFromDate(10000000))
            }
        }
    }
}

dependencies {
    fileTree(dir: 'libs', include: ['*.jar'])

    // Legacy Support Library
    implementation 'androidx.legacy:legacy-support-v4:1.0.0'

    // Settings Library + Appcompat for AndroidX
    implementation 'androidx.appcompat:appcompat:1.2.0'
    implementation 'androidx.preference:preference:1.1.1'

    // Locus Maps integration
    implementation 'com.asamm:locus-api-android:0.9.50'

    // openwig@cgeo
    implementation 'com.github.cgeo:openwig:1.0.0'

    // File select dialog
    implementation 'com.github.jfmdev:aFileDialog:v1.0.6'

    //
    implementation 'com.github.jspricke.mapsforge-map-whereyougo:mapsforge-map:75d7c20'

    // barcode scanner
    // v4.x: Minimum SDK version 24, downgradable to 14 by using zxing:core 3.3.0, uses androidx
    implementation 'com.journeyapps:zxing-android-embedded:4.1.0'
    // downgrade zxing:core to 3.3.0 or earlier for Android 14+ support
    // AndroidManifest.xml: use tools:overrideLibrary="com.google.zxing.client.android" to force usage
    //noinspection GradleDependency
    implementation 'com.google.zxing:core:3.3.0'

    // Okhttp network access
    implementation 'com.squareup.okhttp3:okhttp:4.10.0'

    // ani gif support
    // minSdk=17 from version 1.2.16
    implementation 'pl.droidsonroids.gif:android-gif-drawable:1.2.15'

    // Material Components
    implementation 'com.google.android.material:material:1.3.0'
}

/*
 * version number from the current date, plus an offset defined by the build type (to define which versions overwrite each other)
 */
static def versionCodeFromDate(offset) {
    def date = new Date()
    def formattedDate = date.format('yyyyMMdd')
    return Integer.valueOf(formattedDate) + offset
}

/*
 * version name based on current date
 */
static def versionNameFromDate() {
    def date = new Date()
    def formattedDate = date.format('yyyy.MM.dd')
    return formattedDate
}

class GitCommit {
    static String commitId

    /*
     * get the most recent git commit ID
     */
    static String current() {
        if (commitId == null) {
            Process p = ['git', 'rev-parse', 'HEAD'].execute()
            if (p.waitFor() != 0) {
                throw new Error("Unable to get git commit id: " + p.err.text)
            }
            commitId = p.text.trim()
        }
        return commitId
    }

    static String currentShort() {
        return current().substring(0, 7)
    }
}

/*
 * Configuration for dependencyUpdates, see https://github.com/ben-manes/gradle-versions-plugin
 */
tasks.named('dependencyUpdates') {
    checkForGradleUpdate = true
    revision = "release"
    gradleReleaseChannel = "current"
}