bitcomet: init at 2.9.0

pkgs/by-name/bi/bitcomet/package.nix

@@ -0,0 +1,41 @@
+{
+  lib,
+  fetchurl,
+  appimageTools,
+}:
+let
+  pname = "bitcomet";
+  version = "2.9.0";
+  src = fetchurl {
+    url = "https://download.bitcomet.com/linux/x86_64/BitComet-${version}-x86_64.AppImage";
+    sha256 = "ZRhpn78D65m3fQb9Uj2KEZ8ATqB+NU7C9f+xS6uZqWk=";
+  };
+  appimageContents = appimageTools.extractType2 { inherit pname version src; };
+in
+appimageTools.wrapType2 {
+  inherit pname version src;
+
+  extraPkgs =
+    pkgs: with pkgs; [
+      libxml2
+      libpng
+      webkitgtk
+    ];
+
+  extraInstallCommands = ''
+    mkdir -p $out/share/applications
+    install -m 444 ${appimageContents}/com.bitcomet.linux.desktop $out/share/applications/${pname}.desktop
+    substituteInPlace $out/share/applications/${pname}.desktop \
+      --replace-fail 'Exec=usr/bin/BitComet' 'Exec=${pname}'
+    cp -r ${appimageContents}/usr/share/icons $out/share
+  '';
+
+  meta = {
+    homepage = "https://www.bitcomet.com";
+    description = "BitComet is a free BitTorrent download client! BitComet is powerful, super-fast and easy-to-use";
+    sourceProvenance = with lib.sourceTypes; [ binaryNativeCode ];
+    license = lib.licenses.unfree;
+    platforms = [ "x86_64-linux" ];
+    maintainers = with lib.maintainers; [ aucub ];
+  };
+}