Add Nix flakes devenv

.envrc

@@ -0,0 +1,8 @@
+if ! has nix_direnv_version || ! nix_direnv_version 2.3.0; then
+    source_url "https://raw.githubusercontent.com/nix-community/nix-direnv/2.3.0/direnvrc" "sha256-Dmd+j63L84wuzgyjITIfSxSD57Tx7v51DMxVZOsiUD8="
+fi
+
+watch_file flake.nix
+dotenv_if_exists
+use flake
+# vi: ft=sh

.gitignore

@@ -26,3 +26,4 @@ types/build
 types/ts-types
 .dvc/
 solidity-fixtures
+.direnv

README.md

@@ -92,6 +92,14 @@ Build the node in `release mode`:
 cargo build --release
 ```
 
+## Installation Using Nix 💻
+
+1. Install [Nix](https://nixos.org/download.html)
+2. Enable Flakes (if you are not already see here: [Flakes](https://nixos.wiki/wiki/Flakes))
+3. If you have [`direnv`](https://github.com/nix-community/nix-direnv#installation) installed, everything should work out of the box.
+4. Alternatively, you can run `nix flake develop` in the root of this repo to get a shell with all the dependencies installed.
+5. Happy hacking!
+
 #### Troubleshooting for Apple Silicon users
 
 Install Homebrew if you have not already. You can check if you have it installed with the following command:

flake.nix

@@ -0,0 +1,67 @@
+{
+  description = "Protocol Substrate development environment";
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+    # Rust
+    rust-overlay = {
+      url = "github:oxalica/rust-overlay";
+      inputs = {
+        nixpkgs.follows = "nixpkgs";
+        flake-utils.follows = "flake-utils";
+      };
+    };
+  };
+
+  outputs = { self, nixpkgs, rust-overlay, flake-utils }:
+    flake-utils.lib.eachDefaultSystem (system:
+      let
+        overlays = [ (import rust-overlay) ];
+        pkgs = import nixpkgs {
+          inherit system overlays;
+        };
+        lib = pkgs.lib;
+        toolchain = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
+      in
+      {
+        devShells.default = pkgs.mkShell {
+          name = "protocol-substrate";
+          nativeBuildInputs = [
+            pkgs.protobuf
+            pkgs.pkg-config
+            # Needed for rocksdb-sys
+            pkgs.clang
+            pkgs.libclang.lib
+            pkgs.rustPlatform.bindgenHook
+            # Mold Linker for faster builds (only on Linux)
+            (lib.optionals pkgs.stdenv.isLinux pkgs.mold)
+          ];
+          buildInputs = [
+            # Used for DVC
+            pkgs.python311
+            pkgs.python311Packages.pipx
+            # We want the unwrapped version, wrapped comes with nixpkgs' toolchain
+            pkgs.rust-analyzer-unwrapped
+            # Nodejs for test suite
+            pkgs.nodePackages.typescript-language-server
+            pkgs.nodejs_18
+            pkgs.nodePackages.yarn
+            # Finally the toolchain
+            toolchain
+          ];
+          packages = [ ];
+          # Environment variables
+          RUST_SRC_PATH = "${toolchain}/lib/rustlib/src/rust/library";
+          # Runs DVC pull in the fixtures
+          # we do not install dvc globally, since it
+          # is broken on nixos
+          shellHook = ''
+            ROOT=$(git rev-parse --show-toplevel)
+            cd $ROOT/solidity-fixtures && pipx run dvc pull
+            cd $ROOT
+            cd $ROOT/substrate-fixtures && pipx run dvc pull
+            cd $ROOT
+          '';
+        };
+      });
+}

rust-toolchain.toml

@@ -1,4 +1,4 @@
 [toolchain]
 channel = "nightly-2022-12-26"
-components = ["rustfmt", "clippy"]
+components = ["rustfmt", "clippy", "rust-src"]
 targets = ["wasm32-unknown-unknown"]