build.gradle

description = "Spring for GraphQL"

ext {
	moduleProjects = [project(":spring-graphql"), project(":spring-graphql-test")]
	springFrameworkVersion = "6.0.14"
	graphQlJavaVersion = "20.7"
	springBootVersion = "3.1.5"
}

subprojects {
	apply plugin: 'org.springframework.graphql.build.conventions'
	group = 'org.springframework.graphql'

	repositories {
		mavenCentral()
		maven {
			url "https://repo.spring.io/milestone"
			content {
				includeGroup "org.springframework.boot"
			}
		}
		if (version.contains('-')) {
			maven { url "https://repo.spring.io/milestone" }
		}
		if (version.endsWith('-SNAPSHOT')) {
			maven { url "https://repo.spring.io/snapshot" }
		}
	}
}

configure(moduleProjects) {
	apply plugin: 'java-library'
	apply plugin: 'java-test-fixtures'

	java {
		toolchain {
			languageVersion = JavaLanguageVersion.of(17)
		}
	}

	configurations {
		dependencyManagement {
			canBeConsumed = false
			canBeResolved = false
			visible = false
		}
		matching { it.name.endsWith("Classpath") }.all { it.extendsFrom(dependencyManagement) }
	}

	dependencies {
		dependencyManagement(enforcedPlatform(dependencies.project(path: ":platform")))
	}

	ext.javadocLinks = [
			"https://docs.oracle.com/en/java/javase/17/docs/api/",
			"https://docs.spring.io/spring-framework/docs/6.0.x/javadoc-api/",
			"https://javadoc.io/doc/com.graphql-java/graphql-java/20.7/"
	] as String[]

	components.java.withVariantsFromConfiguration(configurations.testFixturesApiElements) { skip() }
	components.java.withVariantsFromConfiguration(configurations.testFixturesRuntimeElements) { skip() }
	
	apply from: "${rootDir}/gradle/publishing.gradle"
}