From a3dc993bcd732585cded431855fc71240eaa0f69 Mon Sep 17 00:00:00 2001
From: Die4Ever <die4ever2005@gmail.com>
Date: Tue, 18 Apr 2023 11:00:09 -0500
Subject: [PATCH] Randomizer shuffle items

---
 Classes/Randomizer.uc | 75 +++++++++++++++++++++++++++++++++++++++++++
 UT99CrowdControl.int  |  1 +
 2 files changed, 76 insertions(+)
 create mode 100644 Classes/Randomizer.uc

diff --git a/Classes/Randomizer.uc b/Classes/Randomizer.uc
new file mode 100644
index 0000000..af2b3a2
--- /dev/null
+++ b/Classes/Randomizer.uc
@@ -0,0 +1,75 @@
+class Randomizer extends Mutator;
+
+function InitRando()
+{
+    ShuffleItems();
+}
+
+function ShuffleItems()
+{
+    local Inventory item, items[512], weapons[128];
+    local int num_items, num_weapons, i, slot;
+
+    foreach AllActors(class'Inventory', item) {
+        if(item.Owner != None) continue;
+        if(Weapon(item) != None)
+            weapons[num_weapons++] = item;
+        else
+            items[num_items++] = item;
+    }
+
+    for(i=0; i<num_items; i++) {
+        slot = Rand(num_items);
+        if(slot != i)
+            SwapActors(items[i], items[slot]);
+    }
+
+    for(i=0; i<num_weapons; i++) {
+        slot = Rand(num_weapons);
+        if(slot != i)
+            SwapActors(weapons[i], weapons[slot]);
+    }
+}
+
+function SwapActors(Actor a, Actor b)
+{
+    local vector locA;
+    local Rotator rotA;
+
+    locA = a.Location;
+    rotA = a.Rotation;
+    a.SetLocation(b.Location);
+    a.SetRotation(b.Rotation);
+    b.SetLocation(locA);
+    b.SetRotation(rotA);
+}
+
+simulated function PreBeginPlay()
+{
+   InitRando();
+   CheckServerPackages();
+}
+
+function CheckServerPackages()
+{
+    local string packages;
+
+    if (Level.NetMode!=NM_DedicatedServer && Level.NetMode!=NM_ListenServer){
+        //Not hosting a server, don't worry about it
+        return;
+    }
+
+    packages=ConsoleCommand("get Engine.GameEngine ServerPackages");
+    if (InStr(packages,"UT99CrowdControl")!=-1){
+        log("UT99CrowdControl is set in ServerPackages!  Nice!");
+    } else {
+        log("UT99CrowdControl is not set in ServerPackages!  Bummer!");
+        packages = Left(packages,Len(packages)-1)$",\"UT99CrowdControl\")";
+        log("Added UT99CrowdControl to ServerPackages!");
+        ConsoleCommand("set Engine.GameEngine ServerPackages "$packages);
+
+        //Reload the level so that the serverpackages gets updated for real
+        log("Restarting game so that ServerPackages are reloaded");
+        Level.ServerTravel( "?Restart", false );
+    }
+}
diff --git a/UT99CrowdControl.int b/UT99CrowdControl.int
index abee803..92f3594 100644
--- a/UT99CrowdControl.int
+++ b/UT99CrowdControl.int
@@ -1,5 +1,6 @@
 [Public]
 
 Object=(Name=UT99CrowdControl.CrowdControl,Class=Class,MetaClass=Engine.Mutator,Description="Crowd Control support for UT99")
+Object=(Name=UT99CrowdControl.Randomizer,Class=Class,MetaClass=Engine.Mutator,Description="Randomizer for UT99")
 Object=(Name=UT99CrowdControl.UT99CCStartTournyMenuItem,Class=Class,MetaClass=UMenu.UMenuModMenuItem,Description="Start Crowd Control Tournament,Crowd Control Tournament")
 Object=(Name=UT99CrowdControl.UT99CCLoadTournyMenuItem,Class=Class,MetaClass=UMenu.UMenuModMenuItem,Description="Resume Crowd Control Tournament,Crowd Control Tournament")
\ No newline at end of file