WIP: add syntax for MOI.Parameter

src/sets.jl

@@ -344,3 +344,30 @@ end
 function moi_set(set::Semiinteger{T}) where {T}
     return MOI.Semiinteger{T}(set.lower, set.upper)
 end
+
+"""
+    Parameter(value)
+
+A short-cut for the [`MOI.Parameter`](@ref) set.
+
+## Example
+
+```jldoctest
+julia> model = Model();
+
+julia> @variable(model, x in Parameter(2.0))
+x
+
+julia> print(model)
+Feasibility
+Subject to
+ x ∈ MathOptInterface.Parameter{Float64}(2.0)
+```
+"""
+struct Parameter{T} <: AbstractScalarSet
+    value::T
+end
+
+function moi_set(set::Parameter{T}) where {T}
+    return MOI.Parameter{T}(set.value)
+end

src/variables.jl

@@ -1091,6 +1091,55 @@ function BinaryRef(v::GenericVariableRef)
     return ConstraintRef(owner_model(v), _binary_index(v), ScalarShape())
 end
 
+"""
+    ParameterRef(x::GenericVariableRef)
+
+Return a constraint reference to the constraint constraining `x` to be a
+parameter.
+
+Errors if one does not exist.
+
+See also [`is_parameter`](@ref), [`set_parameter`](@ref).
+"""
+function ParameterRef(x::GenericVariableRef)
+    return ParameterRef(owner_model(x), _parameter_index(x), ScalarShape())
+end
+
+function _parameter_index(x::GenericVariableRef)
+    S = MOI.Parameter{value_type(typeof(x))}
+    return MOI.ConstraintIndex{MOI.VariableIndex,S}(index(x).value)
+end
+
+"""
+    is_parameter(x::GenericVariableRef)
+
+Return `true` if `x` is constrained to be a parameter.
+
+See also [`ParameterRef`](@ref), [`set_parameter`](@ref).
+"""
+function is_parameter(x::GenericVariableRef)
+    return _moi_is_parameter(backend(owner_model(x)), x)
+end
+
+function _moi_is_parameter(moi_backend, x::GenericVariableRef)
+    return MOI.is_valid(moi_backend, _parameter_index(x))
+end
+
+"""
+    set_parameter(x::GenericVariableRef, value)
+
+Update the parameter constraint on the variable `x` to `value`.
+
+See also [`ParameterRef`](@ref), [`is_parameter`](@ref).
+"""
+function set_parameter(x::GenericVariableRef, value)
+    model = owner_model(x)
+    model.is_model_dirty = true
+    set = MOI.Parameter(value)
+    MOI.set(backend(model), MOI.ConstraintSet(), _parameter_index(x), set)
+    return
+end
+
 """
     start_value(v::GenericVariableRef)