-
Notifications
You must be signed in to change notification settings - Fork 25
/
configs.jl
317 lines (257 loc) · 9.16 KB
/
configs.jl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
module Configs
export read_options, has_comonicon_toml, @asset_str
using TOML
using Configurations
using PackageCompiler: DEFAULT_EMBEDDING_WRAPPER
using Pkg
struct Asset
package::Union{Nothing,String}
path::String
end
function Asset(s::String)
parts = strip.(split(s, ":"))
if length(parts) == 1
Asset(nothing, parts[1])
elseif length(parts) == 2
Asset(parts[1], parts[2])
else
error("invalid syntax for asset string: $s")
end
end
macro asset_str(s::String)
return Asset(s)
end
function Base.show(io::IO, ::MIME"text/plain", x::Asset)
print(io, "asset\"")
if x.package !== nothing
printstyled(io, x.package, ": "; color = :green)
end
printstyled(io, x.path, "\""; color = :cyan)
end
Base.convert(::Type{Asset}, s::String) = Asset(s)
function get_path(m::Module, x::Asset)
isnothing(x.package) && return pkgdir(m, x.path)
ctx = Pkg.Types.Context()
haskey(ctx.env.project.deps, x.package) || error("asset $x not in current project dependencies")
uuid = ctx.env.project.deps[x.package]
pkgid = Base.PkgId(uuid, x.package)
origin = get(Base.pkgorigins, pkgid, nothing)
return joinpath(dirname(dirname(origin.path)), x.path)
end
"""
Install
Installation configurations.
## Keywords
- `path`: installation path.
- `completion`: set to `true` to install shell auto-completion scripts.
- `quiet`: print logs or not, default is `false`.
- `compile`: julia compiler option for CLIs if not built as standalone application, default is "min". See help section of `julia --compile` for more details.
- `optimize`: julia compiler option for CLIs if not built as standalone application, default is `2`. See help section of `julia --optimize` for more details.
- `nthreads`: julia compiler option for CLIs if not built as standalone application, default is `1`.
"""
@option struct Install
path::String = first(DEPOT_PATH)
completion::Bool = true
quiet::Bool = false
compile::String = "yes"
optimize::Int = 2
nthreads::Union{Int,String} = 1
end
"""
Precompile
Precompilation files for `PackageCompiler`.
## Keywords
- `execution_file`: precompile execution file.
- `statements_file`: precompile statements file.
"""
@option struct Precompile
execution_file::Vector{String} = String[]
statements_file::Vector{String} = String[]
end
# See https://github.com/JuliaCI/julia-buildbot/blob/489ad6dee5f1e8f2ad341397dc15bb4fce436b26/master/inventory.py
function default_app_cpu_target()
if Sys.ARCH === :i686
return "pentium4;sandybridge,-xsaveopt,clone_all"
elseif Sys.ARCH === :x86_64
return "generic;sandybridge,-xsaveopt,clone_all;haswell,-rdrnd,base(1)"
elseif Sys.ARCH === :arm
return "armv7-a;armv7-a,neon;armv7-a,neon,vfp4"
elseif Sys.ARCH === :aarch64
return "generic" # is this really the best here?
elseif Sys.ARCH === :powerpc64le
return "pwr8"
else
return "generic"
end
end
"""
SysImg
System image build configurations.
## Keywords
- `path`: system image path to generate into, default is "deps/lib".
- `incremental`: set to `true` to build incrementally, default is `true`.
- `filter_stdlibs`: set to `true` to filter out unused stdlibs, default is `false`.
- `cpu_target`: cpu target to build, default is `PackageCompiler.default_app_cpu_target()`.
- `precompile`: precompile configurations, see [`Precompile`](@ref), default is `Precompile()`.
"""
@option struct SysImg
path::String = "deps"
incremental::Bool = true
filter_stdlibs::Bool = false
cpu_target::String = default_app_cpu_target()
precompile::Precompile = Precompile()
end
"""
Download
Download information.
## Keywords
- `host`: where are the tarballs hosted, default is "github.com"
- `user`: required, user name on the host.
- `repo`: required, repo name on the host.
!!! note
Currently this only supports github, and this is considered experimental.
"""
@option struct Download
host::String = "github.com"
user::String
repo::String
end
"""
Application
Application build configurations.
## Keywords
- `path`: application build path, default is "build".
- `incremental`: set to `true` to build incrementally, default is `true`.
- `filter_stdlibs`: set to `true` to filter out unused stdlibs, default is `false`.
- `cpu_target`: cpu target to build, default is `PackageCompiler.default_app_cpu_target()`.
- `precompile`: precompile configurations, see [`Precompile`](@ref), default is `Precompile()`.
- `c_driver_program`: driver program.
"""
@option struct Application
path::String = "build"
assets::Vector{Asset} = Asset[]
incremental::Bool = false
filter_stdlibs::Bool = true
include_lazy_artifacts::Bool = true
cpu_target::String = default_app_cpu_target()
precompile::Precompile = Precompile()
c_driver_program::String = String(DEFAULT_EMBEDDING_WRAPPER)
shell_completions::Vector{String} = ["zsh"]
end
"""
Command
Configs for Command execution.
# Keywords
- `color`: whether print with color in help page, default is `true`.
- `static`: whether genrate help info at compile time,
the format won't be adaptive to displaysize anymore,
if `true`, default is `true`.
- `width`: if `static=true`, `width` is used to set the static size of expected terminal.
- `dash`: whether parse `--` seperator, default is `true`.
- `plugin`: parse `<main CLI name>-<plugin>` for CLI plugin, default is `false`.
"""
@option struct Command
color::Bool = true
static::Bool = true
width::Int = 120
dash::Bool = true
plugin::Bool = false
end
"""
Comonicon
Build configurations for Comonicon. One can set this option
via `Comonicon.toml` under the root path of a Julia
project directory and read in using [`read_configs`](@ref).
## Keywords
- `name`: required, the name of CLI file to install.
- `command`: configs for command parsing.
- `install`: installation options, see also [`Install`](@ref).
- `sysimg`: system image build options, see also [`SysImg`](@ref).
- `download`: download options, see also [`Download`](@ref).
- `application`: application build options, see also [`Application`](@ref).
"""
@option struct Comonicon
name::String
command::Command = Command()
install::Install = Install()
sysimg::Maybe{SysImg} = nothing
download::Union{Download,Nothing} = nothing
application::Union{Application,Nothing} = nothing
end
function validate(options::Comonicon)
if options.sysimg !== nothing
isabspath(options.sysimg.path) && error("system image path must be project relative")
end
if options.application !== nothing
isabspath(options.application.path) && error("application build path must project relative")
end
return
end
"""
find_comonicon_toml(path::String, files=["Comonicon.toml", "JuliaComonicon.toml"])
Find `Comonicon.toml` or `JuliaComonicon.toml` in given path.
"""
function find_comonicon_toml(path::String, files = ["Comonicon.toml", "JuliaComonicon.toml"])
# user input file path
basename(path) in files && return path
# user input dir path
for file in files
path = joinpath(path, file)
if ispath(path)
return path
end
end
return
end
"""
read_toml(path::String)
Read `Comonicon.toml` or `JuliaComonicon.toml` in given path.
"""
function read_toml(path::String)
file = find_comonicon_toml(path)
file === nothing && return Dict{String,Any}()
return TOML.parsefile(file)
end
"""
read_toml(mod::Module)
Read `Comonicon.toml` or `JuliaComonicon.toml` in given module's project path.
"""
function read_toml(mod::Module)
path = pkgdir(mod)
path === nothing && return Dict{String,Any}()
return read_toml(path)
end
function has_comonicon_toml(m::Module)
path = pkgdir(m)
isnothing(path) && return false
!isnothing(find_comonicon_toml(path))
end
"""
read_options(comonicon; kwargs...)
Read in Comonicon build options. The argument `comonicon` can be:
- a module of a Comonicon CLI project.
- a path to a Comonicon CLI project that contains either `JuliaComonicon.toml` or `Comonicon.toml`.
- a path to a Comonicon CLI build configuration file named either `JuliaComonicon.toml` or `Comonicon.toml`.
In some cases, you might want to change the configuration written in the TOML file temporarily, e.g for writing
build tests etc. In this case, you can modify the configuration using corresponding keyword arguments.
keyword arguments of [`Application`](@ref) and [`SysImg`](@ref) are the same, thus keys like `filter_stdlibs`
are considered ambiguous in `read_options`, but you can specifiy them by specifiy the specific [`Application`](@ref)
or [`SysImg`](@ref) object, e.g
```julia
read_options(MyCLI; sysimg=SysImg(filter_stdlibs=false))
```
See also [`Comonicon`](@ref), [`Install`](@ref), [`SysImg`](@ref), [`Application`](@ref),
[`Download`](@ref), [`Precompile`](@ref).
"""
function read_options(m::Union{Module,String}; kwargs...)
d = read_toml(m)
if !haskey(d, "name")
d["name"] = default_cmd_name(m)
end
options = from_dict(Comonicon, d; kwargs...)
validate(options)
return options
end
default_cmd_name(m::Module) = lowercase(string(nameof(m)))
default_cmd_name(m) = error("command name is not specified")
end