Added List.sort(comp) to List module

doc/site/modules/core/list.markdown

@@ -94,6 +94,25 @@ System.print(["a", "b", "c"].removeAt(1)) //> b
 
 It is a runtime error if the index is not an integer or is out of bounds.
 
+### **sort**(), **sort**(comparer)
+
+Sorts the elements of a list in-place; altering the list.
+
+<pre class="snippet">
+var list = [4, 1, 3, 2].sort()
+System.print(list) //> [1, 2, 3, 4]
+</pre>
+
+A comparison function `comparer` can be provided to customise the element sorting. The comparison function must return a boolean value specifying the order in which elements should appear in the list. The default behaviour uses a `<` comparison.
+
+<pre class="snippet">
+var list = [9, 6, 8, 7]
+list.sort {|a, b| a < b}
+System.print(list) //> [6, 7, 8, 9]
+</pre>
+
+It is a runtime error if `comparer` is not a function.
+
 ### **[**index**]** operator
 
 Gets the element at `index`. If `index` is negative, it counts backwards from

src/vm/wren_core.wren

@@ -323,6 +323,41 @@ class List is Sequence {
     return other
   }
 
+  sort() { sort {|a, b| a < b } }
+
+  sort(comparer) {
+    if (!(comparer is Fn)) {
+      Fiber.abort("Comparer must be a function.")
+    }
+    quicksort_(0, count - 1, comparer)
+    return this
+  }
+
+  quicksort_(a, b, comparer) {
+    if (a < b) {
+      var p = partition_(a, b, comparer)
+      quicksort_(a, p - 1, comparer)
+      quicksort_(p + 1, b, comparer)
+    }
+  }
+
+  partition_(a, b, comparer) {
+    var p = this[b]
+    var i = a - 1
+    for (j in a..(b-1)) {
+      if (comparer.call(this[j], p)) {  
+        i = i + 1
+        var t = this[i]
+        this[i] = this[j]
+        this[j] = t
+      }
+    }
+    var t = this[i+1]
+    this[i+1] = this[b]
+    this[b] = t
+    return i+1
+  }
+
   toString { "[%(join(", "))]" }
 
   +(other) {

src/vm/wren_core.wren.inc

@@ -325,6 +325,41 @@ static const char* coreModuleSource =
 "    return other\n"
 "  }\n"
 "\n"
+"  sort() { sort {|a, b| a < b } }\n"
+"\n"
+"  sort(comparer) {\n"
+"    if (!(comparer is Fn)) {\n"
+"      Fiber.abort(\"Comparer must be a function.\")\n"
+"    }\n"
+"    quicksort_(0, count - 1, comparer)\n"
+"    return this\n"
+"  }\n"
+"\n"
+"  quicksort_(a, b, comparer) {\n"
+"    if (a < b) {\n"
+"      var p = partition_(a, b, comparer)\n"
+"      quicksort_(a, p - 1, comparer)\n"
+"      quicksort_(p + 1, b, comparer)\n"
+"    }\n"
+"  }\n"
+"\n"
+"  partition_(a, b, comparer) {\n"
+"    var p = this[b]\n"
+"    var i = a - 1\n"
+"    for (j in a..(b-1)) {\n"
+"      if (comparer.call(this[j], p)) {  \n"
+"        i = i + 1\n"
+"        var t = this[i]\n"
+"        this[i] = this[j]\n"
+"        this[j] = t\n"
+"      }\n"
+"    }\n"
+"    var t = this[i+1]\n"
+"    this[i+1] = this[b]\n"
+"    this[b] = t\n"
+"    return i+1\n"
+"  }\n"
+"\n"
 "  toString { \"[%(join(\", \"))]\" }\n"
 "\n"
 "  +(other) {\n"

test/core/list/sort.wren

@@ -0,0 +1,9 @@
+System.print([4, 1, 3, 2].sort()) // expect: [1, 2, 3, 4]
+
+var l = [10, 7, 8, 9, 1, 5]
+l.sort{|a, b| a < b }
+System.print(l) // expect: [1, 5, 7, 8, 9, 10]
+l.sort{|a, b| a > b }
+System.print(l) // expect: [10, 9, 8, 7, 5, 1]
+
+[10, 7, 8, 9, 1, 5].sort(3) // expect runtime error: Comparer must be a function.