Debug Console Commands for Admins

Basic Commands

These commands are single liners that do various things, mostly with Antistasi's functions.

Teleport HQ Assets

Run as local. Teleports the relevant asset to your position.

petros setPos (getPos player);
flagX setPos (getPos player);
mapX setPos (getPos player);
vehicleBox setPos (getPos player);
boxX setPos (getPos player);
fireX setPos (getPos player);

Rebuild HQ at player location

Run as local. This teleports Petros to your position and then executes the "Build HQ" command.

[getpos player] remoteExec ["A3A_fnc_createPetros", 2];
[] remoteExec ["A3A_fnc_buildHQ", 2];

Force Commander

Both run as Local. The first one makes you the commander, the second makes the person you are looking at commander.

[player] remoteExec ["A3A_fnc_makePlayerBossIfEligible", 2];
[cursorTarget] remoteExec ["A3A_fnc_makePlayerBossIfEligible", 2];

Adding Temporary Members

Both run as local. First one adds yourself, second adds the person you are looking at.

membersX pushBackUnique (getPlayerUID player); publicVariable "membersX";
call A3A_fnc_memberAdd;

membersX pushBackUnique (getPlayerUID cursorTarget); publicVariable "membersX";
call A3A_fnc_memberAdd;

Force commander eligibility

Both run as local. First sets yourself eligible, second sets the person you are looking at.

player setVariable ["eligible",true,true];
cursorTarget setVariable ["eligible",true,true];

Resources and money

Both run as local. First adds x to your personal money, Second adds HR and Money to the faction. Replace x, HR, Money with the value you want to add. Negative numbers will subtract.

[x] call A3A_fnc_resourcesPlayer;

//[HR,Money]
[0,0] remoteExec ["A3A_fnc_resourcesFIA",2];

Prestige / Aggro

Run as local. Adds the specified aggro amount (-100 to 100) to the aggression of the specified side, with falloff over the specified time in minutes. Side must be Occupants or Invaders.

[side, aggroAmount, aggroTime] remoteExec ["A3A_fnc_addAggression",2];

View and adjust enemy resources (3.0.0)

Run as server. Defence resources have a maximum of 10*A3A_balanceResourceRate (depends on player count, aggro, war tier, difficulty), and cannot be used when below zero. Attacks will be launched if attack resources are above zero.

View all enemy resource counts:

[A3A_resourcesDefenceOcc, A3A_resourcesDefenceInv, A3A_resourcesAttackOcc, A3A_resourcesAttackInv];

Add 500 to invader attack resources:

A3A_resourcesAttackInv = A3A_resourcesAttackInv + 500;

Force update UI

Run as local. Forces the UI bar to update.

[] spawn A3A_fnc_statistics;

Flip Marker

Run as local. Changes the owner of a marker. Specify the marker to change and what side to give it to.

Markername is case-sensitive and needs to be given as a string "outpost_1".

Sides are: Teamplayer, Invaders, Occupants

[side, markername] remoteExec ["A3A_fnc_markerChange", 2];

City Support

Run as local. Change the support values of the closest city to you. Values can be negative, both gov and reb must be set to a number from 100 to -100.

[gov, reb, getPos player, false] remoteExec ["A3A_fnc_citySupportChange", 2];

Advanced Commands

Remove item from arsenal

Run as server. Removes the item, specified by classname, from the arsenal.

private _arsenalTab = "rhs_weap_Izh18" call jn_fnc_arsenal_itemType;
[_arsenalTab,"rhs_weap_Izh18",-1] call jn_fnc_arsenal_removeItem;

Remove Array of Items from arsenal

Run as server. Removes an Array of Items. For Example: UnlockedHandguns

{
   private _tab = _x call  jn_fnc_arsenal_itemType;
  [_tab,_x,-1] call jn_fnc_arsenal_removeItem;
} forEach someArrayOfTypes;

Add initialRebelEquipment

Run as server. Adds all initialRebelEquipment again, for cases where mission started without ace, to add missing items.

Not recommended to be used after switching between modsets.

{ [_x] call A3A_fnc_unlockEquipment } forEach initialRebelEquipment

Add initialRebelEquipment (3.0.0)

Run as server. Adds all unlimited initialRebelEquipment again, for cases where mission started without ace, to add missing items.

Not recommended to be used after switching between modsets.

{
    if (_x isEqualType "") then { _x call A3A_fnc_unlockEquipment };
} foreach (A3A_faction_reb get "initialRebelEquipment");

Other Useful Commands

Repair Buildings

repairs the building that you are looking at.

[cursorObject] remoteExec ["A3A_fnc_repairRuinedBuilding", 2]

repairs all buildings in the area of a marker.

{ [_x, true] remoteExec ["A3A_fnc_repairRuinedBuilding", 2] } forEach (destroyedBuildings inAreaArray "marker")

Vanilla Revive

Run as local, will revive you and remove any damage.

player setDamage 0;
player setVariable ["incapacitated",false,true];

Vanilla Stamina reset

run as local, will reset your Stamina

[player, 0] remoteExec ["setFatigue", _0];

Ace Revive

run as local, will fully heal you and revive if you were downed.

[player, player] call ace_medical_treatment_fnc_fullHeal

Regain Undercover (Player)

run as local allows you to go Undercover if you were reported. Will not allow your Vehicle to go Undercover again.

player setVariable ["compromised", 0, true];