-
Notifications
You must be signed in to change notification settings - Fork 5
/
build.gradle
141 lines (124 loc) · 4.01 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
/*
* Copyright 2018 Infostellar, Inc.
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
* http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
buildscript {
repositories {
mavenCentral()
}
dependencies {
classpath 'com.google.protobuf:protobuf-gradle-plugin:0.8.6'
}
}
plugins {
id 'com.github.blindpirate.gogradle' version '0.10'
}
repositories {
jcenter()
mavenCentral()
maven {
url = 'https://oss.jfrog.org/libs-snapshot'
}
}
apply plugin: 'java' // Required by com.google.protobuf but we don't compile Java here.
apply plugin: 'com.google.protobuf'
golang {
packagePath = 'github.com/infostellarinc/go-genproto'
}
dependencies {
protobuf 'com.stellarstation.api:stellarstation-api:0.0.9-SNAPSHOT'
}
sourceSets {
main {
proto {
// A source directory must be specified for protobuf-gradle-plugin to work, but since we have
// no sources in this repository we just set it to an empty directory.
srcDirs = [file('build/proto-src')]
}
}
}
protobuf {
protoc {
// Download from repositories
artifact = 'com.google.protobuf:protoc:3.6.0'
}
generateProtoTasks {
all().each {task ->
task.plugins {
go {
option 'plugins=grpc'
}
}
task.builtins {
remove java
}
}
}
plugins {
go {
path = file('.gogradle/project_gopath/bin/protoc-gen-go')
}
}
}
task installProtocGoPlugin(type: com.github.blindpirate.gogradle.Go) {
go 'get -u github.com/golang/protobuf/protoc-gen-go'
}
task installProtoWrap(type: com.github.blindpirate.gogradle.Go) {
go 'get -u github.com/square/goprotowrap/cmd/protowrap'
}
afterEvaluate {
tasks.generateProto.dependsOn tasks.clean, installProtocGoPlugin, installProtoWrap
tasks.assemble.dependsOn tasks.generateProto
// Hack around golang protobuf plugin not supporting compiling multiple packages at the same
// time. We use the protowrap wrapper which does support it and hack it into the generateProto
// task.
def generateProto = tasks.generateProto
// We need to round-trip through either doFirst or doLast so Closure is converted to Action.
// We add it to the last and pop it off and insert where we want it.
generateProto.doLast {
def protocPath = protobuf.tools.protoc.path
def protowrapPath = file('.gogradle/project_gopath/bin/protowrap')
def runProtowrap = file("${buildDir}/scripts/run-protowrap.sh")
runProtowrap.parentFile.mkdirs()
runProtowrap.text = """
#!/usr/bin/env sh
${protowrapPath} --protoc_command=${protocPath} \$@
"""
runProtowrap.executable = true
project.protobuf.tools.protoc.path = runProtowrap
}
def hackProtoWrap = generateProto.actions.pop()
// HACK(anuraaga): This is dependent on gradle-protobuf-plugin implementation details. Protoc
// resolution happens here so we insert our hack after it.
generateProto.actions.addAll(1, hackProtoWrap)
generateProto.doFirst {
mkdir file('build/proto-src')
}
generateProto.doLast {
copy {
from file('build/generated/source/proto/main/go/stellarstation')
into projectDir
}
}
}
tasks.clean.doFirst {
delete file('api')
}
wrapper {
version = '4.9'
distributionType = 'ALL'
}
// protobuf-gradle-plugin always apply Java plugin, but we don't need it.
tasks.compileJava.enabled = false
tasks.compileTestJava.enabled = false