How to release package for multiple architectures

[chrichrichri]

Hello everyone,

I am creating some nix-package out of python packages using dream2nix, which works like a charm. Thanks a lot. Now my problem is, that I need to install the nix-package at different architectures, not only 86_64-linux. My package generally works, if I exchange the system definition in flake.nix, but since the content of the lockfile is changed, I can only install it on one platform.

I searched the repo here, but could not find an answer. I hope it was not just my stupidity to not find it. Can anyone give a hint how to allow building on multiple platforms? This is my current flake.nix, just like in the example:

{
  description = "A collection of software packages managed with dream2nix";

  inputs = {
    dream2nix.url = "github:nix-community/dream2nix";
    nixpkgs.follows = "dream2nix/nixpkgs";
  };

  outputs = inputs @ {
    self,
    dream2nix,
    nixpkgs,
    ...
  }: let
    system = "x86_64-linux";
  in {
    # all packages defined inside ./packages/
    packages.${system} = dream2nix.lib.importPackages {
      projectRoot = ./.;
      # can be changed to ".git" or "flake.nix" to get rid of .project-root
      projectRootFile = "flake.nix";
      packagesDir = ./packages;
      packageSets.nixpkgs = nixpkgs.legacyPackages.${system};
      packageSets.dreampkgs = self.packages.${system};
      specialArgs = {inherit inputs;};
    };
    checks.${system} =
      builtins.mapAttrs
      (_: p: p // {inherit system;})
      self.packages.${system};
  };
}

[christoph-blessing]

I have the same problem. I want my package to run on x86_64-linux and x86_64-darwin but the lock file is platform dependent. Is there a way to have multiple lock files?

[phaer]

Hello!

This is my current flake.nix, just like in the example:

You can avoid hard-coding a single system by defining a helper function which iterates over a list of systems, as in this example: https://github.com/nix-systems/nix-systems?tab=readme-ov-file#basic-usage (the list could either come from nix-systems or just from your flake, i.e. systems = [ "x86_64-linux" "aarch64-darwin" ];)

Now my problem is, that I need to install the nix-package at different architectures, not only 86_64-linux.

I think you didn't publish your package definitions here? You are probably using the pip module? The pdm one is marked experimental, but supports multi-platform lock files. The pip one doesn't, so as you already found out you'd need one lock file per platform. To do so you could add

paths.lockFile = "lock.${system}.json"

to your module. You'd still need to nix run .#package.lock on each platform though

[chrichrichri]

Thanks for the message. You are correct, I am using the pip module. Sorry for not writing above. I tried to implement your suggestions, but did not suceed so far. Based on what you wrote, my flake.nix now looks like this:

{
  description = "A collection of software packages managed with dream2nix";

  inputs = {
    dream2nix.url = "github:nix-community/dream2nix";
    nixpkgs.follows = "dream2nix/nixpkgs";
  };


  outputs = inputs @ {
    self,
    dream2nix,
    nixpkgs,
    ...
  }: let
    eachSystem = nixpkgs.lib.genAttrs [  "x86_64-linux" "aarch64-darwin" ];
  in {
    # all packages defined inside ./packages/
    packages = eachSystem (system: {
        ${system} = dream2nix.lib.importPackages {
              projectRoot = ./.;
              # can be changed to ".git" or "flake.nix" to get rid of .project-root
              projectRootFile = "flake.nix";
              packagesDir = ./packages;
              packageSets.nixpkgs = nixpkgs.legacyPackages.${system};
              packageSets.dreampkgs = self.packages.${system};
              specialArgs = {inherit inputs;};
              lockFile = "lock.${system}.json";
            };
        });
  };
}

But it seems this is not working, when calling nix flake showit just tells me error: expected a derivation and running nix run .#my_package returns │error: flake 'git+file:///Users/christof/git/nix_python_packages' does not provide attribute 'apps.aarch64-darwin.my_package.lock', 'packages.aarch64-darwin.my_package.lock', 'legacyPackages.aarch64-darwin.my_package.lock' or 'my_package.lock'

[phaer]

my_package was an example, you need to use the actual packages attribute name here.

   packages = eachSystem (system: {
        ${system} = dream2nix.lib.importPackages {

nixpkgs.lib.genAttrs above those lines, already creates an attribute set where the keys are the system. You ${system} is where the packages attribute name should be, so your package is probably called x86_64-linux atm.

e.g.

   packages = eachSystem (system: {
        my_package = dream2nix.lib.importPackages {

would maybe make the lock command above work.

[chrichrichri]

Thanks a lot. That my_package was just an example was clear to me, just left it there to avoid confusion. Based on your comment I now updated my package definition and it works like a charm:

1. Update flake_nix like this:

packages = eachSystem (system:
        dream2nix.lib.importPackages {
              projectRoot = ./.;
              # can be changed to ".git" or "flake.nix" to get rid of .project-root
              projectRootFile = "flake.nix";
              packagesDir = ./packages;
              packageSets.nixpkgs = nixpkgs.legacyPackages.${system};
              packageSets.dreampkgs = self.packages.${system};
              specialArgs = {inherit inputs; inherit system;};
            }
        );

2. Add paths.lockFile = "lock.${system}.json"; to each package default.nix

With this a platform specific lock file will be created by running nix run .#my_package.lock on the respective platform.