flake.nix

{
	description = "My heavily customized fork of DWL";

	inputs = {
		nixpkgs = {
			url = "github:NixOS/nixpkgs/nixos-unstable";
		};

		# Override the systems for the flake, because this only builds on Linux
		systems = {
			url = "github:nix-systems/default-linux";
		};

		flake-utils = {
			url	= "github:numtide/flake-utils";
			inputs.systems.follows = "systems";
		};

		wvkbd-minego = {
			url = github:minego/wvkbd/main;
			inputs.nixpkgs.follows = "nixpkgs";
		};

		swipeguess = {
			url = git+https://git.sr.ht/~earboxer/swipeGuess;
			flake = false;
		};
	};

	outputs = { self, nixpkgs, flake-utils, ... }@inputs:

	let
		overlay = final: prev: {
			# Replace the 'dwl' in nixpkgs with our own
			dwl-unwrapped			= prev.pkgs.callPackage ./dwl.nix { inherit inputs; };
			dwl						= prev.pkgs.callPackage ./derivation.nix { inherit inputs; };
		};
	in

	flake-utils.lib.eachDefaultSystem (system:
		let
			pkgs = nixpkgs.legacyPackages.${system}.extend overlay;
		in rec {
			packages.dwl-unwrapped	= pkgs.dwl-unwrapped;
			packages.dwl			= pkgs.dwl;

			packages.default		= packages.dwl;
			devShells.default		= import ./shell.nix { inherit pkgs; };
		}
	)
	//
	{
		overlays.default			= overlay;
	};
}