CraftTweaker for Heating Coils

Note that you should not specify a #loader when changing Heating Coils.

Adding a new block as a heating coil: HeatingCoils.add(IBlockState state, String name, int temperature, int level, int discount, int tier, Material material).

import mods.gregtech.blocks.HeatingCoils;

// register a heating coil made from Minecraft's Dirt
// 1400K temperature
// Level 2 (32 * 2 multismelter parallel)
// Discount 4 (16 / 4 EU/t in multismelter per item)
// Tier 3 (used for discount in the cracker and pyrolyse oven)
// Material null (uses the Dirt block for JEI name)
HeatingCoils.add(<blockstate:minecraft:dirt:variant=dirt,snowy=false>, "dirt", 1400, 2, 4, 3, null);


// register a heating coil made from Minecraft's Oak Planks
// 1900K temperature
// Level 1 (32 * 1 multismelter parallel)
// Discount 2 (16/2 EU/t in multismelter per item)
// Tier 3 (used for discount in the cracker and pyrolyse oven)
// Material Silver (uses the Silver material for JEI name)
HeatingCoils.add(<blockstate:minecraft:planks:variant=oak>, "planks", 1900, 1, 2, 3, <material:silver>);

Removing an existing Heating Coil: HeatingCoils.remove(IBlockState state).

import mods.gregtech.blocks.HeatingCoils;

// This can and will easily break the base mod's progression, be sure to have a way around that!

// Remove the cupronickel coil
HeatingCoils.remove(<blockstate:gregtech:wire_coil:variant=cupronickel,active=false>);