Noob

[dodalovic]

Hi,
I'm trying to have this script:

dbHost := if env == "dev" { "XXXX.rds.amazonaws.com" } else if env == "staging" { "YYYY.rds.amazonaws.com" } else if env == "prod" { "ZZZZ.rds.amazonaws.com" } else { error("env not supported") }
bastionHost := if env == "dev" { "111.111.111.111" } else if env == "staging" { "222.111.111.111" } else if env == "prod" { "333.111.111.111" } else { error("env not supported") }

tunnel env:
    ssh -i ~/.certs/cert-{{env}}.pem -fN -l ec2-user -L 5432:{{db-{{env}}}}:5432 {{bastion-{{env}}}} -v

and call it like this:

$ just tunnel dev
# or
$ just tunnel staging
# or
$ just tunnel prod

This, unfortunately, doesn't work, and I have no clue by reading the docs how to achieve it.
Would be plain amazing if you can advice

Thanks!

[casey]

Can you post the error you get? I don't notice anything obviously wrong from the justfile itself.

[dodalovic]

just       
error: Expected '}}', '(', or '+', but found '{'
  |
5 |     ssh -i ~/.certs/cert-{{env}}.pem -fN -l ec2-user -L 5432:{{db-{{env}}}}:5432 {{bastion-{{env}}}} -v
  |         

[runeimp]

Why is it

ssh -i ~/.certs/cert-{{env}}.pem -fN -l ec2-user -L 5432:{{db-{{env}}}}:5432 {{bastion-{{env}}}} -v

instead of

ssh -i ~/.certs/cert-{{env}}.pem -fN -l ec2-user -L 5432:db-{{env}}:5432 bastion-{{env}} -v

Are you expecting nested expansion and that {{db-{{env}}}} would resolve to something like {{db-dev}} and then expand to something else that is defined but not shown in your example?

[dodalovic]

The issue I'm trying to solve, is that I have a directory ~/.certs, where I put some certs: dev.pem, staging.pem, prod.pem

I want to run

$ j tunnel dev|staging|prod

and use this dev|staging|prod inside my commands, I'd like to have such file:

default:
  @just --list

dbHost := if env == "dev" { "XXXX.rds.amazonaws.com" } else if env == "staging" { "YYYY.rds.amazonaws.com" } else if env == "prod" { "ZZZZ.rds.amazonaws.com" } else { error("env not supported") }

bastionHost := if env == "dev" { "111.111.111.111" } else if env == "staging" { "222.111.111.111" } else if env == "prod" { "333.111.111.111" } else { error("env not supported") }

tunnel env:
    ssh -i ~/.certs/cert-{{env}}.pem -fN -l ec2-user -L 5432:{{dbHost}}:5432 {{bastionHost}} -v

but it doesn't work.
The documentation is very complex, so I was hoping to get the help here.

Thank You

[runeimp]

There is one major problem with your code. env is only defined for the tunnel recipe. It doesn't exist in the global context of the Justfile. So your if statements need to reside in the the tunnel recipe somehow. You could do a shebang recipe like

default:
	@just --list

tunnel env:
	#!/bin/sh

	dbHost={{ if env == "dev" { "XXXX.rds.amazonaws.com" } else if env == "staging" { "YYYY.rds.amazonaws.com" } else if env == "prod" { "ZZZZ.rds.amazonaws.com" } else { error("env not supported") } }}
	bastionHost={{ if env == "dev" { "111.111.111.111" } else if env == "staging" { "222.111.111.111" } else if env == "prod" { "333.111.111.111" } else { error("env not supported") } }}

	echo ssh -i ~/.certs/cert-{{env}}.pem -fN -l ec2-user -L "5432:${dbHost}:5432" "${bastionHost}" -v

or go more shell based with

default:
	@just --list

tunnel env:
	#!/bin/sh

	dbHost='Undefined'
	bastionHost='Undefined'

	if [ '{{env}}' = 'dev' ]; then
		dbHost='XXXX.rds.amazonaws.com'
		bastionHost='111.111.111.111'
	elif [ '{{env}}' = 'staging' ]; then
		dbHost='YYYY.rds.amazonaws.com'
		bastionHost='222.111.111.111'
	elif [ '{{env}}' = 'prod' ]; then
		dbHost='ZZZZ.rds.amazonaws.com'
		bastionHost='333.111.111.111'
	else
		echo '{{env}} env not supported'
	fi
		
	ssh -i ~/.certs/cert-{{env}}.pem -fN -l ec2-user -L "5432:${dbHost}:5432" "${bastionHost}" -v

Also there is no error function in Just. At least not that I know of and a call to it generates an error error: Call to function error failed: env not supported. Hopefully that helps clear up things for you. 😃

[casey]

There actually is an error function, for generating errors. It would be a different kind of error if the function error didn't exist.

[dodalovic]

Many thanks guys
It worked!