[feat]: nixosModules (hardware/gpu)

hosts/yuki/default.nix

@@ -24,18 +24,27 @@ in {
     ../modules/services/pipewire.nix
   ];
 
+  modules = {
+    hardware = {
+      gpu = {
+        intel.enable = true;
+
+        nvidia = {
+          enable = true;
+          optimus = {
+            enable = true;
+            intelBusId = "PCI:0:2:0";
+            nvidiaBusId = "PCI:1:0:0";
+          };
+        };
+      };
+    };
+  };
+
   boot = {
     kernelModules = ["acpi_call"];
-    blacklistedKernelModules = ["nouveau"];
     extraModulePackages = with config.boot.kernelPackages; [acpi_call];
-    initrd.kernelModules = [
-      "i915"
-      "nvidia"
-      "nvidia_modeset"
-      "nvidia_uvm"
-      "nvidia_drm"
-      "ideapad_laptop"
-    ];
+    initrd.kernelModules = ["ideapad_laptop"];
     kernelPackages = pkgs.linuxPackages_latest;
     kernelParams = [
       "quiet"
@@ -66,8 +75,6 @@ in {
 
     variables = {
       GDK_SCALE = "2";
-      NVD_BACKEND = "direct";
-      MOZ_DISABLE_RDD_SANDBOX = "1";
     };
   };
 
@@ -79,38 +86,11 @@ in {
 
     enableAllFirmware = mkDefault true;
 
-    nvidia = {
-      package = mkDefault config.boot.kernelPackages.nvidiaPackages.beta;
-      modesetting.enable = mkDefault true;
-      powerManagement.enable = mkDefault true;
-      prime = {
-        offload = {
-          enable = true;
-          enableOffloadCmd = true;
-        };
-        intelBusId = mkDefault "PCI:0:2:0";
-        nvidiaBusId = mkDefault "PCI:1:0:0";
-      };
-    };
-
     opengl = {
       enable = mkDefault true;
       driSupport = mkDefault true;
       driSupport32Bit = mkDefault true;
-      extraPackages = with pkgs; [
-        intel-media-driver
-        intel-ocl
-        libvdpau-va-gl
-        vaapiVdpau
-        nvidia-vaapi-driver
-      ];
-      extraPackages32 = with pkgs.pkgsi686Linux; [
-        intel-media-driver
-        libvdpau-va-gl
-        vaapiVdpau
-        glxinfo
-        vdpauinfo
-      ];
+      extraPackages32 = with pkgs.pkgsi686Linux; [glxinfo vdpauinfo];
     };
   };
 
@@ -127,8 +107,6 @@ in {
       percentageAction = 10;
       criticalPowerAction = "Hibernate";
     };
-
-    xserver.videoDrivers = mkDefault ["nvidia"];
   };
 
   zramSwap.enable = true;

modules/default.nix

@@ -23,8 +23,13 @@ in {
         };
       }
 
+      self.nixosModules.hardware
       ../settings.nix
       ./theme
     ];
   };
+
+  flake.nixosModules = {
+    hardware = import ./hardware;
+  };
 }

modules/hardware/default.nix

@@ -0,0 +1,5 @@
+{
+  imports = [
+    ./gpu
+  ];
+}

modules/hardware/gpu/default.nix

@@ -0,0 +1,6 @@
+{
+  imports = [
+    ./intel.nix
+    ./nvidia.nix
+  ];
+}

modules/hardware/gpu/intel.nix

@@ -0,0 +1,22 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  cfg = config.modules.hardware.gpu.intel;
+in
+  with lib; {
+    options.modules.hardware.gpu.intel = {
+      enable = mkEnableOption "Intel GPU support";
+    };
+
+    config = mkIf cfg.enable {
+      boot.initrd.kernelModules = ["i915"];
+
+      hardware.opengl = {
+        extraPackages = with pkgs; [intel-media-driver intel-ocl];
+        extraPackages32 = with pkgs.pkgsi686Linux; [intel-media-driver];
+      };
+    };
+  }

modules/hardware/gpu/nvidia.nix

@@ -0,0 +1,73 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}: let
+  cfg = config.modules.hardware.gpu.nvidia;
+in
+  with lib; {
+    options.modules.hardware.gpu.nvidia = {
+      enable = mkEnableOption "NVIDIA GPU support";
+
+      optimus = {
+        enable = mkEnableOption "NVIDIA Optimus support";
+
+        intelBusId = mkOption {
+          type = types.str;
+          default = "PCI:0:2:0";
+          description = "Bus ID for the Intel GPU in Optimus setup.";
+        };
+
+        nvidiaBusId = mkOption {
+          type = types.str;
+          default = "PCI:1:0:0";
+          description = "Bus ID for the NVIDIA GPU in Optimus setup.";
+        };
+      };
+    };
+
+    config = mkIf cfg.enable {
+      boot = {
+        blacklistedKernelModules = ["nouveau"];
+        initrd.kernelModules = [
+          "nvidia"
+          "nvidia_modeset"
+          "nvidia_uvm"
+          "nvidia_drm"
+        ];
+      };
+
+      environment.variables = {
+        NVD_BACKEND = "direct";
+        MOZ_DISABLE_RDD_SANDBOX = "1";
+      };
+
+      hardware.nvidia = {
+        open = mkDefault false;
+        package = mkDefault config.boot.kernelPackages.nvidiaPackages.beta;
+        modesetting.enable = mkDefault true;
+        powerManagement.enable = mkDefault true;
+
+        prime = {
+          offload = {
+            enable = cfg.optimus.enable;
+            enableOffloadCmd = cfg.optimus.enable;
+          };
+          intelBusId = mkDefault cfg.optimus.intelBusId;
+          nvidiaBusId = mkDefault cfg.optimus.nvidiaBusId;
+        };
+      };
+
+      hardware.opengl = {
+        extraPackages = with pkgs; [
+          libvdpau-va-gl
+          vaapiVdpau
+          nvidia-vaapi-driver
+        ];
+        extraPackages32 = with pkgs.pkgsi686Linux; [libvdpau-va-gl vaapiVdpau];
+      };
+
+      services.xserver.videoDrivers = mkDefault ["nvidia"];
+    };
+  }