Individual Process Testing Where You can Use another process' output as input for the next one

[vasquini]

So I am grateful for the recent updates to nf-test. I can now get multiple process tests even if they are in the same file. I know there's pipeline tests, which I've ran successfully, but my team prefers multiple process tests specifically. I was wondering if there's a way to access the outputs of other processes like how it would be done on regular nextflow. Example: flye(guppy_ch.fastq). Can the tests emit outputs too? And can those inputs be passed as input?

[nvnieuwk]

Couldn't you just write a test workflow that channels all the outputs between the processes and perform a test on this workflow? :)

[sateeshperi]

Thank you for your response @nvnieuwk but, I would like to re-open this issue if possible to get more insights. ping @lukfor @seppinho

• I'm currently interested in transitioning nf-core modules (~ 900 and counting) test framework, which currently runs on pytest, to nf-test.

• While nf-core modules are intended to be independent units, the nature of various bioinformatics tools often requires chaining, resulting in many modules containing two or more processes to create the correct test data. I'm aware that this encroaches into the scope of workflows; however, the motivation remains fundamentally distinct.

Example of Dependent module test:

include { ABRICATE_RUN } from '../../../../../modules/nf-core/abricate/run/main.nf'
include { ABRICATE_SUMMARY } from '../../../../../modules/nf-core/abricate/summary/main.nf'

workflow test_abricate_summary {

    inputs = [
        tuple([ id:'test1', single_end:false ], // meta map
              file(params.test_data['bacteroides_fragilis']['genome']['genome_fna_gz'], checkIfExists: true)),
        tuple([ id:'test2', single_end:false ],
              file(params.test_data['haemophilus_influenzae']['genome']['genome_fna_gz'], checkIfExists: true))
    ]

    ABRICATE_RUN ( Channel.fromList(inputs) )
    ABRICATE_SUMMARY ( 
        ABRICATE_RUN.out.report.collect{ meta, report -> report }.map{ report -> [[ id: 'test_summary'], report]}
    )
}

• This was also previously referenced in this issue Individual Process Testing Where You can Use another process' output as input for the next one #70, but ideally, I would not want to venture out of the process scope here (as one reason being it will be difficult to host test_data for all standalone modules on github).
• Hence, what would be ideal is a way to accommodate generating tests for a process that might need the output from another test.

Ideal solution:

nf-test process can support a depends field which runs the dependent module test first and makes the output channels available as input to the new module.

nextflow_process {

    name "Test Process ABRICATE_SUMMARY"
    script "modules/nf-core/abricate/summary/main.nf"
    process "ABRICATE_SUMMARY"
    depends "ABRICATE_RUN" // requires the test file to be present & runs it before executing the current one

    test("ABRICATE_SUMMARY") {

        when {
            params {
                // define parameters here. Example:
                // outdir = "tests/results"
            }
            process {
                """
                // define inputs of the process here. Example:
                input[0] = ABRICATE_RUN.out.report.collect{ meta, report -> report }.map{ report -> [[ id: 'test_summary'], report]}
                """
            }
        }

        then {
            assert process.success
            assert snapshot(process.out).match()
        }

    }

}

I would be interested to hear your thoughts on the feasabilty of the idea proposed or if you have any other ways we can tackle dependent modules.

Thanks a ton for all your work ❤️

[seppinho]

Good point, we're looking into that to find a solution that fits within the nf-test concept

[sateeshperi]

hello @seppinho checking in to see the status of this issue and if there is any way I could help?

[sateeshperi]

hello @lukfor @seppinho

I wanted to follow up on this issue. This particular issue is critical for its adoption in nf-core. We have a hackathon coming up in October, and it would greatly benefit from having this feature implemented.

Could we get an update on any progress or a tentative timeline? Your assistance will significantly impact our productivity during the hackathon.

Thanks for your hard work and understanding.

[drpatelh]

Thanks @sateeshperi ! Quite a few nf-core/modules use chained processes in this way to overcome the need to generate intermediate test data files. Be awesome to have this implemented natively in nf-test.

[sateeshperi]

@lukfor @seppinho I see this issue has been added to the 0.8.0 milestone but, haven't seen any PRs for it....is there a solution for this ?

[lukfor]

With PR #127, it is now possible to specify processes in the setup method that need to be executed before the when block. The outputs of these processes can then be utilized to define parameters or map processes/workflows. The run method takes the process or workflow name, the (relativ) path to the script file and the input mapping as arguments.

For example, the following testcase for the ABRICATE_SUMMARY module executes the ABRICATE_RUN module to generate the input data:

nextflow_process {

    name "Test process data"

    script "../main.nf"
    process "ABRICATE_SUMMARY"
    config "./nextflow.config"

    test("Should use process ABRICATE_RUN to generate input data") {

        setup {
            
            run("ABRICATE_RUN") {
                script "../../run/main.nf"
                process {
                    """
                    input[0] =  Channel.fromList([
                        tuple([ id:'test1', single_end:false ], // meta map
                            file(params.test_data['bacteroides_fragilis']['genome']['genome_fna_gz'], checkIfExists: true)),
                        tuple([ id:'test2', single_end:false ],
                            file(params.test_data['haemophilus_influenzae']['genome']['genome_fna_gz'], checkIfExists: true))
                    ])
                    """
                }
            }

        }

        when {
            process {
                """
                input[0] = ABRICATE_RUN.out.report.collect{ meta, report -> report }.map{ report -> [[ id: 'test_summary'], report]}
                """
            }
        }

        then {
            assert process.success
            assert snapshot(process.out).match()
        }
    }

}

The full example can be found here: https://github.com/askimed/nf-test/tree/features/dependencies/test-data/process/abricate/summary/tests and more details in PR #127

Happy to hear your feedback! @sateeshperi @drpatelh @emiller88 @nvnieuwk @maxulysse 🚀

[sateeshperi]

works like a charm @lukfor Thanks for the setup 😉

nf-test test --tag abricate --profile docker

🚀 nf-test 0.8.0
https://code.askimed.com/nf-test
(c) 2021 - 2023 Lukas Forer and Sebastian Schoenherr

Found 1 files in test directory.

Test Process ABRICATE_SUMMARY

  Test [21188a7f] 'Should run without failures' PASSED (9.064s)

Test Process ABRICATE_RUN

  Test [50895192] 'Bacteroides Fragilis Genome' PASSED (8.443s)


SUCCESS: Executed 2 tests in 17.509s