Ignore Scale Set capacity changes

[ghtyrant]

Terraform Version

AzureRM provider 1.1.2
Terraform v0.11.3

Affected Resource(s)

• azurerm_virtual_machine_scale_set

Terraform Configuration Files

resource "azurerm_virtual_network" "vnet" {
  name                = "vnet"
  address_space       = ["10.0.0.0/16"]
  location            = "West Europe"
  resource_group_name = "rg"
}

resource "azurerm_subnet" "nodesubnet" {
  name                 = "nodesubnet"

  resource_group_name  = "rg"
  virtual_network_name = "${azurerm_virtual_network.vnet.name}"
  address_prefix       = "10.0.2.0/24"
}

resource "azurerm_network_security_group" "ssnsg" {
  name                = "ssnsg"

  resource_group_name = "rg"
  location            = "West Europe"

  security_rule = {
    name = "Custom HTTP"
    description = "Custom HTTP"
    protocol = "tcp"
    source_port_range = "*"
    destination_port_range = "8080"

    # We should fix this to the IP of the load balancer
    source_address_prefix = "10.0.2.0/24"
    destination_address_prefix = "*"

    access = "Allow"
    direction = "Inbound"
    priority = "100"
  }
}

resource "azurerm_virtual_machine_scale_set" "ss" {
  name                = "nodescaleset"
  location            = "West Europe"
  resource_group_name = "rg"
  upgrade_policy_mode = "Manual"

  depends_on = ["azurerm_virtual_machine.mn"]

  overprovision = false

  sku {
    name     = "Standard_NC6"
    tier     = "Standard"
    capacity = 2
  }

  storage_profile_image_reference {
    id = "(...)"
  }

  storage_profile_os_disk {
    caching           = "ReadWrite"
    create_option     = "FromImage"
    managed_disk_type = "Standard_LRS"
  }

  os_profile {
    computer_name_prefix = "node"
    admin_username       = "admin"
    admin_password       = "xxx"
  }

  network_profile {
    name    = "scalenetwork"
    primary = true
    network_security_group_id = "${azurerm_network_security_group.nodensg.id}"

    ip_configuration {
      name                                   = "scaleip"
      subnet_id                              = "${azurerm_subnet.nodesubnet.id}"
    }
  }
}

Actual Behavior

When updating settings like the image id (or any other non sku related stuff) and applying, terraform will notice difference in scale set capacity if it has been scaled up/down in the meantime. It will then reset this capacity back to the number defined in the script, thus killing/creating a bunch of machines.

Expected Behavior

In our use case, we dynamically change the capacity of our scale set (not using terraform). When changing the referenced image id, we expect terraform to ignore the capacity, thus leaving our machines in the scale set alive.

This is a feature request. We want to be able to tell terraform to ignore sku.capacity completely. Simply leaving it out leads to an error (Error: azurerm_virtual_machine_scale_set.ss: sku.0.capacity: required field is not set).

Steps to Reproduce

Please list the steps required to reproduce the issue, for example:

1. terraform apply
2. Increase the capacity of the scale set (using az-cli or the portal)
3. Change the id of the referenced image
4. terraform apply

[ghtyrant]

I just discovered 'ignore_changes', a typical case of write before read.

Sorry about that, I will close this issue.

[nomis4u]

@ghtyrant Were you able to ignore just the capacity rather than the entier sku ? If so , could you please share how you did it

[ghtyrant]

@nomis4u I wasn't able to only ignore the capacity only - ignore_changes ignores the whole SKU. This kind of works for us for now, since we never change name or tier of the SKU. But since this still is a workaround, let me reopen the issue.

[katbyte]

Hi @ghtyrant,

I'm glad that you managed to find a workaround! @nomis4u, you "should" be able to ignore the capacity property alone by using:

  lifecycle {
    ignore_changes = ["sku.#.capacity"]
  }

As the sku block is stored as a set you would need to figure out what the hashcode is (visible in the plan) and use it as so: ignore_changes = ["sku.12345678.capacity"]

This is obviously not ideal so I have opened #1558 to change it to a list so ignore_changes = ["sku.0.capacity"] will be possible.

[katbyte]

As #1558 has been merged and released in v1.10.0 it is now possible to easily ignore these changes via the lifecycle property :

  lifecycle {
    ignore_changes = ["sku.0.capacity"]
  }

[ghtyrant]

Works for me now! Thank you!

[ghost]

I'm going to lock this issue because it has been closed for 30 days ⏳. This helps our maintainers find and focus on the active issues.

If you feel this issue should be reopened, we encourage creating a new issue linking back to this one for added context. If you feel I made an error 🤖 🙉 , please reach out to my human friends 👉 [email protected]. Thanks!