feat: lima 0.14.2.

Until fixed upstream.

Source:

NixOS/nixpkgs#206285

flake.nix

@@ -265,6 +265,9 @@
       )
       // {
         inherit (pkgs) vaultenv;
+
+        # Until upstream is caught up.
+        inherit (pkgs) lima;
       };
     })
 

nix/overlays/200-lima.nix

@@ -0,0 +1,9 @@
+final: prev:
+let
+  lima = final.callPackage ../pkgs/lima {
+    inherit (final.darwin) sigtool;
+  };
+in
+{
+  inherit lima;
+}

nix/pkgs/lima/default.nix

@@ -0,0 +1,69 @@
+{ lib
+, stdenv
+, buildGoModule
+, fetchFromGitHub
+, installShellFiles
+, qemu
+, xcbuild
+, sigtool
+, makeWrapper
+}:
+
+buildGoModule rec {
+  pname = "lima";
+  version = "0.14.2";
+
+  src = fetchFromGitHub {
+    owner = "lima-vm";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "sha256-g4FvkjBviI1m8zlc+GK/09dIqVkTQ2MqqK1Wkyu4qBc=";
+  };
+
+  vendorSha256 = "sha256-l53MTxLY/uid+0U/eY96l0aBWKImST1gN2BARilh2K0=";
+
+  nativeBuildInputs = [ makeWrapper installShellFiles ]
+    ++ lib.optionals stdenv.isDarwin [ xcbuild.xcrun sigtool ];
+
+  # clean fails with read only vendor dir
+  postPatch = ''
+    substituteInPlace Makefile \
+      --replace 'binaries: clean' 'binaries:' \
+      --replace 'codesign --entitlements vz.entitlements -s -' 'codesign --force --entitlements vz.entitlements -s -'
+  '';
+
+  # It attaches entitlements with codesign and strip removes those,
+  # voiding the entitlements and making it non-operational.
+  dontStrip = stdenv.isDarwin;
+
+  buildPhase = ''
+    runHook preBuild
+    make "VERSION=v${version}" binaries
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out
+    cp -r _output/* $out
+    wrapProgram $out/bin/limactl \
+      --prefix PATH : ${lib.makeBinPath [ qemu ]}
+    installShellCompletion --cmd limactl \
+      --bash <($out/bin/limactl completion bash) \
+      --fish <($out/bin/limactl completion fish) \
+      --zsh <($out/bin/limactl completion zsh)
+    runHook postInstall
+  '';
+
+  doInstallCheck = true;
+  installCheckPhase = ''
+    USER=nix $out/bin/limactl validate examples/default.yaml
+  '';
+
+  meta = with lib; {
+    homepage = "https://github.com/lima-vm/lima";
+    description = "Linux virtual machines (on macOS, in most cases)";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ dhess ];
+  };
+}