-
Notifications
You must be signed in to change notification settings - Fork 1
/
crasis
2131 lines (1847 loc) · 84.6 KB
/
crasis
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# -*- mode: shell-script -*-
# vim:ft=zsh:sw=4:sts=4:et
# Started from Zle or from command line
#
# Copyright (c) 2017 Sebastian Gniazdowski
-zui_std_cleanup deserialize:"zinit-crasis"
-zui_std_init app:"zinit-crasis" app_name:"Zinit-Crasis"
emulate -LR zsh -o extendedglob -o typesetsilent -o warncreateglobal
-zui_std_init2
-zui_std_store_default_app_config b:text_mode off
-zui_std_store_default_app_config b:text_select off
-zui_std_store_default_app_config b:border 1
-zui_std_store_default_app_config b:top_anchors 0 # no top-anchors
# Already autoloaded in *.plugin.zsh, here it's for Zshelldoc
autoload -- -zcrasis-process-buffer
# Debug array, for debug view
local -a ZCR_DEBUG_MSGS
# Append message to the debug view
-zcrasis_dbg_msg() { ZCR_DEBUG_MSGS+=( "$*" ); }
# Append multiple messages to the debug view
-zcrasis_dbg_msg_arr() { ZCR_DEBUG_MSGS+=( "$@" ); }
ZUI[log_time_format]="[%H:%M] "
# Initial debug message
-zcrasis_dbg_msg "ZSH version: $ZSH_VERSION ($ZSH_PATCHLEVEL), machine: $CPUTYPE $VENDOR $OSTYPE, LANG: $LANG"
if [[ ${+ZPLGM} = 1 ]]; then
-zcrasis_dbg_msg "Zinit version: <ZPLGVERSION>, Zinit-Crasis version: <ZCRVERSION>"
-zcrasis_dbg_msg "Zinit BIN_DIR: ${ZPLGM[BIN_DIR]/$HOME/~}, HOME_DIR: ${ZPLGM[HOME_DIR]/$HOME/~}, PLUGINS_DIR: ${ZPLGM[PLUGINS_DIR]/$HOME/~}, COMPLETIONS_DIR: ${ZPLGM[COMPLETIONS_DIR]/$HOME/~}"
else
-zcrasis_dbg_msg "${ZUI[RED]}Zinit not loaded${ZUI[FMT_END]}"
fi
-zcrasis_dbg_msg ""
-zcrasis_dbg_msg_arr "Active plugins:" "${ZPLG_REGISTERED_PLUGINS[@]/(#s)/ }"
-zcrasis_dbg_msg ""
#
# CONSTANTS
#
local -A TOKEN_TYPES
TOKEN_TYPES=(
# Precommand
'builtin' 1
'command' 1
'exec' 1
'nocorrect' 1
'noglob' 1
'pkexec' 1
# Control flow
# Tokens that at "command position" are followed by a command
$'\x7b' 2 # {
$'\x28' 2 # (
'()' 2
'while' 2
'until' 2
'if' 2
'then' 2
'elif' 2
'else' 2
'do' 2
'time' 2
'coproc' 2
'!' 2
# Command separators
'|' 3
'||' 3
'&&' 3
'|&' 4
'&!' 4
'&|' 4
'&' 4
';' 4
)
local -a chosen_plugins chosen_descriptions
# 5.0.2, 5.0.6 stop execution after unsuccessful $(<...)
[[ -r "$ZCRASIS_REPO_DIR/gold.lst" ]] && chosen_plugins=( "${(@f)"$(<$ZCRASIS_REPO_DIR/gold.lst)"}" ) || chosen_plugins=( "" "File gold.lst not found" )
[[ -r "$ZCRASIS_REPO_DIR/desc.lst" ]] && chosen_descriptions=( "${(@f)"$(<$ZCRASIS_REPO_DIR/desc.lst)"}" )
local -a ice_order nval_ices
ice_order=(
wait lucid silent service svn proto from teleid as id-as depth cloneopts
ver has if load unload blockf pick bpick src notify mv cp atinit atclone
atload atpull make run-atpull nocd cloneonly trackbinds bindmap multisrc
compile nocompile nocompletions reset-prompt
# Include all additional ices – after
# stripping them from the possible: ''
${(@s.|.)${ZPLG_EXTS[ice-mods]//\'\'/}}
)
nval_ices=(
blockf silent lucid trackbinds cloneonly nocd run-atpull
nocompletions svn
# Include only those additional ices,
# don't have the '' in their name, i.e.
# aren't designed to hold value
${(@)${(@s.|.)ZPLG_EXTS[ice-mods]}:#*\'\'*}
)
# Layout parameters
local -a w_snippet_item_long w_snippet_item_short w_plugin_item_long w_plugin_item_short
local -a w_cdreplay_item_long w_cdreplay_item_short w_cdclear_item_long w_cdclear_item_short
local -a w_other_item_long w_other_item_short
#
# PARAMETERS
#
# Document to process
local zshrc_path="${1:-${ZDOTDIR:-$HOME}/.zshrc}" zshrc
# The bits returned by -zplg-process-buffer
local token prev_token spaces prev_spaces next_token next_spaces
# Command detection
integer at_command=1 in_zinit=0
# Functions
local fun_name
integer next_fun=0 cur_fun=0 prev_fun=0
# Depths in functions, i.e. -1 not in function, 0 in one function, etc.
integer depth=0 prev_depth=0 fun_depth=-1 anon_depth=-1 descentff=0 descentfa=0
# Nested functions tracking
integer nested_fun=0 next_nested_fun=0 prev_nested_fun=0
local -a fun_stack_depths
# Text and commands data
integer was_zinit=0 pre_block_end=0 post_block_begin=0
local -A cmd3
local -a cmdlist
integer coidx=1
# Common
local -a mbegin mend match
local MATCH; integer MBEGIN MEND
local internal # to mark inline action as no-ZUI-restart
local tmp
typeset -g REPLY
typeset -ga reply
# -zcrasis-process-buffer output parameters, declare
# them to prevent globals from being created
local -a ZCR_PB_WORDS ZCR_PB_SPACES ZCR_PB_WORDS_BEGINNINGS ZCR_PB_ALL
ZUI[my_incl_comm]=0
ZUI[my_show_diff]=0
#
# Examine zshrc
#
[[ ! -e "$zshrc_path" ]] && { print "No such file \`$zshrc_path'${ZDOTDIR:+ (using \$ZDOTDIR)}"; return 1; }
[[ ! -f "$zshrc_path" ]] && { print "\`$zshrc_path' isn't a plain, regular file${ZDOTDIR:+ (using \$ZDOTDIR)}"; return 1; }
[[ ! -r "$zshrc_path" ]] && { print "No read permissions to \`$zshrc_path'${ZDOTDIR:+ (using \$ZDOTDIR)}"; return 1; }
[[ ! -w "$zshrc_path" ]] && { print "No write permissions to \`$zshrc_path'${ZDOTDIR:+ (using \$ZDOTDIR)}"; return 1; }
[[ ! -s "$zshrc_path" ]] && { print "File \`$zshrc_path' is empty, aborting"; return 1; }
#
# Load and process theme
#
local CRASIS_THEME="$CRASIS_THEME" CRASIS_LAYOUT="${CRASIS_LAYOUT:-default}"
local -a thcol_entries thcol_entries2 thbcol_entries thtxt_entries thtxt_entries2
thcol_entries=(
# Top bar
menu-active-button-fg menu2-active-button-fg
reload save preview options debug delete-mode edit-mode compact-mode
# Add bar
add-snippet add-plugin gold-choose
# Listing
index enabled disabled up down delete plus-ice minus-ice
# Snippet item
s-url s-marker s-marker-disabled s-as-command s-force
# Plugin item
p-id p-marker p-marker-disabled p-compile
# Ice listing
i-indent i-unknown
# Preview
pv-main-buttons pv-comment
# Options view
o-theme-box o-switch o-layout-box o-switch2 o-save
# Debug view
d-save
)
thcol_entries2=( p-mode i-id d-email )
thbcol_entries=( menu-bg menu-active-button-bg menu2-bg menu2-active-button-bg )
thtxt_entries=(
# Top bar
reload-text save-text preview-text options-text debug-text delete-mode-text edit-mode-text compact-mode-text
# Add bar
add-snippet-text add-plugin-text new-id-url-text gold-choose-text gold-list-info-text
# Listing
enabled-text disabled-text enabled-unicode disabled-unicode up-text down-text up-unicode down-unicode
delete-text delete-unicode minus-ice-text plus-ice-text
# Snippet item
s-marker-text s-marker-disabled-text
# Plugin item
p-marker-text p-marker-disabled-text p-compile-text
# Ice listing
i-indent-text i-blockf-text i-unknown-text
# Options view
o-switch-text o-switch2-text o-save-text
# Debug view
d-save-text
)
thtxt_entries2=( p-mode-text )
local -A theme
# FUNCTION: -zcrasis_process_theme {{{
# Theme file contains a little complex data and
# this functions converts it to be ready to use
function -zcrasis_process_theme() {
typeset -F 3 SECONDS=0
local -A theme_save
theme_save=( "${(kv@)theme[(I)*-unicode-bool]}" )
[[ -f "$ZCRASIS_REPO_DIR/crasis.conf" ]] && {
source "$ZCRASIS_REPO_DIR/crasis.conf"
# Global and from-interface $CRASIS_THEME overrides configuration file
CRASIS_THEME=${CRASIS_THEME:-$theme_name}
# For unicode glyphs, respect configuration file only at start
theme_save[ud-unicode-bool]="${theme_save[ud-unicode-bool]:-$move_unicode_buttons}"
theme_save[ed-unicode-bool]="${theme_save[ed-unicode-bool]:-$toggle_unicode_buttons}"
theme_save[delete-unicode-bool]="${theme_save[delete-unicode-bool]:-$delete_unicode_button}"
}
theme=( "${(kv@)theme_save}" )
# Mostly initial values, but also error check
[[ "${theme[ud-unicode-bool]}" != [0-1] ]] && theme[ud-unicode-bool]=1
[[ "${theme[ed-unicode-bool]}" != [0-1] ]] && theme[ed-unicode-bool]=1
[[ "${theme[delete-unicode-bool]}" != [0-1] ]] && theme[delete-unicode-bool]=1
# Fallback path for theme name
[[ ! -f "$ZCRASIS_REPO_DIR/themes/${CRASIS_THEME}.cr-theme" ]] && {
-zui_std_stalog "No such theme: " "$CRASIS_THEME," "" " reverted to default"
CRASIS_THEME="default"
[[ ! -f "$ZCRASIS_REPO_DIR/themes/${CRASIS_THEME}.cr-theme" ]] && {
print "Couldn't find theme \`$CRASIS_THEME', have to abort.."
print "Looked for file: $ZCRASIS_REPO_DIR/themes/${CRASIS_THEME}.cr-theme"
return 1
}
}
source "$ZCRASIS_REPO_DIR/themes/${CRASIS_THEME}.cr-theme"
theme+=( "${(kv)my_crasis_theme_data[@]}" )
theme[i-blockf]="${${(s;:;)theme[i-id]}[5]}"
theme[layout]="$(<$ZCRASIS_REPO_DIR/layouts/${CRASIS_LAYOUT}.cr-layout)"
# Stats on color settings
local -a provided missing
provided=( "${(@)theme[(I)(${(~j:|:)thcol_entries})]}" "${(@)theme[(I)(${(~j:|:)thcol_entries2})]}" )
missing=( ${thcol_entries:|provided} ${thcol_entries2:|provided} )
-zcrasis_dbg_msg "Theme provided ${#provided} color entries (out of $(( ${#thcol_entries} + ${#thcol_entries2} )) required, missing keys: ${missing:-none})"
# Stats on text settings
provided=( "${(@)theme[(I)(${(~j:|:)thtxt_entries})]}" "${(@)theme[(I)(${(~j:|:)thtxt_entries2})]}" )
missing=( ${thtxt_entries:|provided} ${thtxt_entries2:|provided} )
-zcrasis_dbg_msg "Theme provided ${#provided} text entries (out of $(( ${#thtxt_entries} + ${#thtxt_entries2} )) required, missing keys: ${missing:-none})"
# Convert colors' symbolic names like "green"
local ckey cval nval
for ckey in "${thcol_entries[@]}" "${thbcol_entries[@]}" i-blockf; do
cval=${(U)theme[$ckey]}
[[ -z "$cval" ]] && continue
[[ -n "${thbcol_entries[(r)$ckey]}" ]] && nval=${ZUI[BG_$cval]} || nval=${ZUI[$cval]}
if [[ -n "$nval" ]]; then
theme[$ckey]="$nval"
else
cval="${cval#B}"
[[ -n "${thbcol_entries[(r)$ckey]}" ]] && nval=${ZUI[BG_$cval]} || nval=${ZUI[$cval]}
[[ -n "$nval" ]] && theme[$ckey]="${ZUI[BOLD]}$nval" || theme[$ckey]=""
fi
done
# Convert array-colors specifications
local mkey
local -a thsplit
integer index
for mkey in "${thcol_entries2[@]}"; do
thsplit=( "${(@Us;:;)theme[$mkey]}" )
index=0
for cval in "${thsplit[@]}"; do
index+=1
nval=${ZUI[$cval]}
if [[ -n "$nval" ]]; then
theme[${mkey}-${index}]="$nval"
else
cval="${cval#B}"
nval="${ZUI[$cval]}"
[[ -n "$nval" ]] && theme[${mkey}-${index}]="${ZUI[BOLD]}$nval" || theme[${mkey}-${index}]=""
fi
done
done
# Convert non-semicolon texts to colored ones
local tkey tval
for tkey in "${thtxt_entries[@]}"; do
tval="${theme[$tkey]}"
# %s conversion
if [[ "${tval/\%s*,/}" != "$tval" ]]; then
thsplit=( "${(@s:,:)tval}" )
cval="${theme[${tkey%(-text|-unicode)}]}"
if [[ -n "$cval" ]]; then
[[ -n "${thsplit[2]}" ]] && thsplit[2]="${cval}${thsplit[2]}${ZUI[FMT_END]}"
[[ -n "${thsplit[3]}" ]] && thsplit[3]="${cval}${thsplit[3]}${ZUI[FMT_END]}"
fi
tval=`printf "${thsplit[@]}"`
theme[${tkey}-c]="$tval"
else
cval="${theme[${tkey%(-text|-unicode)}]}"
if [[ -n "$cval" ]]; then
[[ -n "$tval" ]] && theme[${tkey}-c]="${cval}$tval${ZUI[FMT_END]}"
else
[[ -n "$tval" ]] && theme[${tkey}-c]="$tval"
fi
fi
done
# Convert semicolon texts to colored ones
local -a thsplit2
for mkey in "${thtxt_entries2[@]}"; do
thsplit=( "${(@s:;:)theme[$mkey]}" )
index=0
for tval in "${thsplit[@]}"; do
index+=1
# %s conversion
if [[ "${tval/\%s*,/}" != "$tval" ]]; then
thsplit=( "${(@s:,:)tval}" )
cval="${theme[${mkey%(-text|-unicode)}-${index}]}"
if [[ -n "$cval" ]]; then
[[ -n "${thsplit[2]}" ]] && thsplit[2]="${cval}${thsplit[2]}${ZUI[FMT_END]}"
[[ -n "${thsplit[3]}" ]] && thsplit[3]="${cval}${thsplit[3]}${ZUI[FMT_END]}"
fi
tval=`printf "${thsplit[@]}"`
theme[${mkey}-c-${index}]="$tval"
else
cval="${theme[${mkey%(-text|-unicode)}-${index}]}"
if [[ -n "$cval" ]]; then
theme[${mkey}-c-${index}]="${cval}$tval${ZUI[FMT_END]}"
else
theme[${mkey}-c-${index}]="$tval"
fi
fi
done
done
chosen_plugins[1]="$theme[gold-list-info-text]"
[[ -n "$theme[i-unknown]" ]] && {
theme[i-unknown-text-c]="${theme[i-unknown-text]//\%s/${theme[i-unknown]}%s$ZUI[FMT_END]}"
} || theme[i-unknown-text-c]="$theme[i-unknown-text]"
-zcrasis_dbg_msg_arr "Theme processing time: $SECONDS seconds" ""
-zui_std_stalog "Loaded theme \`$CRASIS_THEME' and layout \`$CRASIS_LAYOUT'"
return 0
}
# }}}
# FUNCTION: -zcrasis_set_zui_settings {{{
# If theme provides palette-string, it is
# applied to ZUI settings of this application
function -zcrasis_set_zui_settings() {
[[ -n "$theme[palette-string]" ]] && {
autoload is-at-least
if [[ "$theme[palette-string]" = *[[:digit:]]* ]] && ! is-at-least 5.3; then
-zui_std_stalog "256-color palette needs " "Zsh >= 5.3, " "" "it hasn't been applied"
else
ZUI[palette]="$theme[palette-string]"
fi
}
[[ -n "$theme[logs-palette-string]" ]] && {
autoload is-at-least
if [[ "$theme[logs-palette-string]" = *[[:digit:]]* ]] && ! is-at-least 5.3; then
-zui_std_stalog "256-color logs palette needs " "Zsh >= 5.3, " "" "it hasn't been applied"
else
ZUI[log_colors]="${theme[logs-palette-string]//:/ }"
fi
}
[[ -n "$theme[colorpair-string]" ]] && {
autoload is-at-least
if [[ "$theme[colorpair-string]" = *[[:digit:]]* ]] && ! is-at-least 5.3; then
-zui_std_stalog "256-colors need " "Zsh >= 5.3, " "" "color was skipped"
else
ZUI[colorpair]="${theme[colorpair-string]}"
fi
}
[[ -n "$theme[status-cp-string]" ]] && {
autoload is-at-least
if [[ "$theme[status-cp-string]" = *[[:digit:]]* ]] && ! is-at-least 5.3; then
-zui_std_stalog "256-colors need " "Zsh >= 5.3, " "" "color was skipped"
else
ZUI[status_colorpair]="${theme[status-cp-string]}"
fi
}
[[ -n "$theme[mark]}" ]] && ZUI[mark]="$theme[mark]"
[[ -n "$theme[mark2]}" ]] && ZUI[mark2]="$theme[mark2]"
[[ -n "$theme[altmark]}" ]] && ZUI[altmark]="$theme[altmark]"
[[ -n "$theme[altmark2]}" ]] && ZUI[altmark2]="$theme[altmark2]"
}
# }}}
# FUNCTION: -zcrasis_switch_theme {{{
# Switches theme during operation of Crasis (not
# at startup).
#
# $1 - theme name (not path, no .cr-theme extension)
-zcrasis_switch_theme() {
-zui_std_strip_color_codes "$1"
CRASIS_THEME="$REPLY"
-zcrasis_process_theme
-zcrasis_set_zui_settings
}
# }}}
# FUNCTION: -zcrasis_switch_layout {{{
# Switches layout during operation of Crasis (not
# at startup).
#
# $1 - layout name (not path, no .cr-theme extension)
-zcrasis_switch_layout() {
-zui_std_strip_color_codes "$1"
CRASIS_LAYOUT="$REPLY"
-zcrasis_process_theme
-zcrasis_set_zui_settings
}
# }}}
# FUNCTION: -zcrasis_action_save_options {{{
# Stores current settings to $ZCRASIS_REPO_DIR/crasis.conf.
# Outputs status message.
-zcrasis_action_save_options() {
local out="$ZCRASIS_REPO_DIR/crasis.conf"
print -r -- "local theme_name=${CRASIS_THEME} # Name of active theme. \$CRASIS_THEME overrides." >| "$out"
print -r -- "local move_unicode_buttons=${theme[ud-unicode-bool]} # Use unicode glyphs for up & down buttons?" >>| "$out"
print -r -- "local toggle_unicode_buttons=${theme[ed-unicode-bool]} # Use unicode glyphs for enable & disable buttons?" >>| "$out"
print -r -- "local delete_unicode_button=${theme[delete-unicode-bool]} # Use unicode glyphs for disable button?" >>| "$out"
-zui_std_stalog "Configuration saved to: " "$out"
}
# }}}
-zcrasis_process_theme || return 1
-zcrasis_set_zui_settings
# FUNCTION: -zcrasis-tokenize-zsh-rc {{{
# Runs -zcrasis-process-buffer() on $zshrc (containing the loaded
# .zshrc file). The *-process-buffer() is a general function that
# exists in other projects, is an autoload function, and is kept
# in separate file "-zcrasis-process-buffer".
-zcrasis-tokenize-zsh-rc() {
-zcrasis-process-buffer "$zshrc" 1
}
# }}}
# FUNCTION: -zcrasis_verify_tokenization {{{
# To large extent verifies if tokenization was correct.
# Also removes the test-tokens added to input zshrc.
-zcrasis_verify_tokenization() {
local lasta="${ZCR_PB_WORDS[-1]}" lastb="${ZCR_PB_ALL[-2]}"
if [[ "$lasta" != "test" || "$lastb" != "test" ]]; then
return 1
fi
ZCR_PB_WORDS[-1]=()
ZCR_PB_SPACES[-1]=()
ZCR_PB_SPACES[-1]="${ZCR_PB_SPACES[-1]%$'\n'}"
ZCR_PB_ALL[-2,-1]=()
ZCR_PB_ALL[-1]="${ZCR_PB_ALL[-1]%$'\n'}"
return 0
}
# }}}
# FUNCTION: -zcrasis_tokenization_failed {{{
# Outputs a message that zshrc didn't parse, and
# includes information what can be a possible cause.
-zcrasis_tokenization_failed() {
print -r -- "Failed to parse zshrc. Possible causes:"
print -r -- ""
print -r -- "1. Zsh <= 5.4.2 doesn't parse closing parenthesis ')' for '\$('"
print -r -- " if it is at other line, not at the same line as '\$('. So:"
print -r -- ""
print -r -- " \$(ls -1 | perl -alne 'echo foo')"
print -r -- ""
print -r -- " will parse correctly, while:"
print -r -- ""
print -r -- " \$(ls -1 | perl -alne 'echo foo'"
print -r -- " )"
print -r -- ""
print -r -- " will not. A more sophisticated not-parsing example:"
print -r -- ""
print -r -- " asmcmds+=(\${(o)\$(ls -1 | perl -alne 'echo foo'"
print -r -- " )})"
print -r -- ""
print -r -- "2. A regular syntax error may exist, try: zcompile .zshrc, or"
print -r -- " start a zsh session and see if there are error messages."
print -r -- ""
}
# }}}
# FUNCTION: -zcrasis-process-zsh-rc {{{
# Parses tokens of the loaded zshrc and detects:
# - functions
# - block preceding zinit commands
# - block with those commands
# - block following them
#
# Uses parameters filled by -zcrasis-process-buffer:
# - $ZCR_PB_WORDS - tokens
# - $ZCR_PB_SPACES - spaces in front of each token, +1 at the end
-zcrasis-process-zsh-rc() {
integer i j size="${#ZCR_PB_WORDS}"
for (( i=1; i<=size; ++ i )); do
token="${ZCR_PB_WORDS[i]}"
spaces="${ZCR_PB_SPACES[i]}"
next_token="${ZCR_PB_WORDS[i+1]}"
next_spaces="${ZCR_PB_SPACES[i+1]}"
cur_fun=0 prev_fun=0 descentff=0 descentfa=0
nested_fun=0 prev_nested_fun=0
(( next_fun )) && { next_fun=0 cur_fun=1 prev_fun=0 anon_depth=-1; }
(( next_nested_fun )) && { next_nested_fun=0 nested_fun=1 prev_nested_fun=0; }
# Explicit future-function
if [[ "$token" = "function"(|$'\r') && ( "$fun_depth" -lt 0 ) && ( $anon_depth -lt 0 ) ]]; then
next_fun=1 cur_fun=0 prev_fun=0 anon_depth=-1
# Detect top-level prev-function differentiating from anonymous function
elif [[ "$token" = "()"(|$'\r') && ( "$fun_depth" -lt 0 ) && ( $anon_depth -lt 0 ) ]]; then
if [[ "$spaces" = *$'\n'* || -z "$prev_token" || "${TOKEN_TYPES[$prev_token]}" = [1234] ]]; then
next_fun=0 cur_fun=0 prev_fun=0 anon_depth=$depth
else
next_fun=0 cur_fun=0 prev_fun=1 anon_depth=-1
fi
# Must be a nested future-function
elif [[ "$token" = "function"(|$'\r') ]]; then
next_nested_fun=1 nested_fun=0 prev_nested_fun=0
# Is it a nested prev-function?
elif [[ "$token" = "()"(|$'\r') && "$nested_fun" -eq 0 && "$depth" -gt "$fun_stack_depths[-1]" ]]; then
if [[ "$spaces" != *$'\n'* && -n "$prev_token" && "${TOKEN_TYPES[$prev_token]}" != [1234] ]]; then
next_nested_fun=0 nested_fun=0 prev_nested_fun=1
fi
elif [[ "$token" = "{"(|$'\r') ]]; then
(( ++ depth ))
elif [[ "$token" = "}"(|$'\r') ]]; then
(( -- depth ))
fi
# Check if any final function-flag is raised
if (( cur_fun )); then
fun_name="${token%$'\r'}"
fun_depth="$depth"
fun_stack_depths+=( "$depth" )
elif (( prev_fun )); then
fun_name="${prev_token%$'\r'}"
fun_depth="$depth"
fun_stack_depths+=( "$depth" )
fi
# Track nested functions
if (( nested_fun + prev_nested_fun )); then
fun_stack_depths+=( "$depth" )
fi
# Ascent to function - skip '{'
if (( fun_depth >= 0 && depth == (fun_depth + 1) )) && [[ "$token" = "{"(|$'\r') ]]; then
:
# In function
elif (( fun_depth >= 0 && depth > fun_depth )); then
if [[ "$token" != [[:blank:]]#\#* ]]; then
: # do something with a non-comment function token
fi
# Handle descent from nested function
if (( ${#fun_stack_depths} > 0 && depth == fun_stack_depths[-1] && prev_depth == fun_stack_depths[-1] + 1 )); then
fun_stack_depths[-1]=()
fi
# In anonymous-function
elif (( anon_depth >= 0 && depth > anon_depth )); then
if (( ${#fun_stack_depths} > 0 && depth == fun_stack_depths[-1] && prev_depth == fun_stack_depths[-1] + 1 )); then
fun_stack_depths[-1]=()
fi
# Descent from function - skip '}'
elif (( fun_depth >= 0 && depth == fun_depth && prev_depth == fun_depth + 1 )); then
descentff=1
# Descent from anon
elif (( anon_depth >= 0 && depth == anon_depth && prev_depth == anon_depth + 1 )); then
descentfa=1
fi
# Anon function in top-level
if (( anon_depth >= 0 && fun_depth < 0 )); then
[[ "$token" != [[:blank:]]#\#* ]] && : # do something with non-comment anon-function token
fi
# Check for introduction of Zinit call
if [[ "$spaces" = *$'\n'* || -z "$prev_token" || "${TOKEN_TYPES[$prev_token]}" = [1234] ]]; then
if [[ $spaces != [[:blank:]]#"\\"(|$'\r')$'\n'[[:blank:]]# || ${TOKEN_TYPES[$prev_token]} = [1234] ]]; then
at_command=1
[[ "$token" != [[:blank:]]#\#* ]] && in_zinit=0 || { (( in_zinit )) && in_zinit=1; }
fi
(( in_zinit )) && {
(( 2*i - 1 - post_block_begin > 7*4 )) && { -zui_std_stalog "WARNING:" " many non-Zinit commands in Zinit block"; }
# A new command (i.e. $spaces has a new line, etc.) - move the post-block pointer
post_block_begin=2*i-1
}
fi
# Command token
if (( at_command )); then
at_command=0
# Zinit call not in function
if [[ "$cur_fun" -eq 0 && "$next_token" != "()"(|$'\r') && "$fun_stack_depths[-1]" -le "0" ]]; then
if [[ "$token" = (zplugin|zplg|zinit) || ( "$token" = ":" && "$next_token" = (zplugin|zplg|zinit) ) ]]; then
in_zinit=1
(( was_zinit == 0 )) && {
for (( j=i-1; j >= 1; j -- )); do
[[ "${ZCR_PB_WORDS[j]}" != [[:blank:]]#\#* || "${ZCR_PB_SPACES[j+1]}" = *$'\n'*$'\n'* ]] && { pre_block_end=2*j; break; }
done
}
was_zinit=1
# Revive at_command mode if disabled zinit command
[[ "$token" = ":" ]] && at_command=1
fi
fi
fi
# Late disable of anonymous function
if (( descentfa )); then
anon_depth=-1
# Late disable of normal function
elif (( descentff )); then
fun_name=""
fun_depth=-1
fun_stack_depths[-1]=()
# No-function text gathering
elif (( next_fun == 0 && cur_fun == 0 && prev_fun == 0 && anon_depth < 0 && fun_depth < 0 )); then
if [[ "$next_token" != "()"(|$'\r') || "$next_spaces" = *$'\n'* || "${TOKEN_TYPES[$token]}" = [34] ]]; then
[[ "$token" != [[:blank:]]#\#* ]] && : # do something with script-body token
fi
fi
# History of state
prev_depth="$depth"
prev_token="$token"
prev_spaces="$spaces"
done
# If zinit command ended the zshrc, detect it here
(( in_zinit )) && post_block_begin=2*i-1
if (( pre_block_end == 0 )); then
(( post_block_begin == 0 )) && pre_block_end=2*(i-1)
else
j=0+(pre_block_end/2)
# Soft command-separator?
if [[ "${TOKEN_TYPES[${ZCR_PB_WORDS[j]}]}" = "3" ]]; then
integer found=0
for (( j=(pre_block_end/2)-1; j>=1; -- j )); do
token="${ZCR_PB_WORDS[j]}"
spaces="${ZCR_PB_SPACES[j]}"
next_token="${ZCR_PB_WORDS[j+1]}"
next_spaces="${ZCR_PB_SPACES[j+1]}"
(( j >= 2 )) && prev_token="${ZCR_PB_WORDS[j-1]}" || prev_token=""
if [[ "${TOKEN_TYPES[$token]}" = "4" ]]; then
found=1
pre_block_end=2*j
break
# Soft command separator can have spaces after it
elif [[ "$spaces" = *$'\n'* && "${TOKEN_TYPES[$prev_token]}" != "3" ]]; then
pre_block_end=2*(j-1)
found=1
break
fi
done
# Didn't found, and therefore reached beginning of file
(( found == 0 )) && pre_block_end=0
fi
fi
if (( post_block_begin == 0 )); then
post_block_begin=2*i-1
else
# Detect not related trailing comments
for (( j=(post_block_begin+1)/2-1; j >= 1; -- j )); do
[[ "${ZCR_PB_WORDS[j]}" = [[:blank:]]#\#* && "${ZCR_PB_WORDS[j]}" != [[:blank:]]#\#[[:blank:]]#zinit* ]] && {
post_block_begin=2*j-1
} || break
done
# Detect if compinit follows
integer count=$(( size-(post_block_begin+1)/2 ))
local next_token_2
(( count = (count > 15) ? 15 : count ))
for (( j=(post_block_begin+1)/2; count > 0; ++ j, -- count )); do
token="${ZCR_PB_WORDS[j]}"
next_token="${ZCR_PB_WORDS[j+1]}"
next_token_2="${ZCR_PB_WORDS[j+2]}"
next_spaces="${ZCR_PB_SPACES[j+1]}"
if [[ "$token" = "autoload" && ( "$next_token" = "compinit" || "$next_token_2" = "compinit" ) ]]; then
[[ "$next_token" = "compinit" ]] && { post_block_begin=2*(j+2)-1; j+=1; count=count-1; }
[[ "$next_token_2" = "compinit" ]] && { post_block_begin=2*(j+3)-1; j+=2; count=count-2; }
elif [[ "$token" = "compinit" && ( "$next_spaces" = *$'\n'* || "${TOKEN_TYPES[$next_token]}" = 4 ) ]]; then
# TODO: soft-connected following tokens can be also included
post_block_begin=2*(j+1)-1
break
fi
done
fi
}
# }}}
# FUNCTION: -zcrasis-process-zinit-commands {{{
# Processes block with zinit commands established earlier
# in -zcrasis-process-zsh-rc() and generates $cmdlist array
# which holds serialized hashes of every zinit invocation,
# mixed-in additional (external) commands, comments.
#
# Uses parameters filled by -zcrasis-process-buffer:
# - $ZCR_PB_WORDS - tokens
# - $ZCR_PB_SPACES - spaces in front of each token, +1 at the end
-zcrasis-process-zinit-commands() {
integer i
cmd3=()
# Reset parameters used in -zcrasis-process-zsh-rc
prev_depth=0 prev_token="" prev_spaces=""
# From start to end of zinit block
for (( i=(pre_block_end/2)+1; i<=(post_block_begin+1)/2-1; ++ i )); do
token="${ZCR_PB_WORDS[i]}"
spaces="${ZCR_PB_SPACES[i]}"
next_token="${ZCR_PB_WORDS[i+1]}"
next_spaces="${ZCR_PB_SPACES[i+1]}"
# New command?
if [[ "$spaces" = *$'\n'* || -z "$prev_token" || "${TOKEN_TYPES[$prev_token]}" = [1234] ]]; then
if [[ "${TOKEN_TYPES[$prev_token]}" = [34] ]]; then
# When command ends with explicit command separator,
# then remember white spaces after that separator
cmd3[aspaces]="$spaces"
elif [[ "$spaces" != (|$'\r')$'\n' ]]; then
# Remember spaces if they're not single newline, and
# if what follows isn't a comment. So basically spaces
# between commands are remembered. Spaces before comments
# are not (but comment-remembering handles this)
if [[ "$token" != [[:blank:]]#\#* ]]; then
cmd3[aspaces]="$spaces"
else
unset 'cmd3[aspaces]'
fi
else
unset 'cmd3[aspaces]'
fi
if [[ "$spaces" != [[:blank:]]#"\\"(|$'\r')$'\n'[[:blank:]]# ]]; then
in_zinit=1
if [[ "${cmd3[c]}" = (zplugin|zinit) && "${cmd3[sub]}" = "ice" ]]; then
cmdlist[coidx+1]="${(j: :)${(qkv)cmd3[@]}}"
elif [[ "${cmd3[c]}" = (zplugin|zinit) && "${cmd3[sub]}" != "ice" ]]; then
cmdlist[coidx+2]="${(j: :)${(qkv)cmd3[@]}}"
coidx+=3
else
# Don't increase coidx untill we get some command.
# This causes preceding comments to accumulate.
if [[ -n "${cmd3[c]}" ]]; then
# Custom command
cmdlist[coidx+2]="${(j: :)${(qkv)cmd3[@]}}"
coidx+=3
fi
fi
cmd3=()
fi
fi
# Command token
if [[ "$token" = [[:blank:]]#\#* ]]; then
if (( in_zinit == 1 )); then
cmdlist[coidx]="${cmdlist[coidx]%%[[:space:]]##}"
cmdlist[coidx]+="$spaces$token$next_spaces"
else
cmd3[comment]="$spaces$token"
fi
elif (( in_zinit == 1 )); then
[[ "$token" = (zplugin|zplg|zinit) ]] && "${cmd3[c]}" = (zplugin|zinit) || cmd3[c]="$token"
# Postpone current state to next token
[[ "$token" = ":" ]] && { cmd3[disabled]=1; (( in_zinit -- )); }
elif (( in_zinit == 2 )); then
if [[ "${cmd3[c]}" = (zplugin|zinit) ]]; then
[[ "$token" = (ice|load|light|snippet|cdclear|
cdreplay|env-whitelist|create)
]] && {
cmd3[sub]="$token"
# We get another ice-command while a previous ice-command
# is still being pointed to by coidx? -> progress coidx
[[ "$token" = ice && -n "${cmdlist[coidx+1]}" ]] && \
coidx+=3
((1))
} || \
{ cmd3[sub]="unkn"; cmd3[unkn]="$token"; }
else
cmd3[arg_1]="$token"
cmd3[spaces_1]="$spaces"
fi
else
if [[ "${cmd3[sub]}" = "ice" ]]; then
# Also dequote the ice modifier
[[ "$token" = (#b)(${(~j:|:)ice_order})(?)(?)(*)(?) || \
"$token" = (#b)(${(~j:|:)ice_order})(*)
]] && {
local key="${match[1]}" string="${match[2]#[:=]}${match[3]}${match[4]}${match[5]}"
local second="${match[2]}" third="${match[3]}" last="${match[5]}"
cmd3[$key]="${string//(#b)(:|=|)([\"\']|\$\'|)(*)[\"\']/${match[3]}}"
# Remember also the quoting style, if the quoting
# is a recognized one
[[ ( -n "$second" && "$second" = "$last" ) || \
"$second" = (:|=)* # Via the star this handles both matchings
]] && \
cmd3[${key}_style]="${second[1]}" || {
[[ "$second" = '$' && "$third" = "'" ]] && \
cmd3[${key}_style]="\$'"
}
((1))
} || {
cmd3[custom_$(( in_zinit - 2 ))]="$token"
cmd3[spaces_$(( in_zinit - 2 ))]="$spaces"
}
elif [[ "${cmd3[sub]}" = (load|light) ]]; then
if (( in_zinit == 4 )); then
cmd3[url]+="/$token"
elif (( ${+cmd3[url]} == 0 )); then
cmd3[url]="$token"
else
cmd3[custom_$(( in_zinit - 2 ))]="$token"
cmd3[spaces_$(( in_zinit - 2 ))]="$spaces"
fi
elif [[ "${cmd3[sub]}" = "snippet" ]]; then
if [[ "$token" = "-f" ]]; then
cmd3[-f]="1"
elif [[ "$token" = "--command" ]]; then
cmd3[--command]="1"
elif [[ ${+cmd3[url]} != 1 && "${TOKEN_TYPES[$token]}" != [34] ]]; then
cmd3[url]="$token"
else
cmd3[custom_$(( in_zinit - 2 ))]="$token"
cmd3[spaces_$(( in_zinit - 2 ))]="$spaces"
fi
elif [[ "${cmd3[sub]}" = "cdclear" ]]; then
[[ "$token" = "-q" ]] && cmd3[-q]="1" || {
cmd3[custom_$(( in_zinit - 2 ))]="$token"
cmd3[spaces_$(( in_zinit - 2 ))]="$spaces"
}
elif [[ "${cmd3[sub]}" = "cdreplay" ]]; then
[[ "$token" = "-q" ]] && cmd3[-q]="1" || {
cmd3[custom_$(( in_zinit - 2 ))]="$token"
cmd3[spaces_$(( in_zinit - 2 ))]="$spaces"
}
elif [[ "${cmd3[sub]}" = "unkn" ]]; then
# Argument following "zinit <unknown> ..."
cmd3[arg_$(( in_zinit - 2 ))]="$token"
else
# Argument following "<unknown> <arg_1> ..."
cmd3[arg_$(( in_zinit - 1 ))]="$token"
cmd3[spaces_$(( in_zinit - 1 ))]="$spaces"
fi
fi
# Advance deeper into "zinit ..." if it wasn't comment
#[[ "$token" != [[:blank:]]#\#* ]] && in_zinit+=1
in_zinit+=1
# History of state
prev_depth="$depth"
prev_token="$token"
prev_spaces="$spaces"
done
if [[ -n "${cmd3[c]}" ]];then
if [[ "${cmd3[c]}" = (zplugin|zinit) && "${cmd3[sub]}" = "ice" ]]; then
cmdlist[coidx+1]="${(j: :)${(qkv)cmd3[@]}}"
elif [[ "${cmd3[c]}" = (zplugin|zinit) && "${cmd3[sub]}" != "ice" ]]; then
cmdlist[coidx+2]="${(j: :)${(qkv)cmd3[@]}}"
elif [[ "${cmd3[c]}" = (zplugin|zinit) ]]; then
cmdlist[coidx+2]="${(j: :)${(qkv)cmd3[@]}}"
fi
-zcrasis_dbg_msg "Zinit block in zshrc has $(( (coidx + 2) / 3 )) commands (not counting \`zinit ice ...')"
else
-zcrasis_dbg_msg "Zinit block in zshrc has $(( (coidx-1) / 3 )) commands (not counting \`zinit ice ...')"
fi
-zcrasis_dbg_msg ""
}
# }}}
# FUNCTION: -zcrasis_util_swap {{{
# Swaps two variables given by name. Uses (P) substitution
# flag, can swap e.g. hash entries. For example:
# local -A hash_arr=( a b c d )
# -zcrasis_util_swap 'hash_arr[a]' 'hash_arr[b]'
#
# $1 - name of first variable to swap
# $2 - name of second variable to swap
-zcrasis_util_swap() {
local __var_name1="$1" __var_name2="$2" __tmp
integer set1="${(P)+__var_name1}" set2="${(P)+__var_name2}"
if (( set1 && set2 )); then
tmp="${(P)__var_name1}"
: ${(P)__var_name1::=${(P)__var_name2}}
: ${(P)__var_name2::=$tmp}
elif (( set1 && !set2 )); then
: ${(P)__var_name2::=${(P)__var_name1}}
unset $__var_name1
elif (( !set1 && set2 )); then
: ${(P)__var_name1::=${(P)__var_name2}}
unset $__var_name2
fi
}
# }}}
# FUNCTION: -zcrasis_action_move_up {{{
# Moves given instance ($2) up, i.e. swaps current and
# previous instance. Using "instance" here means: ZUI's
# module instance representing single zinit command
# (possibly preceded with "zinit ice ..." invocation)
# by the design of Crasis. Instance = invocation of a
# generator with "module_idx" "instance_idx" arguments.
#
# $1 - module index (will be 2)
# $2 - instance index
-zcrasis_action_move_up() {
local mod="$1" ice="$2" t
local -a cmd1 cmd2
(( (ice-1-1)*3+1 > ${#cmdlist} || (ice-1)*3 > ${#cmdlist} || (ice-1)*3+1 > ${#cmdlist} || ice*3 > ${#cmdlist} )) && return 1
cmd1=( "${(@)cmdlist[(ice-1-1)*3+1,(ice-1)*3]}" )
cmd2=( "${(@)cmdlist[(ice-1)*3+1,ice*3]}" )
cmdlist[(ice-1-1)*3+1,(ice-1)*3]=( "${cmd2[@]}" )
cmdlist[(ice-1)*3+1,ice*3]=( "${cmd1[@]}" )
noglob -zcrasis_util_swap ZUI[toggle_dis_${mod}_${ice}] ZUI[toggle_dis_${mod}_$(( ice-1 ))]
noglob -zcrasis_util_swap ZUI[toggle_command_${mod}_${ice}] ZUI[toggle_command_${mod}_$(( ice-1 ))]
noglob -zcrasis_util_swap ZUI[toggle_force_${mod}_${ice}] ZUI[toggle_force_${mod}_$(( ice-1 ))]
noglob -zcrasis_util_swap ZUI[toggle_mode_${mod}_${ice}] ZUI[toggle_mode_${mod}_$(( ice-1 ))]
for t in "${ice_order[@]}"; do
noglob -zcrasis_util_swap ZUI[my_tfield4_${ice}_${t}_width] ZUI[my_tfield4_$(( ice-1 ))_${t}_width]
noglob -zcrasis_util_swap ZUI[my_tfield4_${ice}_${t}_start] ZUI[my_tfield4_$(( ice-1 ))_${t}_start]
noglob -zcrasis_util_swap ZUI[my_tfield4_${ice}_${t}_data] ZUI[my_tfield4_$(( ice-1 ))_${t}_data]
done
return 0
}
# }}}
# FUNCTION: -zcrasis_action_move_down {{{
# Moves given instance ($2) down, i.e. swaps current and
# next instance. Using "instance" here means: ZUI's
# module instance representing single zinit command
# (possibly preceded with "zinit ice ..." invocation)
# by the design of Crasis. Instance = invocation of a
# generator with "module_idx" "instance_idx" arguments.
#
# $1 - module index (will be 2)