lbl-srg · mwetter · Aug 18, 2021 · Mar 14, 2021 · Mar 17, 2021 · Mar 17, 2021
diff --git a/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/Boston.mo b/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/Boston.mo
@@ -0,0 +1,6 @@
+within Buildings.BoundaryConditions.GroundTemperature.ClimaticConstants;
+record Boston =
+    Buildings.BoundaryConditions.GroundTemperature.ClimaticConstants.Generic (
+    TMeaSur=273.15+11.08,
+    TSurAmp=11.57,
+    sinPhaDay=115.1) "Boston";
diff --git a/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/Generic.mo b/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/Generic.mo
@@ -0,0 +1,8 @@
+within Buildings.BoundaryConditions.GroundTemperature.ClimaticConstants;
+record Generic "Generic climatic constants"
+  extends Modelica.Icons.Record;
+  parameter Modelica.SIunits.Temperature TMeaSur "Mean annual surface temperature";
+  parameter Modelica.SIunits.TemperatureDifference TSurAmp "Surface temperature amplitude";
+  parameter Modelica.SIunits.Duration sinPhaDay "Phase lag of soil surface temperature (in days)";
+
+end Generic;
diff --git a/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/NewYork.mo b/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/NewYork.mo
@@ -0,0 +1,6 @@
+within Buildings.BoundaryConditions.GroundTemperature.ClimaticConstants;
+record NewYork =
+    Buildings.BoundaryConditions.GroundTemperature.ClimaticConstants.Generic (
+    TMeaSur=273.15+12.88,
+    TSurAmp=11.45,
+    sinPhaDay=112.6) "New York";
diff --git a/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/SanFrancisco.mo b/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/SanFrancisco.mo
@@ -0,0 +1,6 @@
+within Buildings.BoundaryConditions.GroundTemperature.ClimaticConstants;
+record SanFrancisco =
+    Buildings.BoundaryConditions.GroundTemperature.ClimaticConstants.Generic (
+    TMeaSur=273.15+14.49,
+    TSurAmp=3.35,
+    sinPhaDay=120.6) "San Francisco";
diff --git a/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/package.mo b/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/package.mo
@@ -0,0 +1,13 @@
+within Buildings.BoundaryConditions.GroundTemperature;
+package ClimaticConstants
+  extends Modelica.Icons.MaterialPropertiesPackage;
+
+  annotation (Documentation(info="<html>
+<p>
+Surface temperature data that is used in the calculation of undisturbed soil temperature.
+See <a href=\"https://tc0602.ashraetcs.org/Climatic_constants_using_ASHRAE_CD_Ver_6.0.pdf\">
+Climatic Constants for Calculating Subsurface Soil Temperatures</a> for
+more information and a table of values
+</p>
+</html>"));
+end ClimaticConstants;
diff --git a/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/package.order b/Buildings/BoundaryConditions/GroundTemperature/ClimaticConstants/package.order
@@ -0,0 +1,4 @@
+Boston
+Generic
+NewYork
+SanFrancisco
diff --git a/Buildings/BoundaryConditions/GroundTemperature/Examples/UndisturbedSoilTemperature.mo b/Buildings/BoundaryConditions/GroundTemperature/Examples/UndisturbedSoilTemperature.mo
@@ -0,0 +1,40 @@
+within Buildings.BoundaryConditions.GroundTemperature.Examples;
+model UndisturbedSoilTemperature "Example model for undisturbed soil temperature"
+  extends Modelica.Icons.Example;
+
+  Buildings.BoundaryConditions.GroundTemperature.UndisturbedSoilTemperature
+    Tsoi0(cliCon=cliCon, soiDat=soiDat, dep=0) "Surface temperature"
+    annotation (Placement(transformation(extent={{-10,80},{10,100}})));
+  Buildings.BoundaryConditions.GroundTemperature.UndisturbedSoilTemperature
+    Tsoi2(cliCon=cliCon, soiDat=soiDat, dep=2) "Soil temperature at 2m depth"
+    annotation (Placement(transformation(extent={{-10,40},{10,60}})));
+  Buildings.BoundaryConditions.GroundTemperature.UndisturbedSoilTemperature
+    Tsoi5(cliCon=cliCon, soiDat=soiDat, dep=5) "Soil temperature at 5m depth"
+    annotation (Placement(transformation(extent={{-10,-20},{10,0}})));
+  Buildings.BoundaryConditions.GroundTemperature.UndisturbedSoilTemperature
+    Tsoi9(cliCon=cliCon, soiDat=soiDat, dep=9) "Soil temperature at 9m depth"
+    annotation (Placement(transformation(extent={{-10,-100},{10,-80}})));
+
+protected
+  replaceable parameter ClimaticConstants.Boston cliCon "Surface temperature climatic conditions";
+  replaceable parameter Buildings.HeatTransfer.Data.Soil.Generic soiDat(
+    k=1.58,c=1150,d=1600) "Soil thermal properties";
+  annotation (Icon(coordinateSystem(preserveAspectRatio=false)), Diagram(
+        coordinateSystem(preserveAspectRatio=false)),
+    experiment(StopTime=31536000, __Dymola_Algorithm="Cvode", Tolerance=1e-6),
+    Documentation(info="<html>
+<p>
+This example model illustrates how the undisturbed soil temperature model decreases
+seasonal temperature oscillations and increases delay as depth is increasing.
+</p>
+</html>", revisions="<html>
+<ul>
+<li>
+March 17, 2021, by Baptiste Ravache:<br/>
+First implementation.
+</li>
+</ul>
+</html>"),
+    __Dymola_Commands(file="modelica://Buildings/Resources/Scripts/Dymola/BoundaryConditions/GroundTemperature/Examples/UndisturbedSoilTemperature.mos"
+        "Simulate and plot"));
+end UndisturbedSoilTemperature;
diff --git a/Buildings/BoundaryConditions/GroundTemperature/Examples/package.mo b/Buildings/BoundaryConditions/GroundTemperature/Examples/package.mo
@@ -0,0 +1,4 @@
+within Buildings.BoundaryConditions.GroundTemperature;
+package Examples
+  extends Modelica.Icons.ExamplesPackage;
+end Examples;
diff --git a/Buildings/BoundaryConditions/GroundTemperature/Examples/package.order b/Buildings/BoundaryConditions/GroundTemperature/Examples/package.order
@@ -0,0 +1 @@
+UndisturbedSoilTemperature
diff --git a/Buildings/BoundaryConditions/GroundTemperature/UndisturbedSoilTemperature.mo b/Buildings/BoundaryConditions/GroundTemperature/UndisturbedSoilTemperature.mo
@@ -0,0 +1,84 @@
+within Buildings.BoundaryConditions.GroundTemperature;
+model UndisturbedSoilTemperature "Undisturbed soil temperature"
+  parameter Modelica.SIunits.Length dep "Depth";
+  replaceable parameter Buildings.HeatTransfer.Data.Soil.Generic soiDat "Soil thermal properties";
+  replaceable parameter ClimaticConstants.Generic cliCon "Surface temperature climatic conditions";
+
+  Modelica.Thermal.HeatTransfer.Interfaces.HeatPort_b port "Boundary heat port";
+protected
+  constant Modelica.SIunits.Angle pi = Modelica.Constants.pi;
+  constant Modelica.SIunits.Duration Year = 365.2422*24*60*60 "Annual period length";
+
+  parameter Modelica.SIunits.ThermalDiffusivity soiDif = soiDat.k / soiDat.c / soiDat.d "Soil diffusivity";
+  parameter Modelica.SIunits.Duration timLag = cliCon.sinPhaDay*24*60*60 "Start time of surface temperature sinusoid";
+  parameter Real pha = - dep * (pi/soiDif/Year)^0.5 "Phase angle of ground temperature sinusoid";
+
+equation
+  port.T = cliCon.TMeaSur + cliCon.TSurAmp * exp(pha) * sin(2*pi*(time-timLag)/Year - pha);
+    annotation (Placement(transformation(extent={{-6,-104},{6,-92}}),
+        iconTransformation(extent={{-6,-104},{6,-92}})),
+              Icon(coordinateSystem(preserveAspectRatio=false), graphics={
+        Text(
+          lineColor={0,0,255},
+          extent={{-150,110},{150,150}},
+          textString="%name"),
+        Rectangle(
+          extent={{-100,20},{100,-100}},
+          lineColor={0,0,0},
+          fillColor={211,168,137},
+          fillPattern=FillPattern.Backward),
+        Rectangle(
+          extent={{-100,20},{100,26}},
+          lineColor={0,0,0},
+          fillColor={0,255,128},
+          fillPattern=FillPattern.Solid),
+        Rectangle(
+          extent={{-100,26},{100,100}},
+          lineColor={0,0,0},
+          fillColor={85,170,255},
+          fillPattern=FillPattern.Solid),
+        Line(
+          points={{0,38},{0,-60}},
+          color={191,0,0},
+          thickness=1),
+        Polygon(
+          points={{16,-60},{-16,-60},{0,-92},{16,-60}},
+          lineColor={191,0,0},
+          fillColor={191,0,0},
+          fillPattern=FillPattern.Solid),
+        Text(
+          extent={{-38,-38},{-100,-100}},
+          lineColor={0,0,0},
+          textString="K")}),                                     Diagram(
+        coordinateSystem(preserveAspectRatio=false)),
+    Documentation(info="<html>
+<p>
+This model provides a prescribed temperature boundary counditions for buried objects,
+where the temperature is computed per the ASCE (1996) equation:
+
+</p>
+<p align=\"center\">
+<img alt=\"image\" src=\"modelica://Buildings/Resources/Images/BoundaryConditions/GroundTemperature/UndisturbedGroundTemperature.png\" />
+</p>
+<p>
+where T<sub>s,z</sub> is the ground temperature at depth z, 
+&tau; is the annual period length (constant 365.25 days),
+&alpha; is the soil thermal diffusivity, and t is the time.
+T<sub>ms</sub>, A<sub>s</sub> and t<sub>lag</sub> are function of the
+climate and represent the offset, amplitude and phase, respectively,
+of the representative surface temperature sinusoid.
+</p>
+<h4>References</h4>
+<p>
+ASCE (1996). <i>Cold Regions Utilities Monograph</i>. D.W. Smith, Technical Editor.
+</p>
+
+</html>", revisions="<html>
+<ul>
+<li>
+March 17, 2021, by Baptiste Ravache:<br/>
+First implementation.
+</li>
+</ul>
+</html>"));
+end UndisturbedSoilTemperature;
diff --git a/Buildings/BoundaryConditions/GroundTemperature/package.mo b/Buildings/BoundaryConditions/GroundTemperature/package.mo
@@ -0,0 +1,5 @@
+within Buildings.BoundaryConditions;
+package GroundTemperature
+  extends Modelica.Icons.VariantsPackage;
+
+end GroundTemperature;
diff --git a/Buildings/BoundaryConditions/GroundTemperature/package.order b/Buildings/BoundaryConditions/GroundTemperature/package.order
@@ -0,0 +1,3 @@
+UndisturbedSoilTemperature
+ClimaticConstants
+Examples
diff --git a/Buildings/BoundaryConditions/package.order b/Buildings/BoundaryConditions/package.order
@@ -1,4 +1,5 @@
 UsersGuide
+GroundTemperature
 SkyTemperature
 SolarGeometry
 SolarIrradiation

diff --git a/Buildings/Fluid/BuriedPipes/BaseClasses/Functions/groundCouplingFactors.mo b/Buildings/Fluid/BuriedPipes/BaseClasses/Functions/groundCouplingFactors.mo
@@ -0,0 +1,54 @@
+within Buildings.Fluid.BuriedPipes.BaseClasses.Functions;
+function groundCouplingFactors
+  "Geometric factors for buried pipe-ground coupling"
+  extends Modelica.Icons.Function;
+  input Integer nPip(min=1, fixed=true) "Number of pipes";
+
+  input Modelica.SIunits.Length dep[nPip] "Pipes Buried Depth";
+  input Modelica.SIunits.Length pos[nPip] "Pipes Horizontal Coordinate (to an arbitrary reference point)";
+  input Modelica.SIunits.Length rad[nPip] "Pipes external radius";
+
+  output Real P[nPip, nPip] "Thermal coupling geometric factors";
+
+algorithm
+  for i in 1:nPip loop
+    for j in 1:nPip loop
+      if i == j then
+        P[i,j] := Modelica.Math.log(2*dep[i]/rad[i]);
+      else
+        P[i,j] := Modelica.Math.log(
+        ((pos[i] - pos[j])^2 + (dep[i] + dep[j])^2)/
+        ((pos[i] - pos[j])^2 + (dep[i] - dep[j])^2));
+      end if;
+    end for;
+  end for;
+
+  annotation (Documentation(info="<html>
+<p>
+This function computes the multiple buried pipe system coupling matrix P described by Kusuda (1981).
+</p>
+<p>
+For a network of n buried pipes that are coaxial, the matrix P of size n x n is 
+computed from the system geometry:
+</p>
+<p align=\"center\">
+<img alt=\"image\" src=\"modelica://Buildings/Resources/Images/Fluid/BuriedPipes/GroundCouplingMatrix.png\" />
+</p>
+<p>
+where a<sub>i</sub>, d<sub>i</sub> and r<sub>i</sub> corresponds to the 
+horizontal position, depth and external radius, respectively, of pipe i.
+</p>
+<h4>References</h4>
+<p>
+Kusuda, T. (1981). <i>Heat transfer analysis of underground heat 
+and chilled-water distribution systems</i>. National Bureau of Standards.
+</p>
+</html>", revisions="<html>
+<ul>
+<li>
+March 17, 2020, by Baptiste Ravache:<br/>
+First implementation.
+</li>
+</ul>
+</html>"));
+end groundCouplingFactors;
diff --git a/Buildings/Fluid/BuriedPipes/BaseClasses/Functions/package.mo b/Buildings/Fluid/BuriedPipes/BaseClasses/Functions/package.mo
@@ -0,0 +1,10 @@
+within Buildings.Fluid.BuriedPipes.BaseClasses;
+package Functions "Package with base functions for Buildings.Fluid.BuriedPipes"
+  extends Modelica.Icons.VariantsPackage;
+
+annotation (Documentation(info="<html>
+<p>
+This package contains base functions that are used to construct the models in Buildings.Fluid.BuriedPipes. 
+</p>
+</html>"));
+end Functions;
diff --git a/Buildings/Fluid/BuriedPipes/BaseClasses/Functions/package.order b/Buildings/Fluid/BuriedPipes/BaseClasses/Functions/package.order
@@ -0,0 +1 @@
+groundCouplingFactors
diff --git a/Buildings/Fluid/BuriedPipes/BaseClasses/package.mo b/Buildings/Fluid/BuriedPipes/BaseClasses/package.mo
@@ -0,0 +1,10 @@
+within Buildings.Fluid.BuriedPipes;
+package BaseClasses
+  extends Modelica.Icons.BasesPackage;
+
+  annotation (Documentation(info="<html>
+<p>
+This package contains base classes that are used to construct the models in Buildings.Fluid.BuriedPipes. 
+</p>
+</html>"));
+end BaseClasses;
diff --git a/Buildings/Fluid/BuriedPipes/BaseClasses/package.order b/Buildings/Fluid/BuriedPipes/BaseClasses/package.order
@@ -0,0 +1 @@
+Functions