forked from rokusk/lyra-vaults
-
Notifications
You must be signed in to change notification settings - Fork 7
/
StrategyBase.sol
219 lines (183 loc) · 7.12 KB
/
StrategyBase.sol
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
//SPDX-License-Identifier: MIT
pragma solidity ^0.8.9;
// Lyra
import {LyraAdapter} from "@lyrafinance/protocol/contracts/periphery/LyraAdapter.sol";
// Libraries
import {Vault} from "../libraries/Vault.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {LyraVault} from "../core/LyraVault.sol";
import {DecimalMath} from "@lyrafinance/protocol/contracts/synthetix/DecimalMath.sol";
import {SignedDecimalMath} from "@lyrafinance/protocol/contracts/synthetix/SignedDecimalMath.sol";
contract StrategyBase is LyraAdapter {
using DecimalMath for uint;
using SignedDecimalMath for int;
LyraVault public immutable vault;
OptionType public immutable optionType;
/// @dev asset used as collateral in AMM to sell. Should be the same as vault asset
IERC20 public collateralAsset;
mapping(uint => uint) public lastTradeTimestamp;
uint[] public activeStrikeIds;
mapping(uint => uint) public strikeToPositionId;
///////////
// ADMIN //
///////////
modifier onlyVault() virtual {
require(msg.sender == address(vault), "only Vault");
_;
}
constructor(LyraVault _vault, OptionType _optionType) LyraAdapter() {
vault = _vault;
optionType = _optionType;
}
function initAdapter(
address _lyraRegistry,
address _optionMarket,
address _curveSwap,
address _feeCounter
) external onlyOwner {
// set addresses for LyraAdapter
setLyraAddresses(_lyraRegistry, _optionMarket, _curveSwap, _feeCounter);
quoteAsset.approve(address(vault), type(uint).max);
baseAsset.approve(address(vault), type(uint).max);
collateralAsset = _isBaseCollat() ? IERC20(address(baseAsset)) : IERC20(address(quoteAsset));
}
///////////////////
// VAULT ACTIONS //
///////////////////
/**
* @dev exchange asset back to collateral asset and send it back to the vault
* @dev override this function if you want to customize asset management flow
*/
function _returnFundsToVault() internal virtual {
ExchangeRateParams memory exchangeParams = _getExchangeParams();
uint quoteBal = quoteAsset.balanceOf(address(this));
if (_isBaseCollat()) {
// exchange quote asset to base asset, and send base asset back to vault
uint baseBal = baseAsset.balanceOf(address(this));
uint minQuoteExpected = quoteBal.divideDecimal(exchangeParams.spotPrice).multiplyDecimal(
DecimalMath.UNIT - exchangeParams.baseQuoteFeeRate
);
uint baseReceived = _exchangeFromExactQuote(quoteBal, minQuoteExpected);
require(baseAsset.transfer(address(vault), baseBal + baseReceived), "failed to return funds from strategy");
} else {
// send quote balance directly
require(quoteAsset.transfer(address(vault), quoteBal), "failed to return funds from strategy");
}
}
/////////////////////////////
// Trade Parameter Helpers //
/////////////////////////////
/**
* @dev Automatically decide between close and forceClose
* depending on whether deltaCutoff or tradingCutoff are crossed
*/
function _formatedCloseOrForceClosePosition(
OptionPosition memory position,
uint closeAmount,
uint minTotalCost,
uint maxTotalCost,
address lyraRewardRecipient
) internal {
// closes excess position with premium balance
// if it's a full close, take out our collateral as well.
uint setCollateralTo = position.amount == closeAmount ? 0 : position.collateral;
TradeInputParameters memory tradeParams = TradeInputParameters({
strikeId: position.strikeId,
positionId: position.positionId,
iterations: 3,
optionType: optionType,
amount: closeAmount,
setCollateralTo: setCollateralTo,
minTotalCost: minTotalCost,
maxTotalCost: maxTotalCost,
rewardRecipient: lyraRewardRecipient // set to zero address if don't want to wait for whitelist
});
// if forceClosed, will pay less competitive price to close position but bypasses Lyra delta/trading cutoffs
TradeResult memory result = _closeOrForceClosePosition(tradeParams);
require(result.totalCost <= maxTotalCost, "premium paid is above max expected premium");
}
/**
* @dev get minimum premium that the vault should receive.
* param listingId lyra option listing id
* param size size of trade in Lyra standard sizes
*/
function _getPremiumLimit(
Strike memory strike,
uint vol,
uint size
) internal view returns (uint limitPremium) {
ExchangeRateParams memory exchangeParams = _getExchangeParams();
(uint callPremium, uint putPremium) = _getPurePremium(
_getSecondsToExpiry(strike.expiry),
vol,
exchangeParams.spotPrice,
strike.strikePrice
);
limitPremium = _isCall() ? callPremium.multiplyDecimal(size) : putPremium.multiplyDecimal(size);
}
//////////////////////////////
// Active Strike Management //
//////////////////////////////
/**
* @dev add strike id to activeStrikeIds array
*/
function _addActiveStrike(uint strikeId, uint tradedPositionId) internal {
if (!_isActiveStrike(strikeId)) {
strikeToPositionId[strikeId] = tradedPositionId;
activeStrikeIds.push(strikeId);
}
}
/**
* @dev add the last traded timestamp for a specific strike.
*/
function _setLastTradedAt(uint strikeId, uint timestamp) internal {
lastTradeTimestamp[strikeId] = timestamp;
}
/**
* @dev remove position data opened in the current round.
* this can only be called after the position is settled by lyra
**/
function _clearAllActiveStrikes() internal {
if (activeStrikeIds.length != 0) {
for (uint i = 0; i < activeStrikeIds.length; i++) {
uint strikeId = activeStrikeIds[i];
OptionPosition memory position = _getPositions(_toDynamic(strikeToPositionId[strikeId]))[0];
// revert if position state is not settled
require(position.state != PositionState.ACTIVE, "cannot clear active position");
delete strikeToPositionId[strikeId];
delete lastTradeTimestamp[strikeId];
}
delete activeStrikeIds;
}
}
function _isActiveStrike(uint strikeId) internal view returns (bool isActive) {
isActive = strikeToPositionId[strikeId] != 0;
}
//////////
// Misc //
//////////
function _isBaseCollat() internal view returns (bool isBase) {
isBase = (optionType == OptionType.SHORT_CALL_BASE) ? true : false;
}
function _isCall() internal view returns (bool isCall) {
isCall = (optionType == OptionType.SHORT_PUT_QUOTE || optionType == OptionType.LONG_PUT) ? false : true;
}
function _getSecondsToExpiry(uint expiry) internal view returns (uint) {
require(block.timestamp <= expiry, "timestamp expired");
return expiry - block.timestamp;
}
function _abs(int val) internal pure returns (uint) {
return val >= 0 ? uint(val) : uint(-val);
}
function _min(uint x, uint y) internal pure returns (uint) {
return (x < y) ? x : y;
}
function _max(uint x, uint y) internal pure returns (uint) {
return (x > y) ? x : y;
}
// temporary fix - eth core devs promised Q2 2022 fix
function _toDynamic(uint val) internal pure returns (uint[] memory dynamicArray) {
dynamicArray = new uint[](1);
dynamicArray[0] = val;
}
}