Journal Articles with starting and ending page but no issue nor volume number.

[eliarizzetto]

There are journal articles in Meta that, despite not having metadata about the volume or issue in which they are published, appear to have a starting and ending page. Since the page interval refers to the position of the article within the container publication, rather than the absolute length of the article itself, this scenario shouldn't be possible.

Most of the articles involved in this issue are probably Online First publications, i.e articles published online ahead of print, whose metadata (including page numbers) has been made available in one of Meta's primary sources without specifying the issue/volume in which they were hosted (at least prior to the time of ingestion into Meta). This kind of "partial" metadata typically have "1" as their starting page (as, indeed, the page numbers refer to the lenght of the article and not to the actual page interval in the venue).

Below, a SPARQL query that can be used to retrieve some examples (run on Sept. 30 2024).

PREFIX datacite: <http://purl.org/spar/datacite/>
PREFIX literal: <http://www.essepuntato.it/2010/06/literalreification/>
PREFIX prism: <http://prismstandard.org/namespaces/basic/2.0/>
PREFIX fabio: <http://purl.org/spar/fabio/>
PREFIX frbr: <http://purl.org/vocab/frbr/core#>

SELECT ?br ?doi {
  ?br frbr:embodiment/prism:startingPage "1";  # more likely to be reffering to article's lenght
    datacite:hasIdentifier ?id;
    a fabio:JournalArticle.
  ?id datacite:usesIdentifierScheme datacite:doi;
      literal:hasLiteralValue ?lit.
  BIND(CONCAT("https://doi.org/", ?lit) AS ?doi)
  
  FILTER NOT EXISTS { 
    ?br frbr:partOf ?venue.
    ?venue a fabio:JournalIssue.
  }
  FILTER NOT EXISTS { 
    ?br frbr:partOf ?venue.
    ?venue a fabio:JournalVolume.
  }
}
LIMIT 10

Which returned the following result:

	br	doi
1	https://w3id.org/oc/meta/br/06701633311	https://doi.org/10.1080/02640414.2021.1904694
2	https://w3id.org/oc/meta/br/06701633313	https://doi.org/10.1080/02640414.2021.1902138
3	https://w3id.org/oc/meta/br/06701633320	https://doi.org/10.1080/02640414.2021.1906523
4	https://w3id.org/oc/meta/br/06701633321	https://doi.org/10.1080/02640414.2021.1907902
5	https://w3id.org/oc/meta/br/06701633326	https://doi.org/10.1080/02640414.2021.1903706
6	https://w3id.org/oc/meta/br/06701633327	https://doi.org/10.1080/02640414.2021.1907062
7	https://w3id.org/oc/meta/br/06701633328	https://doi.org/10.1080/02640414.2021.1899610
8	https://w3id.org/oc/meta/br/06701633329	https://doi.org/10.1080/02640414.2021.1898174
9	https://w3id.org/oc/meta/br/06701633334	https://doi.org/10.1080/02640414.2021.1898193
10	https://w3id.org/oc/meta/br/06701633335	https://doi.org/10.1080/02640414.2021.1898175