Fix rendering glitch: dashed borders in the parent are inherited to child

src/Bloc-Alexandrie-Tests/BlSpaceFixture.class.st

@@ -114,6 +114,41 @@ BlSpaceFixture >> buildCapRoundDashedBorderOnClosedGeometry [
 
 ]
 
+{ #category : #fixtures }
+BlSpaceFixture >> buildChildDoesntInheritDashedBorder [
+
+	| outskirts |
+	builder spaceExtent: 90 @ 50.
+	builder space root layout: BlFlowLayout horizontal.
+
+	outskirts := {
+		BlOutskirts centered.
+		BlOutskirts inside.
+		BlOutskirts outside }.
+
+	#(true false) do: [ :childHasBorder |
+		outskirts do: [ :eachOutskirt |
+			| parent child |
+			parent := builder addToRoot
+				size: 25 @ 20;
+				margin: (BlInsets all: 2.5);
+				outskirts: eachOutskirt;
+				layout: BlFrameLayout new;
+				border: (BlBorder builder
+					paint: Color blue;
+					width: 2;
+					dashArray: #(2 2);
+					build).
+			child := (builder addTo: parent)
+				size: 12 asPoint;
+				constraintsDo: [ :c |
+					c frame horizontal alignCenter.
+					c frame vertical alignCenter ].
+			childHasBorder ifTrue: [
+				child border: (BlBorder paint: Color white width: 4) ] ] ]
+
+]
+
 { #category : #fixtures }
 BlSpaceFixture >> buildClippingAbsolutelyTransparentElement [
 	"Add 3 elements, where only the last one should be clipped by it's transparent parent.

src/Bloc-Alexandrie/BlBorder.extension.st

@@ -20,9 +20,9 @@ BlBorder >> aeApplyTo: aeCanvas element: aBlElement [
 	aeCanvas setBorderBlock: [
 		paint aeApplyTo: aeCanvas.
 
-		"No dashes is the default"
-		style dashArray ifNotEmpty: [ :da |
-			aeCanvas setDashes: da offset: style dashOffset ].
+		aeCanvas
+			setDashes: style dashArray
+			offset: style dashOffset.
 
 		aBlElement geometry hasJoins ifTrue: [
 			style lineJoin

src/Bloc-Alexandrie/BlTextBorderAttribute.extension.st

@@ -28,10 +28,9 @@ BlTextBorderAttribute >> aeDrawOn: aeCanvas span: aBASpan [
 			aeCanvas setBorderBlock: [
 				border paint aeApplyTo: aeCanvas.
 
-				border style dashArray ifNotEmpty: [ :da |
-					aeCanvas
-						setDashes: da
-						offset: border style dashOffset ].
+				aeCanvas
+					setDashes: border style dashArray
+					offset: border style dashOffset.
 
 				border style lineJoin
 					aeApplyTo: aeCanvas