Add FlxTween.shake for sprite shaking.

flixel/tweens/FlxTween.hx

@@ -1,5 +1,7 @@
 package flixel.tweens;
 
+import flixel.tweens.misc.ShakeTween;
+import flixel.util.FlxAxes;
 import flixel.FlxG;
 import flixel.FlxObject;
 import flixel.FlxSprite;
@@ -130,6 +132,26 @@ class FlxTween implements IFlxDestroyable
 		return globalManager.num(FromValue, ToValue, Duration, Options, TweenFunction);
 	}
 
+	/**
+	 * A simple shake effect for FlxSprite. Shorthand for creating a ShakeTween, starting it and adding it to the TweenManager.
+	 *
+	 * ```haxe
+	 * FlxTween.shake(Sprite, 0.1, 2, FlxAxes.XY, { ease: easeFunction, onStart: onStart, onUpdate: onUpdate, onComplete: onComplete, type: ONESHOT });
+	 * ```
+	 * 
+	 * @param	Sprite       Sprite to shake.
+	 * @param   Intensity    Percentage representing the maximum distance
+	 *                       that the sprite can move while shaking.
+	 * @param   Duration     The length in seconds that the shaking effect should last.
+	 * @param   Axes         On what axes to shake. Default value is `FlxAxes.XY` / both.
+	 * @param	Options      A structure with tween options.
+	 * @return The added ShakeTween object.
+	 */
+	public static function shake(Sprite:FlxSprite, Intensity:Float = 0.05, Duration:Float = 1, ?Axes:FlxAxes, ?Options:TweenOptions):ShakeTween
+	{
+		return globalManager.shake(Sprite, Intensity, Duration, Axes, Options);
+	}
+
 	/**
 	 * Tweens numeric value which represents angle. Shorthand for creating a AngleTween object, starting it and adding it to the TweenManager.
 	 *
@@ -857,6 +879,27 @@ class FlxTweenManager extends FlxBasic
 		return add(tween);
 	}
 
+	/**
+	 * A simple shake effect for FlxSprite. Shorthand for creating a ShakeTween, starting it and adding it to the TweenManager.
+	 *
+	 * ```haxe
+	 * FlxTween.shake(Sprite, 0.1, 2, FlxAxes.XY, { ease: easeFunction, onStart: onStart, onUpdate: onUpdate, onComplete: onComplete, type: ONESHOT });
+	 * ```
+	 * 
+	 * @param	Sprite       Sprite to shake.
+	 * @param   Intensity    Percentage representing the maximum distance
+	 *                       that the sprite can move while shaking.
+	 * @param   Duration     The length in seconds that the shaking effect should last.
+	 * @param   Axes         On what axes to shake. Default value is `FlxAxes.XY` / both.
+	 * @param	Options      A structure with tween options.
+	 */
+	public function shake(Sprite:FlxSprite, Intensity:Float = 0.05, Duration:Float = 1, ?Axes:FlxAxes = XY, ?Options:TweenOptions):ShakeTween
+	{
+		var tween = new ShakeTween(Options, this);
+		tween.tween(Sprite, Intensity, Duration, Axes);
+		return add(tween);
+	}
+
 	/**
 	 * Tweens numeric value which represents angle. Shorthand for creating a AngleTween object, starting it and adding it to the TweenManager.
 	 *

flixel/tweens/misc/ShakeTween.hx

@@ -0,0 +1,75 @@
+package flixel.tweens.misc;
+
+import flixel.math.FlxPoint;
+import flixel.util.FlxAxes;
+
+/**
+ * Shake effect for a FlxSprite
+ */
+class ShakeTween extends FlxTween
+{
+	/**
+	 * Percentage representing the maximum distance that the object can move while shaking.
+	 */
+	var intensity:Float;
+
+	/**
+	 * Defines on what axes to `shake()`. Default value is `XY` / both.
+	 */
+	var axes:FlxAxes;
+
+	/**
+	 * The sprite to shake.
+	 */
+	var sprite:FlxSprite;
+
+	/**
+	 * Defines the initial offset of the sprite at the beginning of the shake effect.
+	 */
+	var initialOffset:FlxPoint;
+
+	/**
+	 * A simple shake effect for FlxSprite.
+	 *
+	 * @param	Sprite       Sprite to shake.
+	 * @param   Intensity    Percentage representing the maximum distance
+	 *                       that the sprite can move while shaking.
+	 * @param   Duration     The length in seconds that the shaking effect should last.
+	 * @param   Axes         On what axes to shake. Default value is `FlxAxes.XY` / both.
+	 */
+	public function tween(Sprite:FlxSprite, Intensity:Float = 0.05, Duration:Float = 1, Axes:FlxAxes = XY):ShakeTween
+	{
+		intensity = Intensity;
+		sprite = Sprite;
+		duration = Duration;
+		axes = Axes;
+		initialOffset = new FlxPoint(Sprite.offset.x, Sprite.offset.y);
+		start();
+		return this;
+	}
+
+	override function destroy():Void
+	{
+		super.destroy();
+		// Return the sprite to its initial offset.
+		if (sprite != null && !sprite.offset.equals(initialOffset))
+			sprite.offset.set(initialOffset.x, initialOffset.y);
+
+		sprite = null;
+		initialOffset = null;
+	}
+
+	override function update(elapsed:Float)
+	{
+		super.update(elapsed);
+		if (axes != Y)
+			sprite.offset.x = initialOffset.x + FlxG.random.float(-intensity * sprite.width, intensity * sprite.width);
+		if (axes != X)
+			sprite.offset.y = initialOffset.y + FlxG.random.float(-intensity * sprite.height, intensity * sprite.height);
+	}
+
+	override function isTweenOf(Object:Dynamic, ?Field:String):Bool
+	{
+		return sprite == Object && (Field == null || Field == "shake");
+	}
+}

tests/unit/src/flixel/tweens/FlxTweenTest.hx

@@ -1,5 +1,6 @@
 package flixel.tweens;
 
+import flixel.math.FlxPoint;
 import flixel.tweens.FlxTween.TweenCallback;
 import flixel.util.FlxTimer;
 import massive.munit.Assert;
@@ -212,6 +213,29 @@ class FlxTweenTest extends FlxTest
 		};
 	}
 
+	@Test
+	function testCancelShakeTween()
+	{
+		var spriteTest = new FlxSprite();
+		var initialOffset = new FlxPoint(0, 0);
+		var shakeTween = FlxTween.shake(spriteTest, 1, 0.1);
+		step();
+		shakeTween.cancel();
+		Assert.isTrue(shakeTween.finished);
+		Assert.isTrue(spriteTest.offset.equals(initialOffset));
+	}
+
+	@Test
+	function testCompleteShakeTween()
+	{
+		var spriteTest = new FlxSprite();
+		var initialOffset = new FlxPoint(0, 0);
+		var shakeTween = FlxTween.shake(spriteTest, 1, 0.01);
+		step(10);
+		Assert.isTrue(shakeTween.finished);
+		Assert.isTrue(spriteTest.offset.equals(initialOffset));
+	}
+
 	@Test
 	function testCompleteAll()
 	{