Setting a value of a nested path from for loop in a tool.

[iilyak]

moving conversation from an issue #1276

I have a list of users under _users key. Each user is a structure which has a _ssh_authorized_keys key. The _ssh_authorized_keys is a list. My goal is to develop a cue tool which would inject the ssh_key into _users[name]._ssh_authorized_keys[*].

Here is the code structure

command: "gen": {
	for user in _users {
		for _key in user._ssh_authorized_keys if _key.key == "{generate}" {
			"key-\(user.name)": file.Read & {
				filename: "identities/\(user.name).pub"
				contents: string
			}
		}
		// how do I append a new value into `ssh_authorized_keys` for each key for each user
	}
}

I am trying to produce the following output to the console.

users:
  - name: user1
    ssh-authorized-keys:
      - ssh-ed25519 AAAACuser1......1 user1
      - ssh-ed25519 AAAACuser1......2 user1
  - name: user2
    ssh-authorized-keys:
      - ssh-ed25519 AAAACuser2.....1 user2
      - ssh-ed25519 AAAACuser2......2 user2

given the:

#ssh_key: {
	key: string
	type: "ed25519" | "rsa" | "ecdsa"
}

let generate = #ssh_key & {key: "{generate}", type: "ed25519"}

#user: {
	name: string
	_sudo: bool
	shell: "/bin/bash"
	_ssh_authorized_keys: [generate]
}

_users: [
	#user & {name: "user1", _sudo: true, _ssh_authorized_keys: [generate]},
	#user & {name: "user2", _sudo: true},
	#user & {name: "user3", _sudo: false}
]

Questions:

• how to refer to a path to assign values (_users[user.name]._ssh_authorized_keys: "something" doesn't work)?
• how to use "key-(user.name)" in a reference ("key-\(user.name)".key doesn't work)?
• how to iterate array and get current index so I can use _users[idx] to refer to the user structure?

[iilyak]

I also tried this

	for user_idx, user in _users {
		for key_idx, _key in user._ssh_authorized_keys if _key.key == "{generate}" {
			_users[user_idx]._ssh_authorized_keys[key_idx]: file.Read & {
				filename: "identities/\(user.name).pub"
				contents: gen["key-\(user.name)"].contents
			}
	       }
        }

the result is

missing ',' in struct literal:
    ./cloud_init_tool.cue:21:50

[verdverm]

While this won't answer your first stated goal, hopefully it answers your 3 questions.

For your first question, you can use a: b: "foo" to set nested fields in a single line. You won't be able to do this in a loop (comprehension) to set outer scopes.

For Q2, see F3, you want to use ["\(name)"] to access with interpolation, F4 shows without. It seem interpolation doesn't work without the brackets.

For Q3, see F1

package main

#file: {
        name: string
        content: string
}

files: [...#file] & [
        { name: "a" },
        { name: "b" },
]

F1: [for i, f in files { "i": i, "name": files[i].name }]

F2: {
        for f in files {
                "file-\(f.name)": f
        }
}

F3: F2["file-\(files[0].name)"]
F4: F2."file-a"

You'll probably want to build up the data within the commands, and then use encoding/yaml and cli.Print or file.Write to get the final user details out.

Something like this perhaps (combined with the above):

package main

import (
        "encoding/yaml"

        "tool/cli"
        "tool/file"
)

command: gen: {
        results: {
                for f in files {
                        "file-\(f.name)": file.Read & {
                                filename: "\(f.name).txt"
                                contents: string
                        }
                }
        }

        Files: [ for f in files {
                f & { contents: results["file-\(f.name)"].contents }
        }]

        print: cli.Print & {
                text: yaml.Marshal(Files)
        }
}

[verdverm]

I should add, if you are open to writing a Go program, there is a lot more flexibility and possibility.