-
Notifications
You must be signed in to change notification settings - Fork 723
/
TxBody.hs
3749 lines (3237 loc) · 148 KB
/
TxBody.hs
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
{-# LANGUAGE DataKinds #-}
{-# LANGUAGE DeriveGeneric #-}
{-# LANGUAGE DerivingVia #-}
{-# LANGUAGE DisambiguateRecordFields #-}
{-# LANGUAGE EmptyCase #-}
{-# LANGUAGE FlexibleContexts #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE GADTs #-}
{-# LANGUAGE GeneralizedNewtypeDeriving #-}
{-# LANGUAGE NamedFieldPuns #-}
{-# LANGUAGE PatternSynonyms #-}
{-# LANGUAGE RankNTypes #-}
{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE StandaloneDeriving #-}
{-# LANGUAGE TypeApplications #-}
{-# LANGUAGE TypeFamilies #-}
{-# LANGUAGE ViewPatterns #-}
-- | Transaction bodies
--
module Cardano.Api.TxBody (
parseTxId,
-- * Transaction bodies
TxBody(.., TxBody),
makeTransactionBody,
TxBodyContent(..),
TxBodyError(..),
TxBodyScriptData(..),
TxScriptValidity(..),
TxScriptValiditySupportedInEra(..),
ScriptValidity(..),
scriptValidityToIsValid,
isValidToScriptValidity,
scriptValidityToTxScriptValidity,
txScriptValidityToIsValid,
txScriptValidityToScriptValidity,
-- * Transaction Ids
TxId(..),
getTxId,
getTxIdShelley,
-- * Transaction inputs
TxIn(..),
TxIx(..),
genesisUTxOPseudoTxIn,
-- * Transaction outputs
CtxTx, CtxUTxO,
TxOut(..),
TxOutValue(..),
TxOutDatum(TxOutDatumNone, TxOutDatumHash, TxOutDatumInTx, TxOutDatumInline),
toCtxUTxOTxOut,
lovelaceToTxOutValue,
prettyRenderTxOut,
txOutValueToLovelace,
txOutValueToValue,
parseHash,
TxOutInAnyEra(..),
txOutInAnyEra,
-- * Other transaction body types
TxInsCollateral(..),
TxInsReference(..),
TxReturnCollateral(..),
TxTotalCollateral(..),
TxFee(..),
TxValidityLowerBound(..),
TxValidityUpperBound(..),
TxMetadataInEra(..),
TxAuxScripts(..),
TxExtraKeyWitnesses(..),
TxWithdrawals(..),
TxCertificates(..),
TxUpdateProposal(..),
TxMintValue(..),
-- ** Building vs viewing transactions
BuildTxWith(..),
BuildTx,
ViewTx,
-- * Era-dependent transaction body features
CollateralSupportedInEra(..),
MultiAssetSupportedInEra(..),
OnlyAdaSupportedInEra(..),
TxFeesExplicitInEra(..),
TxFeesImplicitInEra(..),
ValidityUpperBoundSupportedInEra(..),
ValidityNoUpperBoundSupportedInEra(..),
ValidityLowerBoundSupportedInEra(..),
TxMetadataSupportedInEra(..),
AuxScriptsSupportedInEra(..),
TxExtraKeyWitnessesSupportedInEra(..),
ScriptDataSupportedInEra(..),
WithdrawalsSupportedInEra(..),
CertificatesSupportedInEra(..),
UpdateProposalSupportedInEra(..),
TxTotalAndReturnCollateralSupportedInEra(..),
-- ** Feature availability functions
collateralSupportedInEra,
multiAssetSupportedInEra,
txFeesExplicitInEra,
validityUpperBoundSupportedInEra,
validityNoUpperBoundSupportedInEra,
validityLowerBoundSupportedInEra,
txMetadataSupportedInEra,
auxScriptsSupportedInEra,
extraKeyWitnessesSupportedInEra,
scriptDataSupportedInEra,
withdrawalsSupportedInEra,
certificatesSupportedInEra,
updateProposalSupportedInEra,
txScriptValiditySupportedInShelleyBasedEra,
txScriptValiditySupportedInCardanoEra,
totalAndReturnCollateralSupportedInEra,
-- * Inspecting 'ScriptWitness'es
AnyScriptWitness(..),
ScriptWitnessIndex(..),
renderScriptWitnessIndex,
collectTxBodyScriptWitnesses,
mapTxScriptWitnesses,
-- * Conversion to inline data
scriptDataToInlineDatum,
-- * Internal conversion functions & types
toByronTxId,
toShelleyTxId,
toShelleyTxIn,
toShelleyTxOut,
toShelleyTxOutAny,
fromShelleyTxId,
fromShelleyTxIn,
fromShelleyTxOut,
toAlonzoRdmrPtr,
fromAlonzoRdmrPtr,
fromByronTxIn,
fromLedgerTxOuts,
renderTxIn,
-- * Misc helpers
calculateExecutionUnitsLovelace,
-- * Data family instances
AsType(AsTxId, AsTxBody, AsByronTxBody, AsShelleyTxBody, AsMaryTxBody),
) where
import Prelude
import Control.Applicative (some)
import Control.Monad (guard)
import Data.Aeson (object, withObject, withText, (.:), (.:?), (.=))
import qualified Data.Aeson as Aeson
import qualified Data.Aeson.Key as Aeson
import qualified Data.Aeson.KeyMap as KeyMap
import Data.Aeson.Types (ToJSONKey (..), toJSONKeyText)
import qualified Data.Aeson.Types as Aeson
import Data.Bifunctor (first)
import Data.ByteString (ByteString)
import qualified Data.ByteString.Char8 as BSC
import qualified Data.ByteString.Lazy as LBS
import Data.Foldable (for_, toList)
import Data.Function (on)
import Data.List (intercalate, sortBy)
import qualified Data.List.NonEmpty as NonEmpty
import Data.Map.Strict (Map)
import qualified Data.Map.Strict as Map
import Data.Maybe (fromMaybe, maybeToList)
import Data.Scientific (toBoundedInteger)
import qualified Data.Sequence.Strict as Seq
import Data.Set (Set)
import qualified Data.Set as Set
import Data.String
import Data.Text (Text)
import qualified Data.Text as Text
import Data.Type.Equality (TestEquality (..), (:~:) (Refl))
import Data.Word (Word16, Word32, Word64)
import GHC.Generics
import GHC.Records (HasField (..))
import Text.Parsec ((<?>))
import qualified Text.Parsec as Parsec
import qualified Text.Parsec.Language as Parsec
import qualified Text.Parsec.String as Parsec
import qualified Text.Parsec.Token as Parsec
import Cardano.Binary (Annotated (..), reAnnotate, recoverBytes)
import qualified Cardano.Binary as CBOR
import qualified Cardano.Crypto.Hash.Class as Crypto
import qualified Cardano.Ledger.Serialization as CBOR (decodeNullMaybe, encodeNullMaybe)
import Cardano.Slotting.Slot (SlotNo (..))
import qualified Cardano.Chain.Common as Byron
import qualified Cardano.Chain.UTxO as Byron
import qualified Cardano.Crypto.Hashing as Byron
import qualified Cardano.Ledger.Address as Shelley
import qualified Cardano.Ledger.AuxiliaryData as Ledger (hashAuxiliaryData)
import Cardano.Ledger.BaseTypes (StrictMaybe (..), maybeToStrictMaybe)
import qualified Cardano.Ledger.BaseTypes as Ledger
import qualified Cardano.Ledger.Coin as Ledger
import qualified Cardano.Ledger.Core as Core
import qualified Cardano.Ledger.Core as Ledger
import qualified Cardano.Ledger.Credential as Shelley
import Cardano.Ledger.Crypto (StandardCrypto)
import qualified Cardano.Ledger.Era as Ledger
import qualified Cardano.Ledger.Keys as Shelley
import qualified Cardano.Ledger.SafeHash as SafeHash
import qualified Cardano.Ledger.Shelley.Constraints as Ledger
import qualified Cardano.Ledger.Shelley.Genesis as Shelley
import qualified Cardano.Ledger.Shelley.Metadata as Shelley
import qualified Cardano.Ledger.Shelley.Tx as Shelley
import qualified Cardano.Ledger.Shelley.TxBody as Shelley
import qualified Cardano.Ledger.TxIn as Ledger
import qualified Cardano.Ledger.Mary.Value as Mary
import qualified Cardano.Ledger.ShelleyMA.AuxiliaryData as Allegra
import qualified Cardano.Ledger.ShelleyMA.AuxiliaryData as Mary
import qualified Cardano.Ledger.ShelleyMA.TxBody as Allegra
import qualified Cardano.Ledger.ShelleyMA.TxBody as Mary
import Cardano.Ledger.Val (isZero)
import qualified Cardano.Ledger.Alonzo as Alonzo
import qualified Cardano.Ledger.Alonzo.Data as Alonzo
import qualified Cardano.Ledger.Alonzo.Language as Alonzo
import qualified Cardano.Ledger.Alonzo.PParams as Alonzo
import qualified Cardano.Ledger.Alonzo.Scripts as Alonzo
import qualified Cardano.Ledger.Alonzo.Tx as Alonzo
import qualified Cardano.Ledger.Alonzo.TxBody as Alonzo
import qualified Cardano.Ledger.Alonzo.TxWitness as Alonzo
import qualified Cardano.Ledger.Babbage as Babbage
import qualified Cardano.Ledger.Babbage.PParams as Babbage
import qualified Cardano.Ledger.Babbage.TxBody as Babbage
import Ouroboros.Consensus.Shelley.Eras (StandardAllegra, StandardAlonzo, StandardBabbage,
StandardMary, StandardShelley)
import Cardano.Api.Address
import Cardano.Api.Certificate
import Cardano.Api.Eras
import Cardano.Api.Error
import Cardano.Api.HasTypeProxy
import Cardano.Api.Hash
import Cardano.Api.KeysByron
import Cardano.Api.KeysShelley
import Cardano.Api.NetworkId
import Cardano.Api.ProtocolParameters
import Cardano.Api.Script
import Cardano.Api.ScriptData
import Cardano.Api.SerialiseCBOR
import Cardano.Api.SerialiseJSON
import Cardano.Api.SerialiseRaw
import Cardano.Api.SerialiseTextEnvelope
import Cardano.Api.SerialiseUsing
import Cardano.Api.TxMetadata
import Cardano.Api.Utils
import Cardano.Api.Value
import Cardano.Api.ValueParser
{- HLINT ignore "Redundant flip" -}
{- HLINT ignore "Use section" -}
-- | Indicates whether a script is expected to fail or pass validation.
data ScriptValidity
= ScriptInvalid -- ^ Script is expected to fail validation.
-- Transactions marked as such can include scripts that fail validation.
-- Such transactions may be submitted to the chain, in which case the
-- collateral will be taken upon on chain script validation failure.
| ScriptValid -- ^ Script is expected to pass validation.
-- Transactions marked as such cannot include scripts that fail validation.
deriving (Eq, Show)
instance ToCBOR ScriptValidity where
toCBOR = toCBOR . scriptValidityToIsValid
instance FromCBOR ScriptValidity where
fromCBOR = isValidToScriptValidity <$> fromCBOR
scriptValidityToIsValid :: ScriptValidity -> Alonzo.IsValid
scriptValidityToIsValid ScriptInvalid = Alonzo.IsValid False
scriptValidityToIsValid ScriptValid = Alonzo.IsValid True
isValidToScriptValidity :: Alonzo.IsValid -> ScriptValidity
isValidToScriptValidity (Alonzo.IsValid False) = ScriptInvalid
isValidToScriptValidity (Alonzo.IsValid True) = ScriptValid
-- | A representation of whether the era supports tx script validity.
--
-- The Mary and subsequent eras support script validity.
--
data TxScriptValidity era where
TxScriptValidityNone :: TxScriptValidity era
-- | Tx script validity is supported in transactions in the 'Alonzo' era onwards.
TxScriptValidity
:: TxScriptValiditySupportedInEra era
-> ScriptValidity
-> TxScriptValidity era
deriving instance Eq (TxScriptValiditySupportedInEra era)
deriving instance Show (TxScriptValiditySupportedInEra era)
data TxScriptValiditySupportedInEra era where
TxScriptValiditySupportedInAlonzoEra :: TxScriptValiditySupportedInEra AlonzoEra
TxScriptValiditySupportedInBabbageEra :: TxScriptValiditySupportedInEra BabbageEra
deriving instance Eq (TxScriptValidity era)
deriving instance Show (TxScriptValidity era)
txScriptValiditySupportedInCardanoEra :: CardanoEra era -> Maybe (TxScriptValiditySupportedInEra era)
txScriptValiditySupportedInCardanoEra ByronEra = Nothing
txScriptValiditySupportedInCardanoEra ShelleyEra = Nothing
txScriptValiditySupportedInCardanoEra AllegraEra = Nothing
txScriptValiditySupportedInCardanoEra MaryEra = Nothing
txScriptValiditySupportedInCardanoEra AlonzoEra = Just TxScriptValiditySupportedInAlonzoEra
txScriptValiditySupportedInCardanoEra BabbageEra = Just TxScriptValiditySupportedInBabbageEra
txScriptValiditySupportedInShelleyBasedEra :: ShelleyBasedEra era -> Maybe (TxScriptValiditySupportedInEra era)
txScriptValiditySupportedInShelleyBasedEra ShelleyBasedEraShelley = Nothing
txScriptValiditySupportedInShelleyBasedEra ShelleyBasedEraAllegra = Nothing
txScriptValiditySupportedInShelleyBasedEra ShelleyBasedEraMary = Nothing
txScriptValiditySupportedInShelleyBasedEra ShelleyBasedEraAlonzo = Just TxScriptValiditySupportedInAlonzoEra
txScriptValiditySupportedInShelleyBasedEra ShelleyBasedEraBabbage = Just TxScriptValiditySupportedInBabbageEra
txScriptValidityToScriptValidity :: TxScriptValidity era -> ScriptValidity
txScriptValidityToScriptValidity TxScriptValidityNone = ScriptValid
txScriptValidityToScriptValidity (TxScriptValidity _ scriptValidity) = scriptValidity
scriptValidityToTxScriptValidity :: ShelleyBasedEra era -> ScriptValidity -> TxScriptValidity era
scriptValidityToTxScriptValidity era scriptValidity = case txScriptValiditySupportedInShelleyBasedEra era of
Nothing -> TxScriptValidityNone
Just witness -> TxScriptValidity witness scriptValidity
txScriptValidityToIsValid :: TxScriptValidity era -> Alonzo.IsValid
txScriptValidityToIsValid = scriptValidityToIsValid . txScriptValidityToScriptValidity
-- ----------------------------------------------------------------------------
-- Transaction Ids
--
newtype TxId = TxId (Shelley.Hash StandardCrypto Shelley.EraIndependentTxBody)
-- We use the Shelley representation and convert to/from the Byron one
deriving stock (Eq, Ord)
deriving (Show, IsString) via UsingRawBytesHex TxId
deriving (ToJSON, FromJSON) via UsingRawBytesHex TxId
deriving (ToJSONKey, FromJSONKey) via UsingRawBytesHex TxId
instance HasTypeProxy TxId where
data AsType TxId = AsTxId
proxyToAsType _ = AsTxId
instance SerialiseAsRawBytes TxId where
serialiseToRawBytes (TxId h) = Crypto.hashToBytes h
deserialiseFromRawBytes AsTxId bs = TxId <$> Crypto.hashFromBytes bs
toByronTxId :: TxId -> Byron.TxId
toByronTxId (TxId h) =
Byron.unsafeHashFromBytes (Crypto.hashToBytes h)
toShelleyTxId :: TxId -> Ledger.TxId StandardCrypto
toShelleyTxId (TxId h) =
Ledger.TxId (SafeHash.unsafeMakeSafeHash (Crypto.castHash h))
fromShelleyTxId :: Ledger.TxId StandardCrypto -> TxId
fromShelleyTxId (Ledger.TxId h) =
TxId (Crypto.castHash (SafeHash.extractHash h))
-- | Calculate the transaction identifier for a 'TxBody'.
--
getTxId :: forall era. TxBody era -> TxId
getTxId (ByronTxBody tx) =
TxId
. fromMaybe impossible
. Crypto.hashFromBytesShort
. Byron.abstractHashToShort
. Byron.hashDecoded
$ tx
where
impossible =
error "getTxId: byron and shelley hash sizes do not match"
getTxId (ShelleyTxBody era tx _ _ _ _) =
obtainConstraints era $ getTxIdShelley era tx
where
obtainConstraints
:: ShelleyBasedEra era
-> (( Ledger.Crypto (ShelleyLedgerEra era) ~ StandardCrypto
, Ledger.UsesTxBody (ShelleyLedgerEra era)
) => a)
-> a
obtainConstraints ShelleyBasedEraShelley f = f
obtainConstraints ShelleyBasedEraAllegra f = f
obtainConstraints ShelleyBasedEraMary f = f
obtainConstraints ShelleyBasedEraAlonzo f = f
obtainConstraints ShelleyBasedEraBabbage f = f
getTxIdShelley
:: Ledger.Crypto (ShelleyLedgerEra era) ~ StandardCrypto
=> Ledger.UsesTxBody (ShelleyLedgerEra era)
=> ShelleyBasedEra era -> Ledger.TxBody (ShelleyLedgerEra era) -> TxId
getTxIdShelley _ tx =
TxId
. Crypto.castHash
. (\(Ledger.TxId txhash) -> SafeHash.extractHash txhash)
$ Ledger.txid tx
-- ----------------------------------------------------------------------------
-- Transaction inputs
--
data TxIn = TxIn TxId TxIx
deriving (Eq, Ord, Show)
instance ToJSON TxIn where
toJSON txIn = Aeson.String $ renderTxIn txIn
instance ToJSONKey TxIn where
toJSONKey = toJSONKeyText renderTxIn
instance FromJSON TxIn where
parseJSON = withText "TxIn" $ runParsecParser parseTxIn
instance FromJSONKey TxIn where
fromJSONKey = Aeson.FromJSONKeyTextParser $ runParsecParser parseTxIn
parseTxId :: Parsec.Parser TxId
parseTxId = do
str <- some Parsec.hexDigit <?> "transaction id (hexadecimal)"
failEitherWith
(\e -> "Incorrect transaction id format: " ++ displayError e) $
deserialiseFromRawBytesHex AsTxId $ BSC.pack str
parseTxIn :: Parsec.Parser TxIn
parseTxIn = TxIn <$> parseTxId <*> (Parsec.char '#' *> parseTxIx)
parseTxIx :: Parsec.Parser TxIx
parseTxIx = TxIx . fromIntegral <$> decimal
decimal :: Parsec.Parser Integer
Parsec.TokenParser { Parsec.decimal = decimal } = Parsec.haskell
renderTxIn :: TxIn -> Text
renderTxIn (TxIn txId (TxIx ix)) =
serialiseToRawBytesHexText txId <> "#" <> Text.pack (show ix)
newtype TxIx = TxIx Word
deriving stock (Eq, Ord, Show)
deriving newtype (Enum)
deriving newtype (ToJSON, FromJSON)
fromByronTxIn :: Byron.TxIn -> TxIn
fromByronTxIn (Byron.TxInUtxo txId index) =
let shortBs = Byron.abstractHashToShort txId
mApiHash = Crypto.hashFromBytesShort shortBs
in case mApiHash of
Just apiHash -> TxIn (TxId apiHash) (TxIx . fromIntegral $ toInteger index)
Nothing -> error $ "Error converting Byron era TxId: " <> show txId
toByronTxIn :: TxIn -> Byron.TxIn
toByronTxIn (TxIn txid (TxIx txix)) =
Byron.TxInUtxo (toByronTxId txid) (fromIntegral txix)
-- | This function may overflow on the transaction index. Call sites must ensure
-- that all uses of this function are appropriately guarded.
toShelleyTxIn :: TxIn -> Ledger.TxIn StandardCrypto
toShelleyTxIn (TxIn txid (TxIx txix)) =
Ledger.TxIn (toShelleyTxId txid) (Ledger.TxIx $ fromIntegral txix)
fromShelleyTxIn :: Ledger.TxIn StandardCrypto -> TxIn
fromShelleyTxIn (Ledger.TxIn txid (Ledger.TxIx txix)) =
TxIn (fromShelleyTxId txid) (TxIx (fromIntegral txix))
-- ----------------------------------------------------------------------------
-- Transaction outputs
--
-- | The context is a transaction body
data CtxTx
-- | The context is the UTxO
data CtxUTxO
data TxOut ctx era = TxOut (AddressInEra era)
(TxOutValue era)
(TxOutDatum ctx era)
(ReferenceScript era)
deriving instance Eq (TxOut ctx era)
deriving instance Show (TxOut ctx era)
data TxOutInAnyEra where
TxOutInAnyEra :: CardanoEra era
-> TxOut CtxTx era
-> TxOutInAnyEra
deriving instance Show TxOutInAnyEra
instance Eq TxOutInAnyEra where
TxOutInAnyEra era1 out1 == TxOutInAnyEra era2 out2 =
case testEquality era1 era2 of
Just Refl -> out1 == out2
Nothing -> False
-- | Convenience constructor for 'TxOutInAnyEra'
txOutInAnyEra :: IsCardanoEra era => TxOut CtxTx era -> TxOutInAnyEra
txOutInAnyEra = TxOutInAnyEra cardanoEra
toCtxUTxOTxOut :: TxOut CtxTx era -> TxOut CtxUTxO era
toCtxUTxOTxOut (TxOut addr val d refS) =
let dat = case d of
TxOutDatumNone -> TxOutDatumNone
TxOutDatumHash s h -> TxOutDatumHash s h
TxOutDatumInTx' s h _ -> TxOutDatumHash s h
TxOutDatumInline s sd -> TxOutDatumInline s sd
in TxOut addr val dat refS
instance IsCardanoEra era => ToJSON (TxOut ctx era) where
toJSON = txOutToJsonValue cardanoEra
txOutToJsonValue :: CardanoEra era -> TxOut ctx era -> Aeson.Value
txOutToJsonValue era (TxOut addr val dat refScript) =
case era of
ByronEra -> object ["address" .= addr, "value" .= val]
ShelleyEra -> object ["address" .= addr, "value" .= val]
AllegraEra -> object ["address" .= addr, "value" .= val]
MaryEra -> object ["address" .= addr, "value" .= val]
AlonzoEra -> object
[ "address" .= addr
, "value" .= val
, datHashJsonVal dat
, "datum" .= datJsonVal dat
]
BabbageEra ->
object
[ "address" .= addr
, "value" .= val
, datHashJsonVal dat
, "datum" .= datJsonVal dat
, "inlineDatum" .= inlineDatumJsonVal dat
, "referenceScript" .= refScriptJsonVal refScript
]
where
datHashJsonVal :: TxOutDatum ctx era -> Aeson.Pair
datHashJsonVal d =
case d of
TxOutDatumNone ->
"datumhash" .= Aeson.Null
TxOutDatumHash _ h ->
"datumhash" .= toJSON h
TxOutDatumInTx' _ h _ ->
"datumhash" .= toJSON h
TxOutDatumInline _ datum ->
"inlineDatumhash" .= toJSON (hashScriptData datum)
datJsonVal :: TxOutDatum ctx era -> Aeson.Value
datJsonVal d =
case d of
TxOutDatumNone -> Aeson.Null
TxOutDatumHash _ _ -> Aeson.Null
TxOutDatumInTx' _ _ datum -> scriptDataToJson ScriptDataJsonDetailedSchema datum
TxOutDatumInline _ _ -> Aeson.Null
inlineDatumJsonVal :: TxOutDatum ctx era -> Aeson.Value
inlineDatumJsonVal d =
case d of
TxOutDatumNone -> Aeson.Null
TxOutDatumHash {} -> Aeson.Null
TxOutDatumInTx'{} -> Aeson.Null
TxOutDatumInline _ datum -> scriptDataToJson ScriptDataJsonDetailedSchema datum
refScriptJsonVal :: ReferenceScript era -> Aeson.Value
refScriptJsonVal rScript =
case rScript of
ReferenceScript _ s -> toJSON s
ReferenceScriptNone -> Aeson.Null
instance (IsShelleyBasedEra era, IsCardanoEra era)
=> FromJSON (TxOut CtxTx era) where
parseJSON = withObject "TxOut" $ \o -> do
case shelleyBasedEra :: ShelleyBasedEra era of
ShelleyBasedEraShelley ->
TxOut <$> o .: "address"
<*> o .: "value"
<*> return TxOutDatumNone
<*> return ReferenceScriptNone
ShelleyBasedEraMary ->
TxOut <$> o .: "address"
<*> o .: "value"
<*> return TxOutDatumNone
<*> return ReferenceScriptNone
ShelleyBasedEraAllegra ->
TxOut <$> o .: "address"
<*> o .: "value"
<*> return TxOutDatumNone
<*> return ReferenceScriptNone
ShelleyBasedEraAlonzo -> alonzoTxOutParser ScriptDataInAlonzoEra o
ShelleyBasedEraBabbage -> do
alonzoTxOutInBabbage <- alonzoTxOutParser ScriptDataInBabbageEra o
-- We check for the existence of inline datums
inlineDatumHash <- o .:? "inlineDatumhash"
inlineDatum <- o .:? "inlineDatum"
mInlineDatum <-
case (inlineDatum, inlineDatumHash) of
(Just dVal, Just h) ->
case scriptDataFromJson ScriptDataJsonDetailedSchema dVal of
Left err ->
fail $ "Error parsing TxOut JSON: " <> displayError err
Right sData ->
if hashScriptData sData /= h
then fail "Inline datum not equivalent to inline datum hash"
else return $ TxOutDatumInline ReferenceTxInsScriptsInlineDatumsInBabbageEra sData
(Nothing, Nothing) -> return TxOutDatumNone
(_,_) -> fail "Should not be possible to create a tx output with either an inline datum hash or an inline datum"
mReferenceScript <- o .:? "referenceScript"
reconcile alonzoTxOutInBabbage mInlineDatum mReferenceScript
where
reconcile
:: TxOut CtxTx BabbageEra -- ^ Alonzo era datum in Babbage era
-> TxOutDatum CtxTx BabbageEra -- ^ Babbagae inline datum
-> Maybe ScriptInAnyLang
-> Aeson.Parser (TxOut CtxTx BabbageEra)
reconcile top@(TxOut addr v dat r) babbageDatum mBabRefScript = do
-- We check for conflicting datums
finalDat <- case (dat, babbageDatum) of
(TxOutDatumNone, bDatum) -> return bDatum
(anyDat, TxOutDatumNone) -> return anyDat
(alonzoDat, babbageDat) ->
fail $ "Parsed an Alonzo era datum and a Babbage era datum " <>
"TxOut: " <> show top <>
"Alonzo datum: " <> show alonzoDat <>
"Babbage dat: " <> show babbageDat
finalRefScript <- case mBabRefScript of
Nothing -> return r
Just anyScript ->
return $ ReferenceScript ReferenceTxInsScriptsInlineDatumsInBabbageEra anyScript
return $ TxOut addr v finalDat finalRefScript
alonzoTxOutParser
:: ScriptDataSupportedInEra era -> Aeson.Object -> Aeson.Parser (TxOut CtxTx era)
alonzoTxOutParser supp o = do
mDatumHash <- o .:? "datumhash"
mDatumVal <- o .:? "datum"
case (mDatumVal, mDatumHash) of
(Nothing,Nothing) -> TxOut <$> o .: "address"
<*> o .: "value"
<*> return TxOutDatumNone
<*> return ReferenceScriptNone
(Just dVal, Just dHash) ->
case scriptDataFromJson ScriptDataJsonDetailedSchema dVal of
Left err ->
fail $ "Error parsing TxOut JSON: " <> displayError err
Right sData -> TxOut <$> o .: "address"
<*> o .: "value"
<*> return (TxOutDatumInTx' supp dHash sData)
<*> return ReferenceScriptNone
(Nothing, Just dHash) ->
TxOut <$> o .: "address"
<*> o .: "value"
<*> return (TxOutDatumHash supp dHash)
<*> return ReferenceScriptNone
(Just _dVal, Nothing) -> fail "Only datum JSON was found, this should not be possible."
instance (IsShelleyBasedEra era, IsCardanoEra era)
=> FromJSON (TxOut CtxUTxO era) where
parseJSON = withObject "TxOut" $ \o -> do
case shelleyBasedEra :: ShelleyBasedEra era of
ShelleyBasedEraShelley ->
TxOut <$> o .: "address"
<*> o .: "value"
<*> return TxOutDatumNone
<*> return ReferenceScriptNone
ShelleyBasedEraMary ->
TxOut <$> o .: "address"
<*> o .: "value"
<*> return TxOutDatumNone
<*> return ReferenceScriptNone
ShelleyBasedEraAllegra ->
TxOut <$> o .: "address"
<*> o .: "value"
<*> return TxOutDatumNone
<*> return ReferenceScriptNone
ShelleyBasedEraAlonzo -> alonzoTxOutParser ScriptDataInAlonzoEra o
ShelleyBasedEraBabbage -> do
alonzoTxOutInBabbage <- alonzoTxOutParser ScriptDataInBabbageEra o
-- We check for the existence of inline datums
inlineDatumHash <- o .:? "inlineDatumhash"
inlineDatum <- o .:? "inlineDatum"
mInlineDatum <-
case (inlineDatum, inlineDatumHash) of
(Just dVal, Just h) ->
case scriptDataFromJson ScriptDataJsonDetailedSchema dVal of
Left err ->
fail $ "Error parsing TxOut JSON: " <> displayError err
Right sData ->
if hashScriptData sData /= h
then fail "Inline datum not equivalent to inline datum hash"
else return $ TxOutDatumInline ReferenceTxInsScriptsInlineDatumsInBabbageEra sData
(Nothing, Nothing) -> return TxOutDatumNone
(_,_) -> fail "Should not be possible to create a tx output with either an inline datum hash or an inline datum"
-- We check for a reference script
mReferenceScript <- o .:? "referenceScript"
reconcile alonzoTxOutInBabbage mInlineDatum mReferenceScript
where
reconcile
:: TxOut CtxUTxO BabbageEra -- ^ Alonzo era datum in Babbage era
-> TxOutDatum CtxUTxO BabbageEra -- ^ Babbagae inline datum
-> Maybe ScriptInAnyLang
-> Aeson.Parser (TxOut CtxUTxO BabbageEra)
reconcile (TxOut addr v dat r) babbageDatum mBabRefScript = do
-- We check for conflicting datums
finalDat <- case (dat, babbageDatum) of
(TxOutDatumNone, bDatum) -> return bDatum
(anyDat, TxOutDatumNone) -> return anyDat
(_,_) -> fail "Parsed an Alonzo era datum and a Babbage era datum"
finalRefScript <- case mBabRefScript of
Nothing -> return r
Just anyScript ->
return $ ReferenceScript ReferenceTxInsScriptsInlineDatumsInBabbageEra anyScript
return $ TxOut addr v finalDat finalRefScript
alonzoTxOutParser :: ScriptDataSupportedInEra era -> Aeson.Object -> Aeson.Parser (TxOut CtxUTxO era)
alonzoTxOutParser supp o = do
mDatumHash <- o .:? "datumhash"
case mDatumHash of
Nothing -> TxOut <$> o .: "address"
<*> o .: "value"
<*> return TxOutDatumNone
<*> return ReferenceScriptNone
Just dHash ->
TxOut <$> o .: "address"
<*> o .: "value"
<*> return (TxOutDatumHash supp dHash)
<*> return ReferenceScriptNone
fromByronTxOut :: Byron.TxOut -> TxOut ctx ByronEra
fromByronTxOut (Byron.TxOut addr value) =
TxOut
(AddressInEra ByronAddressInAnyEra (ByronAddress addr))
(TxOutAdaOnly AdaOnlyInByronEra (fromByronLovelace value))
TxOutDatumNone ReferenceScriptNone
toByronTxOut :: TxOut ctx ByronEra -> Maybe Byron.TxOut
toByronTxOut (TxOut (AddressInEra ByronAddressInAnyEra (ByronAddress addr))
(TxOutAdaOnly AdaOnlyInByronEra value) _ _) =
Byron.TxOut addr <$> toByronLovelace value
toByronTxOut (TxOut (AddressInEra ByronAddressInAnyEra (ByronAddress _))
(TxOutValue era _) _ _) = case era of {}
toByronTxOut (TxOut (AddressInEra (ShelleyAddressInEra era) ShelleyAddress{})
_ _ _) = case era of {}
toShelleyTxOut :: forall era ledgerera.
ShelleyLedgerEra era ~ ledgerera
=> ShelleyBasedEra era
-> TxOut CtxUTxO era
-> Ledger.TxOut ledgerera
toShelleyTxOut era (TxOut _ (TxOutAdaOnly AdaOnlyInByronEra _) _ _) =
case era of {}
toShelleyTxOut _ (TxOut addr (TxOutAdaOnly AdaOnlyInShelleyEra value) _ _) =
Shelley.TxOut (toShelleyAddr addr) (toShelleyLovelace value)
toShelleyTxOut _ (TxOut addr (TxOutAdaOnly AdaOnlyInAllegraEra value) _ _) =
Shelley.TxOut (toShelleyAddr addr) (toShelleyLovelace value)
toShelleyTxOut _ (TxOut addr (TxOutValue MultiAssetInMaryEra value) _ _) =
Shelley.TxOut (toShelleyAddr addr) (toMaryValue value)
toShelleyTxOut _ (TxOut addr (TxOutValue MultiAssetInAlonzoEra value) txoutdata _) =
Alonzo.TxOut (toShelleyAddr addr) (toMaryValue value)
(toAlonzoTxOutDataHash txoutdata)
toShelleyTxOut era (TxOut addr (TxOutValue MultiAssetInBabbageEra value) txoutdata refScript) =
let cEra = shelleyBasedToCardanoEra era
in Babbage.TxOut (toShelleyAddr addr) (toMaryValue value)
(toBabbageTxOutDatum txoutdata) (refScriptToShelleyScript cEra refScript)
fromShelleyTxOut :: ShelleyLedgerEra era ~ ledgerera
=> ShelleyBasedEra era
-> Core.TxOut ledgerera
-> TxOut ctx era
fromShelleyTxOut era ledgerTxOut =
case era of
ShelleyBasedEraShelley ->
TxOut (fromShelleyAddr era addr)
(TxOutAdaOnly AdaOnlyInShelleyEra
(fromShelleyLovelace value))
TxOutDatumNone ReferenceScriptNone
where
Shelley.TxOut addr value = ledgerTxOut
ShelleyBasedEraAllegra ->
TxOut (fromShelleyAddr era addr)
(TxOutAdaOnly AdaOnlyInAllegraEra
(fromShelleyLovelace value))
TxOutDatumNone ReferenceScriptNone
where
Shelley.TxOut addr value = ledgerTxOut
ShelleyBasedEraMary ->
TxOut (fromShelleyAddr era addr)
(TxOutValue MultiAssetInMaryEra
(fromMaryValue value))
TxOutDatumNone ReferenceScriptNone
where
Shelley.TxOut addr value = ledgerTxOut
ShelleyBasedEraAlonzo ->
TxOut (fromShelleyAddr era addr)
(TxOutValue MultiAssetInAlonzoEra
(fromMaryValue value))
(fromAlonzoTxOutDataHash ScriptDataInAlonzoEra datahash)
ReferenceScriptNone
where
Alonzo.TxOut addr value datahash = ledgerTxOut
ShelleyBasedEraBabbage ->
TxOut (fromShelleyAddr era addr)
(TxOutValue MultiAssetInBabbageEra
(fromMaryValue value))
(fromBabbageTxOutDatum
ScriptDataInBabbageEra
ReferenceTxInsScriptsInlineDatumsInBabbageEra
datum)
(case mRefScript of
SNothing -> ReferenceScriptNone
SJust refScript ->
fromShelleyScriptToReferenceScript ShelleyBasedEraBabbage refScript)
where
Babbage.TxOut addr value datum mRefScript = ledgerTxOut
-- TODO: If ledger creates an open type family for datums
-- we can consolidate this function with the Babbage version
toAlonzoTxOutDataHash
:: TxOutDatum CtxUTxO AlonzoEra
-> StrictMaybe (Alonzo.DataHash StandardCrypto)
toAlonzoTxOutDataHash TxOutDatumNone = SNothing
toAlonzoTxOutDataHash (TxOutDatumHash _ (ScriptDataHash dh)) = SJust dh
toAlonzoTxOutDataHash (TxOutDatumInline inlineDatumSupp _sd) =
case inlineDatumSupp :: ReferenceTxInsScriptsInlineDatumsSupportedInEra AlonzoEra of {}
fromAlonzoTxOutDataHash :: ScriptDataSupportedInEra era
-> StrictMaybe (Alonzo.DataHash StandardCrypto)
-> TxOutDatum ctx era
fromAlonzoTxOutDataHash _ SNothing = TxOutDatumNone
fromAlonzoTxOutDataHash s (SJust dh) = TxOutDatumHash s (ScriptDataHash dh)
-- TODO: If ledger creates an open type family for datums
-- we can consolidate this function with the Alonzo version
toBabbageTxOutDatum
:: Ledger.Crypto (ShelleyLedgerEra era) ~ StandardCrypto
=> TxOutDatum CtxUTxO era -> Babbage.Datum (ShelleyLedgerEra era)
toBabbageTxOutDatum TxOutDatumNone = Babbage.NoDatum
toBabbageTxOutDatum (TxOutDatumHash _ (ScriptDataHash dh)) = Babbage.DatumHash dh
toBabbageTxOutDatum (TxOutDatumInline _ sd) = scriptDataToInlineDatum sd
fromBabbageTxOutDatum
:: Ledger.Crypto ledgerera ~ StandardCrypto
=> ScriptDataSupportedInEra era
-> ReferenceTxInsScriptsInlineDatumsSupportedInEra era
-> Babbage.Datum ledgerera
-> TxOutDatum ctx era
fromBabbageTxOutDatum _ _ Babbage.NoDatum = TxOutDatumNone
fromBabbageTxOutDatum supp _ (Babbage.DatumHash dh) =
TxOutDatumHash supp $ ScriptDataHash dh
fromBabbageTxOutDatum _ supp (Babbage.Datum binData) =
TxOutDatumInline supp $ binaryDataToScriptData supp binData
-- ----------------------------------------------------------------------------
-- Era-dependent transaction body features
--
-- | A representation of whether the era supports transactions with inputs used
-- only for collateral for script fees.
--
-- The Alonzo and subsequent eras support collateral inputs.
--
data CollateralSupportedInEra era where
CollateralInAlonzoEra :: CollateralSupportedInEra AlonzoEra
CollateralInBabbageEra :: CollateralSupportedInEra BabbageEra
deriving instance Eq (CollateralSupportedInEra era)
deriving instance Show (CollateralSupportedInEra era)
collateralSupportedInEra :: CardanoEra era
-> Maybe (CollateralSupportedInEra era)
collateralSupportedInEra ByronEra = Nothing
collateralSupportedInEra ShelleyEra = Nothing
collateralSupportedInEra AllegraEra = Nothing
collateralSupportedInEra MaryEra = Nothing
collateralSupportedInEra AlonzoEra = Just CollateralInAlonzoEra
collateralSupportedInEra BabbageEra = Just CollateralInBabbageEra
-- | A representation of whether the era supports multi-asset transactions.
--
-- The Mary and subsequent eras support multi-asset transactions.
--
-- The negation of this is 'OnlyAdaSupportedInEra'.
--
data MultiAssetSupportedInEra era where
-- | Multi-asset transactions are supported in the 'Mary' era.
MultiAssetInMaryEra :: MultiAssetSupportedInEra MaryEra
-- | Multi-asset transactions are supported in the 'Alonzo' era.
MultiAssetInAlonzoEra :: MultiAssetSupportedInEra AlonzoEra
-- | Multi-asset transactions are supported in the 'Babbage' era.
MultiAssetInBabbageEra :: MultiAssetSupportedInEra BabbageEra
deriving instance Eq (MultiAssetSupportedInEra era)
deriving instance Show (MultiAssetSupportedInEra era)
instance ToJSON (MultiAssetSupportedInEra era) where
toJSON = Aeson.String . Text.pack . show
-- | A representation of whether the era supports only ada transactions.
--
-- Prior to the Mary era only ada transactions are supported. Multi-assets are
-- supported from the Mary era onwards.
--
-- This is the negation of 'MultiAssetSupportedInEra'. It exists since we need
-- evidence to be positive.
--
data OnlyAdaSupportedInEra era where
AdaOnlyInByronEra :: OnlyAdaSupportedInEra ByronEra
AdaOnlyInShelleyEra :: OnlyAdaSupportedInEra ShelleyEra
AdaOnlyInAllegraEra :: OnlyAdaSupportedInEra AllegraEra
deriving instance Eq (OnlyAdaSupportedInEra era)
deriving instance Show (OnlyAdaSupportedInEra era)
multiAssetSupportedInEra :: CardanoEra era
-> Either (OnlyAdaSupportedInEra era)
(MultiAssetSupportedInEra era)
multiAssetSupportedInEra ByronEra = Left AdaOnlyInByronEra
multiAssetSupportedInEra ShelleyEra = Left AdaOnlyInShelleyEra
multiAssetSupportedInEra AllegraEra = Left AdaOnlyInAllegraEra
multiAssetSupportedInEra MaryEra = Right MultiAssetInMaryEra
multiAssetSupportedInEra AlonzoEra = Right MultiAssetInAlonzoEra
multiAssetSupportedInEra BabbageEra = Right MultiAssetInBabbageEra
-- | A representation of whether the era requires explicitly specified fees in
-- transactions.
--
-- The Byron era tx fees are implicit (as the difference bettween the sum of
-- outputs and sum of inputs), but all later eras the fees are specified in the
-- transaction explicitly.
--
data TxFeesExplicitInEra era where
TxFeesExplicitInShelleyEra :: TxFeesExplicitInEra ShelleyEra
TxFeesExplicitInAllegraEra :: TxFeesExplicitInEra AllegraEra
TxFeesExplicitInMaryEra :: TxFeesExplicitInEra MaryEra
TxFeesExplicitInAlonzoEra :: TxFeesExplicitInEra AlonzoEra
TxFeesExplicitInBabbageEra :: TxFeesExplicitInEra BabbageEra
deriving instance Eq (TxFeesExplicitInEra era)
deriving instance Show (TxFeesExplicitInEra era)
-- | A representation of whether the era requires implicitly specified fees in
-- transactions.
--
-- This is the negation of 'TxFeesExplicitInEra'.
--
data TxFeesImplicitInEra era where
TxFeesImplicitInByronEra :: TxFeesImplicitInEra ByronEra