python3Packages.mkdocs-material-insiders: init at 9.5.36-insiders-4.53.13

maintainers/maintainer-list.nix

@@ -12653,6 +12653,17 @@
     githubId = 24735185;
     name = "Mahmoud Ayman";
   };
+  mahtaran = {
+    email = "[email protected]";
+    github = "mahtaran";
+    githubId = 22727323;
+    name = "Luka Leer";
+    keys = [
+      {
+        fingerprint = "C7FF B72E 0527 423A D470  E132 AA82 C4EB CB16 82E0";
+      }
+    ];
+  };
   majesticmullet = {
     email = "[email protected]";
     github = "MajesticMullet";

pkgs/development/python-modules/mkdocs-git-committers-plugin-2/default.nix

@@ -0,0 +1,43 @@
+{
+  # Evaluation
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  pythonAtLeast,
+
+  # Dependencies
+  gitpython,
+  mkdocs,
+  requests,
+}:
+
+buildPythonPackage rec {
+  pname = "mkdocs-git-committers-plugin-2";
+  version = "2.3.0";
+  format = "setuptools";
+
+  disabled = !pythonAtLeast "3.8";
+
+  src = fetchFromGitHub {
+    owner = "ojacques";
+    repo = "mkdocs-git-committers-plugin-2";
+    rev = "refs/tags/${version}";
+    hash = "sha256-+Ua2oX8PrfTROAhXNjcKdjIajVfvP3D3ToddFfj5N6A=";
+  };
+
+  propagatedBuildInputs = [
+    gitpython
+    mkdocs
+    requests
+  ];
+
+  pythonImportsCheck = [ "mkdocs_git_committers_plugin_2" ];
+
+  meta = {
+    description = "MkDocs plugin for displaying a list of contributors on each page";
+    homepage = "https://github.com/ojacques/mkdocs-git-committers-plugin-2";
+    changelog = "https://github.com/ojacques/mkdocs-git-committers-plugin-2/releases/tag/${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ mahtaran ];
+  };
+}

pkgs/development/python-modules/mkdocs-material-insiders/default.nix

@@ -0,0 +1,103 @@
+{
+  # Evaluation
+  lib,
+  buildPythonPackage,
+  fetchFromGitHub,
+  pythonAtLeast,
+
+  # Build
+  hatchling,
+  hatch-requirements-txt,
+  hatch-nodejs-version,
+  trove-classifiers,
+
+  # Dependencies
+  jinja2,
+  markdown,
+  mkdocs,
+  mkdocs-material-extensions,
+  pygments,
+  pymdown-extensions,
+  babel,
+  colorama,
+  mergedeep,
+  paginate,
+  regex,
+  requests,
+
+  # Optional dependencies
+  mkdocs-minify-plugin,
+  mkdocs-redirects,
+  mkdocs-rss-plugin,
+  mkdocs-git-committers-plugin-2,
+  mkdocs-git-revision-date-localized-plugin,
+  pillow,
+  cairosvg,
+}:
+
+buildPythonPackage rec {
+  pname = "mkdocs-material";
+  version = "9.5.38-insiders-4.53.13";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "squidfunk";
+    repo = "mkdocs-material-insiders";
+    private = true;
+    rev = "refs/tags/${version}";
+    hash = "sha256-obfepPMQnq8m3P4/kT0nPlIF8w441xqhAWOFro7cHhU=";
+  };
+
+  disabled = !pythonAtLeast "3.8";
+
+  nativeBuildInputs = [
+    hatchling
+    hatch-requirements-txt
+    hatch-nodejs-version
+    trove-classifiers
+  ];
+
+  propagatedBuildInputs = [
+    jinja2
+    markdown
+    mkdocs
+    mkdocs-material-extensions
+    pygments
+    pymdown-extensions
+    babel
+    colorama
+    mergedeep
+    paginate
+    regex
+    requests
+  ];
+
+  passthru.optional-dependencies = {
+    recommended = [
+      mkdocs-minify-plugin
+      mkdocs-redirects
+      mkdocs-rss-plugin
+    ];
+
+    git = [
+      mkdocs-git-committers-plugin-2
+      mkdocs-git-revision-date-localized-plugin
+    ];
+
+    imaging = [
+      pillow
+      cairosvg
+    ];
+  };
+
+  pythonImportsCheck = [ "material" ];
+
+  meta = {
+    changelog = "https://github.com/squidfunk/mkdocs-material-insiders/blob/${version}/CHANGELOG";
+    description = "Sponsor's edition of Material for MkDocs";
+    downloadPage = "https://github.com/squidfunk/mkdocs-material-insiders";
+    homepage = "https://squidfunk.github.io/mkdocs-material/insiders";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ mahtaran ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -7946,6 +7946,8 @@ self: super: with self; {
 
   mkdocs-git-authors-plugin = callPackage ../development/python-modules/mkdocs-git-authors-plugin { };
 
+  mkdocs-git-committers-plugin-2 = callPackage ../development/python-modules/mkdocs-git-committers-plugin-2 { };
+
   mkdocs-git-revision-date-localized-plugin = callPackage ../development/python-modules/mkdocs-git-revision-date-localized-plugin { };
 
   mkdocs-gitlab = callPackage ../development/python-modules/mkdocs-gitlab-plugin { };
@@ -7960,6 +7962,8 @@ self: super: with self; {
 
   mkdocs-material-extensions = callPackage ../development/python-modules/mkdocs-material/mkdocs-material-extensions.nix { };
 
+  mkdocs-material-insiders = callPackage ../development/python-modules/mkdocs-material-insiders { };
+
   mkdocs-mermaid2-plugin = callPackage ../development/python-modules/mkdocs-mermaid2-plugin { };
 
   mkdocs-minify-plugin = callPackage ../development/python-modules/mkdocs-minify-plugin { };