Crypto enhancements, AESContext, RSA public key, signature, verification.

[Faless]

In this PR:

• Add AESContext to provide scripting interface to AES-ECB and AES-CBC encryption/decryption (provided by CryptoCore, i.e., even without mbedtls enabled).
• Crypto now support saving/loading *.pub "public only" keys.
• Add sign and verify Crypto methods to sign/verify the given hash using an RSA key.
• Add encrypt and decrypt Crypto methods for RSA key encryption/decryption.

AESContext demo code:

extends Node

var aes = AESContext.new()

func _ready():
	var key = "My secret key!!!" # Key must be either 16 or 32 bytes.
	var data = "My secret text!!" # Data size must be multiple of 16 bytes, apply padding if needed.
	# Encrypt ECB
	aes.start(AESContext.MODE_ECB_ENCRYPT, key.to_utf8())
	var encrypted = aes.update(data.to_utf8())
	aes.finish()
	# Decrypt ECB
	aes.start(AESContext.MODE_ECB_DECRYPT, key.to_utf8())
	var decrypted = aes.update(encrypted)
	aes.finish()
	# Check ECB
	assert(decrypted == data.to_utf8())

	var iv = "My secret iv!!!!" # IV must be of exactly 16 bytes.
	# Encrypt CBC
	aes.start(AESContext.MODE_CBC_ENCRYPT, key.to_utf8(), iv.to_utf8())
	encrypted = aes.update(data.to_utf8())
	aes.finish()
	# Decrypt CBC
	aes.start(AESContext.MODE_CBC_DECRYPT, key.to_utf8(), iv.to_utf8())
	decrypted = aes.update(encrypted)
	aes.finish()
	# Check CBC
	assert(decrypted == data.to_utf8())

New Crypto methods demo code:

extends Node

var crypto = Crypto.new()

func _ready():
	# Generate new RSA key.
	var key = crypto.generate_rsa(4096)
	# Save key and certificate in the user folder.
	key.save("user://key.key") # Save private key
	key.save("user://key.pub", true) # Save public key only.
	_load_and_test()

func _load_and_test():
	var priv = load("user://key.key")
	var pub = load("user://key.pub")
	assert(pub.is_public_only())
	# Encryption
	var data = "Some data"
	var encrypted = crypto.encrypt(pub, data.to_utf8())
	# Decryption
	var decrypted = crypto.decrypt(priv, encrypted)
	# Signing
	var signature = crypto.sign(HashingContext.HASH_SHA256, data.sha256_buffer(), priv)
	# Verifying
	var verified = crypto.verify(HashingContext.HASH_SHA256, data.sha256_buffer(), signature, pub)
	# Checks
	assert(verified)
	assert(data.to_utf8() == decrypted)

This work was sponsored by Maffle LLC.

[akien-mga]

Thanks!

[tx350z]

Will this generate PKCS1 compatible signatures? If so, which version? In anticipation of this coming in Godot 4 I've built a C# class based upon this https://docs.microsoft.com/en-us/dotnet/standard/security/cryptographic-signatures. The .NET RSAPKCS1SignatureFormatter docs indicate it creates PKCS1 v1.5 signatures.

Just wondering if the signatures generated by my C# class will be compatible with these new features.

EDIT: I think I've answered the question for myself. What digital signature standard is being used? Would like to know so I can build something compatible in C# until 4.0 is released. Thanks.

[Faless]

@tx350z PKCS#1 v1.5, with MD5, SHA1, SHA256.

Next time, please use our one of our community channels to ask support questions, I would recommend joining the Godot Contributors Chat for engine development questions, since it's quite active.