add eip-zodiac (ethereum#5005)

* add eip-zodiac * Add security considerations and some minor fixes * Add ETHMagicians discussion link * Update EIPS/eip-zodiac.md Co-authored-by: William Schwab <[email protected]> * Update EIPS/eip-zodiac.md Co-authored-by: William Schwab <[email protected]> * Update EIPS/eip-zodiac.md Co-authored-by: William Schwab <[email protected]> * Update EIPS/eip-zodiac.md Co-authored-by: William Schwab <[email protected]> * Remove external links to Zodiac & external imports * Rename EIP file to add ERC number * Update EIPS/eip-5005.md Co-authored-by: Pandapip1 <[email protected]> * Update EIPS/eip-5005.md Co-authored-by: Sam Wilson <[email protected]> * Update EIPS/eip-5005.md Co-authored-by: Sam Wilson <[email protected]> * Remove external links Co-authored-by: Sam Wilson <[email protected]> * Fix gramma * Small sentance structure fix * Remove license and external links * Update EIPS/eip-5005.md Co-authored-by: William Schwab <[email protected]> Co-authored-by: Pandapip1 <[email protected]> Co-authored-by: Sam Wilson <[email protected]> Co-authored-by: Micah Zoltu <[email protected]>
nachomazzara · Jan 13, 2023 · a12ffed · a12ffed
1 parent 97627f7
commit a12ffed
Showing 1 changed file with 224 additions and 0 deletions.
diff --git a/EIPS/eip-5005.md b/EIPS/eip-5005.md
@@ -0,0 +1,224 @@
+---
+eip: 5005
+title: Zodiac
+description: A composable design philosophy for DAOs.
+author: Auryn Macmillan (@auryn-macmillan), Kei Kreutler (@keikreutler)
+discussions-to: https://ethereum-magicians.org/t/eip-zodiac-a-composable-design-philosophy-for-daos/8963
+status: Draft
+type: Standards Track
+category: ERC
+created: 2022-04-14
+requires: 165
+---
+
+## Abstract
+Zodiac is a philosophy and open standard for composable and interoperable DAO tooling. A Zodiac-compatible DAO separates the account taking actions/holding tokens (known as the "avatar") and the authorization logic into two separate contracts. This standard defines the `IAvatar` interface, to be implemented by avatar contracts, while the authorization logic can be implemented with any combination of DAO tools and frameworks (Aragon, Colony, Compound/OZ Governor, DAOStack, Moloch, Orca, Tribute, etc).
+
+## Motivation
+Currently, most DAO tools and frameworks are built as somewhat monolithic systems, wherein account and control logic are coupled, either in the same contract or in a tightly bound system of contracts. This needlessly inhibits the future flexibility of organizations using these tools and encourages platform lock-in via extraordinarily high switching costs.
+
+By using the Zodiac standard to decouple account and control logic, organizations are able to:
+1. Enable flexible, module-based control of programmable accounts
+2. Easily switch between frameworks without unnecessary overhead.
+3. Enable multiple control mechanism in parallel.
+4. Enable cross-chain / cross-layer governance.
+5. Progressively decentralize their governance as their project and community matures.
+
+## Specification
+The key words “MUST”, “MUST NOT”, “REQUIRED”, “SHALL”, “SHALL NOT”, “SHOULD”, “SHOULD NOT”, “RECOMMENDED”, “MAY”, and “OPTIONAL” in this document are to be interpreted as described in RFC 2119.
+
+The Zodiac standard consists of four key concepts—Avatars, Modules, Modifiers, and Guards:
+1. **Avatars** are programmable Ethereum accounts, like the Gnosis Safe. Avatars are the address that holds balances, owns systems, executes transaction, is referenced externally, and ultimately represents your DAO. Avatars MUST expose the `IAvatar` interface.
+2. **Modules** are contracts enabled by an avatar that implement some control logic.
+3. **Modifiers** are contracts that sit between modules and avatars to modify the module's behavior. For example, they might enforce a delay on all functions a module attempts to execute or limit the scope of transactions that can be initiated by the module. Modifiers MUST expose the `IAvatar` interface.
+4. **Guards** are contracts that MAY be enabled on modules or modifiers and implement pre- or post-checks on each transaction executed by those modules or modifiers. This allows avatars to do things like limit the scope of addresses and functions that a module or modifier can call or ensure a certain state is never changed by a module or modifier. Guards MUST expose the `IGuard` interface. Modules, modifiers, and avatars that wish to be guardable MUST inherit `Guardable`, MUST call `checkTransaction()` before triggering execution on their target, and MUST call `checkAfterExecution()` after execution is complete.
+
+```solidity
+/// @title Zodiac Avatar - A contract that manages modules that can execute transactions via this contract.
+
+pragma solidity >=0.7.0 <0.9.0;
+
+import "./Enum.sol";
+
+
+interface IAvatar {
+    /// @dev Enables a module on the avatar.
+    /// @notice Can only be called by the avatar.
+    /// @notice Modules should be stored as a linked list.
+    /// @notice Must emit EnabledModule(address module) if successful.
+    /// @param module Module to be enabled.
+    function enableModule(address module) external;
+
+    /// @dev Disables a module on the avatar.
+    /// @notice Can only be called by the avatar.
+    /// @notice Must emit DisabledModule(address module) if successful.
+    /// @param prevModule Address that pointed to the module to be removed in the linked list
+    /// @param module Module to be removed.
+    function disableModule(address prevModule, address module) external;
+
+    /// @dev Allows a Module to execute a transaction.
+    /// @notice Can only be called by an enabled module.
+    /// @notice Must emit ExecutionFromModuleSuccess(address module) if successful.
+    /// @notice Must emit ExecutionFromModuleFailure(address module) if unsuccessful.
+    /// @param to Destination address of module transaction.
+    /// @param value Ether value of module transaction.
+    /// @param data Data payload of module transaction.
+    /// @param operation Operation type of module transaction: 0 == call, 1 == delegate call.
+    function execTransactionFromModule(
+        address to,
+        uint256 value,
+        bytes memory data,
+        Enum.Operation operation
+    ) external returns (bool success);
+
+    /// @dev Allows a Module to execute a transaction and return data
+    /// @notice Can only be called by an enabled module.
+    /// @notice Must emit ExecutionFromModuleSuccess(address module) if successful.
+    /// @notice Must emit ExecutionFromModuleFailure(address module) if unsuccessful.
+    /// @param to Destination address of module transaction.
+    /// @param value Ether value of module transaction.
+    /// @param data Data payload of module transaction.
+    /// @param operation Operation type of module transaction: 0 == call, 1 == delegate call.
+    function execTransactionFromModuleReturnData(
+        address to,
+        uint256 value,
+        bytes memory data,
+        Enum.Operation operation
+    ) external returns (bool success, bytes memory returnData);
+
+    /// @dev Returns if an module is enabled
+    /// @return True if the module is enabled
+    function isModuleEnabled(address module) external view returns (bool);
+
+    /// @dev Returns array of modules.
+    /// @param start Start of the page.
+    /// @param pageSize Maximum number of modules that should be returned.
+    /// @return array Array of modules.
+    /// @return next Start of the next page.
+    function getModulesPaginated(address start, uint256 pageSize)
+        external
+        view
+        returns (address[] memory array, address next);
+}
+```
+
+```solidity
+pragma solidity >=0.7.0 <0.9.0;
+
+import "./Enum.sol";
+
+interface IGuard {
+    function checkTransaction(
+        address to,
+        uint256 value,
+        bytes memory data,
+        Enum.Operation operation,
+        uint256 safeTxGas,
+        uint256 baseGas,
+        uint256 gasPrice,
+        address gasToken,
+        address payable refundReceiver,
+        bytes memory signatures,
+        address msgSender
+    ) external;
+
+    function checkAfterExecution(bytes32 txHash, bool success) external;
+}
+
+```
+
+```solidity
+pragma solidity >=0.7.0 <0.9.0;
+
+import "./Enum.sol";
+import "./BaseGuard.sol";
+
+/// @title Guardable - A contract that manages fallback calls made to this contract
+contract Guardable {
+    address public guard;
+
+    event ChangedGuard(address guard);
+
+    /// `guard_` does not implement IERC165.
+    error NotIERC165Compliant(address guard_);
+
+    /// @dev Set a guard that checks transactions before execution.
+    /// @param _guard The address of the guard to be used or the 0 address to disable the guard.
+    function setGuard(address _guard) external {
+        if (_guard != address(0)) {
+            if (!BaseGuard(_guard).supportsInterface(type(IGuard).interfaceId))
+                revert NotIERC165Compliant(_guard);
+        }
+        guard = _guard;
+        emit ChangedGuard(guard);
+    }
+
+    function getGuard() external view returns (address _guard) {
+        return guard;
+    }
+}
+```
+
+```solidity
+pragma solidity >=0.7.0 <0.9.0;
+
+import "./Enum.sol";
+import "./IERC165.sol";
+import "./IGuard.sol";
+
+abstract contract BaseGuard is IERC165 {
+    function supportsInterface(bytes4 interfaceId)
+        external
+        pure
+        override
+        returns (bool)
+    {
+        return
+            interfaceId == type(IGuard).interfaceId || // 0xe6d7a83a
+            interfaceId == type(IERC165).interfaceId; // 0x01ffc9a7
+    }
+
+    /// @dev Module transactions only use the first four parameters: to, value, data, and operation.
+    /// Module.sol hardcodes the remaining parameters as 0 since they are not used for module transactions.
+    /// @notice This interface is used to maintain compatibility with Gnosis Safe transaction guards.
+    function checkTransaction(
+        address to,
+        uint256 value,
+        bytes memory data,
+        Enum.Operation operation,
+        uint256 safeTxGas,
+        uint256 baseGas,
+        uint256 gasPrice,
+        address gasToken,
+        address payable refundReceiver,
+        bytes memory signatures,
+        address msgSender
+    ) external virtual;
+
+    function checkAfterExecution(bytes32 txHash, bool success) external virtual;
+}
+```
+
+```solidity
+pragma solidity >=0.7.0 <0.9.0;
+
+/// @title Enum - Collection of enums
+contract Enum {
+    enum Operation {Call, DelegateCall}
+}
+```
+
+## Rationale
+In designing the Zodiac standard, we inevitably needed to define a standard interface for modular programmable accounts (avatars). Rather than writing this from scratch, we elected to use the existing interfaces from the Gnosis Safe's Module Manager and from the Gnosis Safe's Guard Manager, since the Gnosis Safe is by far the most widely used programmable account for DAOs, other organizations, and individuals.
+
+## Backwards Compatibility
+No backward compatibility issues are introduced by this standard.
+
+## Security Considerations
+Zodiac primarily leverages the existing ModuleManager interface from the Gnosis Safe, which has been in running securely in production for several years. That said, there are some considerations that module developers and users should take into account.
+1. **Modules have unilateral control:** Modules have unilateral control over any avatar on which they are enabled, so any module implementation should be treated as security critical and users should be vary cautious about enabling new modules. ONLY ENABLE MODULES THAT YOU TRUST WITH THE FULL VALUE OF THE AVATAR.
+2. **Race conditions:** A given avatar may have any number of modules enabled, each with unilateral control over the safe. In such cases, there may be race conditions between different modules (and other control mechanisms, like the multisig mechanism on a Gnosis Safe).
+3. **Don't brick your avatar:** Be warned, there are no safe guards to stop you adding or removing modules. If you remove all of the modules that let you control an avatar, the avatar will cease to function and all funds will be stuck.
+
+## Copyright
+Copyright and related rights waived via [CC0](../LICENSE.md).