evaluator: Regression: result.#_list.0: #in.c1 undefined as #in is incomplete (type _):

[bttk]

What version of CUE are you using (cue version)?

0.5.0-beta.1

Does this issue reproduce with the latest release?

Yes

What did you do?

-- cue.mod/module.cue --
module: "bttk.dev/cuebug"
-- input.cue --
table: "table_1_csv_import": {
        header: ["c1", "c2", "c3"]
        rows: [{
                c1: "V 1"
                c2: "V 2"
                c3: "V 3"
        }, {
                c1: "W 1"
                c2: "W 2"
                c3: "W 3"
        }, {
                c1: "X 1"
                c2: "X 2"
                c3: "X 3"
        }]
}
-- tools/cue/mapper/apply.cue --
package apply

import (
        "bttk.dev/cuebug/tools/cue/mapper"
        "list"
)

FUNC=func: [string]: mapper.#Func
table: [string]: rows: [...]

_mapperType:                  *"list" | "text" @tag(mapper)
_joinStr:                     string | *"\n"   @tag(join)
TABLE_NAME=_tableName:        string | *""     @tag(table)
OUT_TABLE_NAME=_outTableName: string | *""     @tag(outTable)
FUNC_NAME=_funcName:          string | *""     @tag(func)

result: [
        if _mapperType == "list" {mapper.#ListMapper},
        if _mapperType == "text" {mapper.#TextMapper & {#join: _joinStr, _}},
][0] & {
        let TABLE = table
        #in: TABLE[TABLE_NAME].rows
        #fn: FUNC[FUNC_NAME]

        _
}

resultTable: table: "\(OUT_TABLE_NAME)": rows: result
flatTable: table: "\(OUT_TABLE_NAME)": rows:   list.FlattenN(result, 1)
-- tools/cue/mapper/mapper.cue --
package mapper

import "strings"

#Schema: func: [_]: #Func

#Func: {
        #in: _
        _
        ...
}

#ListMapper: {
        IN=#in: [...]
        FN=#fn: #Func

        [ for r in IN {
                FN & {#in: r, _}
        }]
}

#TextMapper: {
        IN=#in: [...]
        FN=#fn: #Func
        #join:  string | *"\n"

        #_list: #ListMapper & {#in: IN, #fn: FN, [...string]}
        strings.Join(#_list, #join)
}
-- tools/cue/test/testdata/func_1.cue --
import (
        "bttk.dev/cuebug/tools/cue/mapper"
)

func: [string]: mapper.#Func

func: "func_1": {
        IN=#in: {[string]: _}

        IN.c1
}

What did you expect to see?

$ go run cuelang.org/go/cmd/[email protected] export --all-errors --verbose '--out=text' --inject 'table=table_1_csv_import' --inject 'func=func_1' --inject 'mapper=text' --inject 'join=|' --inject 'outTable=table_1_csv_import' --expression result input.cue tools/cue/test/testdata/func_1.cue tools/cue/mapper/apply.cue

V 1|W 1|X 1

What did you see instead?

$ go run cuelang.org/go/cmd/[email protected] export --all-errors --verbose '--out=text' --inject 'table=table_1_csv_import' --inject 'func=func_1' --inject 'mapper=text' --inject 'join=|' --inject 'outTable=table_1_csv_import' --expression result input.cue tools/cue/test/testdata/func_1.cue tools/cue/mapper/apply.cue

result.#_list.0: #in.c1 undefined as #in is incomplete (type _):
    ./tools/cue/test/testdata/func_1.cue:10:2
exit status 1

[myitcv]

Thanks for the report, @bttk. Investigating now.

[myitcv]

I've reduced this down to the follow.

What did you do?

exec cue export '--out=text' -e result x.cue
cmp stdout stdout.golden

-- x.cue --
package apply

import (
	"strings"
)

// This appears to be critical to reproducing the error
#Func: {
	#in: _
	_
}

#TextMapper: {
	#in: [...]
	#fn:   #Func
	#join: string
	_#list: [ for r in #in {
		#fn & {#in: r, _}
	}]
	strings.Join(_#list, #join)
}

result: #TextMapper & {
	#join: "|"
	#in: [{c1: "V 1"}]
	#fn: {
		#in: _
		#in.c1
	}
	_
}
-- stdout.golden --
V 1

What did you expect to see?

A passing test. This passes with v0.4.3

What did you see instead?

$ ts repro.txtar
> exec cue export '--out=text' -e result x.cue
[stderr]
result._#list.0: #in.c1 undefined as #in is incomplete (type _):
    ./x.cue:28:3
[exit status 1]
FAIL: /tmp/testscript3972114924/repro.txtar/script.txtar:1: unexpected command failure

Bisected to 748a685

Marking as v0.5.0.

[mpvl]

Simpler reproducer:

c: [1, 2]
a: {
    for k, v in c {
        {x: 1}
        if a.x != _|_ {
        }
    }
}

[myitcv]

A different reproducer:

#Func: {
	#in2: _
	_
}

#fn: #Func
#fn: {
	#in2: _
	#in2.c1
}
x: #fn & {#in2: {c1: "V 1"}, _}

Again, the constraint #fn: #Func is critical here.

Per @mpvl this (also) appears to be an ordering thing.

[bttk]

looks like it's fixed in v0.5.0-beta.2

go run cuelang.org/go/cmd/[email protected] export --all-errors --verbose '--out=text' --inject 'table=table_1_csv_import' --inject 'func=func_1' --i nject 'mapper=text' --inject 'join=|' --inject 'outTable=table_1_csv_import' --expression result input.cue tools/cue/test/testdata/func_1.cue tools/cue/mapper/apply.cue

V 1|W 1|X 1

[myitcv]

Yes indeed, @bttk! You can see above the list of fixes that went into this one. Thanks again for raising, I will mark this as closed now.